[SCRIPT] Vash healer 2.1

[Vash1986]

Ricordate quando tempo fa postai lo script di healing per easyuo? A quei tempi non usavo il paladino nè il warrior, quindi non avevo modo di fare prove sulle ultime modifiche che avevo fatto, riguardo ai tempi di bendata ke adesso sono arrotondati al secondo.
Adesso però, grazie all'utilizzo del paladino con healing e alle segnalazioni di alcuni amici, ho risolto un paio di bug importanti e penso sia una buona cosa postare lo script sul forum. Così magari se molte persone lo utilizzano intensivamente prima o poi salteranno fuori gli ultimi bug e lo si potrà rendere perfetto.

(in futuro penso ke implementerò un check sul save e su cleaning resources, e magari che beva anche pozze refresh in automatico)

Perchè usarlo?
Perchè calcola alla perfezione il tempo di bendata e ha ottimi tempismi.
Perchè è abbastanza leggero.
Perchè non fallisce le azioni troppo veloci grazie a un controllo sul journal.
Perchè potete avere un contatore sopra la testa per sapere quando la bendata finisce.
Perchè beve pozza cure se avvelenati un attimo prima della fine della bendata, in modo che sia quasi impossibile fallire la bendata causa veleno.
Perchè su easyuo.com si trova solo schifo.

Ovviamente gli script non riescono quasi mai perfetti nè al primo, nè al secondo tentativo. Oppure si possono fare casini incollando lo script sul forum. Perciò per qualsiasi problema/bug contattatemi pure :P

E per chi se la fosse persa, qui c'è la guida per lo scripting a easyuo, ancora incompleta cmq:

http://forum.gamesnet.it/showthread....hreadid=295392

Ecco qui lo script:

;=============================
;Vash Healer v. 2.1
;=============================
;>>>>TENETE SEMPRE APERTI ZAINO E STATUS BAR!!!<<<<
;Testato su emulatore di Ultima Online RunUO 1.0.1 (con settaggi bendata OSI) col client 5.0.0b
;Dovrebbe funzionare senz'altro anche coi client vecchi.
;Se le bende finiscono o sono poche ti avverte.
;Ma basta rifornirsi senza dover riavviare lo script.
;Controlla il journal per verificare che le bende siano state correttamente applicate, altrimenti riprova.
;Ottimo calcolo della bendata in base alla dex, secondo le ultime modifiche OSI.
;Mostra una sorta di countdown sulla testa del pg, rappresentante i decimi di secondo mancanti alla fine della bendata.

;SETUP
;===========
;set %counter 1 per usare il contatore in decimi di secondo, set %counter 0 per non usarlo
set %counter 1

;SPECIAL CURE 
;=============
;E' anche possibile far funzionare lo script in modo che beva una pozione contro il veleno poco prima che finisca la bendata,
;in modo che sia impossibile farla fallire.
;Basta impostare su F11 una macro che beve la pozione cure (togliendo scudo ovviamente), e settare %cure a 1 anzichè 0.
set %cure 1
;Se invece non volete usare automaticamente pozze cure, lasciate %cure a 0.
;Se non vi piace il tasto F11 potete cambiarlo in fondo allo script.
;Ma non mettete combinazioni di tasti come CTRL F11 perchè razor non li intercetta.
;Finisce qui il setup, modificate lo script sottostante solo se sapete scriptare o volete cambiare il tasto per razor.

;MAIN LOOP
;=========
linespercycle 20
mainloop:
if #hits < #maxhits || C in #charstatus
     {
     GoSub CheckAids
     if #result = #true
          {
         GoSub CheckDex
         GoSub Apply
         if #result = #false
              goto mainloop
         GoSub Waitnew
         wait 2
         }
     }
wait 1
goto mainloop

;SUB CHECK AIDS
;==============
Sub CheckAids
finditem ZLF C_ , #BACKPACKID
if #findstack = 0
     {
     event ExMsg #charID 3 0 No bandages found!
     wait 5s
     return #false
     }
if #findstack < 10 && #findcnt < 2
     event sysmessage Attention, only #finstack aids remaining
return #true

;SUB CHECK DEX
;==============
Sub CheckDex
set %delay 11 - ( #dex / 20 )
set %euowait %delay * 10
return

;SUB APPLY
;=========
Sub Apply
aidloop:
finditem ZLF C_ , #BACKPACKID
set #lobjectid #findid
set %startscan #jindex
event macro 17 0
target 15
if #targcurs = 0
     goto aidloop
event macro 23 0
GoSub WaitStartMsg 15
if #result = #false
    goto aidloop
if #result = 1
    return #false
return

;SUB WAITSTARTMSG
;===============
Sub WaitStartMsg
set %start #scnt2
set %start %start + %1
_waitsysmsgloop:
for %i %startscan #jindex
     {
     scanjournal %i
     if you_begin in #journal
          {
          set %applystart #scnt2
          return #true
          }
     if that_being in #journal
          return 1
     }
if #scnt2 >= %start
     return #false
wait 1
goto _waitsysmsgloop

;SUB WAITNEW
;============
Sub WaitNew
set %keypressed 0
set %end %euowait + %applystart
set %limitcure %end - 16
waitloop:
if %counter = 1
     {
     set %remaining ( %end - #scnt2 )
     event ExMsg #charID 3 0 %remaining
     }
wait 2
if C in #charstatus && %cure = 1
     {
     if #scnt2 > %limitcure && %keypressed = 0
          {
          key F11 ; cambiatelo se necessario
          set %keypressed 1
          }
     }
if #SCNT2 >= %end || you_finish_applying in #sysmsg
     return
goto waitloop

[AgentOrange]

ti aNo, pensa che io vado a bucca col CEOMedic :P

[Ospite]

bella vash lo provo al volo

[Puch]

Provo subito

[Denkal]

io ho ancora :
;=============================
;JOURNAL HEALING by Vash v. 1.0a
;=============================


penso sia il primo che hai fatto :P ora provo questo nuovo.. azzie 1000 :P

[Dain_Piediferro]

Originally posted by Puch
Provo subito

[Ildioscuro]

grande vash grazie mille

[bibendus]

Originally posted by d0nk4
bella vash lo provo al volo

[fortunesgravo]

grazie

[Utamatumaki]

grazie io usavo quello vekkio ... mo vedo comé questo :P

[AgentOrange]

funziona... sono io che non so combattere :P

[Utamatumaki]

adesso il counter coincide con la bendata

[Ospite]

provato e va alla grande thx mille vash

[Puch]

Provato è perfetto
Thx Vash
VASH FOR PRESIDENT

[Hyjk]

thnx mille!