[EASY UO] Problemi con script crafta fukiya

[matteomassone]

lo script è questo, in pratica non prende più le fukiya per avvelenarle ne per dividerle.. apre solo la cassa iniziale e poi non fa più niente..

;metti nella cassa1 gli shuri le pozze e le fukija e setta l'id dove richiesto
;la cassa2 è quella dove vanno a finire le cariche poisonate settala dove richiesto
;tieni nel backpack una ninja belt e un fucile per le fukija
;-----------------------------------------------

set %fucili MDP
set %fujika SGP
set %belt MCP
set %shuri GDP
set %cassa1 GPQZAND ;metti l'id della cassa
set %cassa2 ASAGNMD  ;metti l'id della cassa
loop:


;carica e scarica il fucile

set #lobjectid %cassa1
event macro 17 0
wait 2s

finditem %fucili C_ , #backpackid
if #findcnt < 1
{
event ExMsg #CHARID 3 50 non hai fucili poisono gli shuri
goto belt
}
wait 5
exevent Popup #findid 1
wait 5
finditem %fujika C_ , %cassa1
if #findcnt < 1
{
event ExMsg #CHARID 3 50 hai finito le cariche poisono gli shuri
goto belt
}
    set #ltargetid #findid
    set #ltargetkind 1
    event macro 22 0
wait 5
if You_cannot_add in #sysmsg
{
finditem %fucili C_ , #backpackid
wait 5
exevent Popup #findid 2
wait 10
gosub poisonadardi
}
goto loop


belt:


;caricascarica belt


finditem %belt C_ , #backpackid
if #findcnt < 1
{
event ExMsg #CHARID 3 50 non hai belt script alt
halt
}
wait 5
exevent Popup #findid 1
wait 5
finditem %shuri C_ , %cassa1
if #findkind = -1
{
event ExMsg #CHARID 3 50 hai finito gli shuri script alt
halt
}
    set #ltargetid #findid
    set #ltargetkind 1
    event macro 22 0
wait 5
if You_cannot_add in #sysmsg
{
finditem %belt C_ , #backpackid
wait 5
exevent Popup #findid 2
wait 10
gosub poisonabelt
}
goto belt


;poisona i dardi


sub poisonadardi
finditem AVF C_ , #backpackid
if #findkind = -1
{
gosub prendipozze
}
	event macro 13 30
	wait 30

	finditem AVF C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 30

	finditem %fujika C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 50

finditem %fujika C_ , #backpackid
exevent drag #findid #findstack
wait 10
exevent dropc %cassa2
return


;poisona belt


sub poisonabelt
finditem AVF C_ , #backpackid
if #findkind = -1
{
gosub prendipozze
}
	event macro 13 30
	wait 30

	finditem AVF C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 30

	finditem %shuri C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 50

finditem %shuri C_ , #backpackid
exevent drag #findid
wait 10
exevent dropc %cassa2
return

sub prendipozze
finditem AVF C_ , %cassa1
     if #findkind = -1
{
display hai finito le pozze script alt
halt
}
         exevent drag #findid 30
         wait 5
         exevent dropc #backpackid
         wait 1s
return

[matteomassone]

nessuno ha idea di che comando dia fastidio con il nuovo client?

[matteomassone]

ho provato a fare F7 e vedere dove si blocca, in pratica si dovrebbe bloccare(credo) su questo comando:
exevent Popup #findid 1


suggerimenti su come modificare lo script??

[fengyr]

hai esattamente trovato il problema, con l'ultima versione di EasyUO il comando exevent popup funziona in maniera diversa...

prima, con la sintassi che hai indicato (exevent Popup #findid 1) si occupava di clickare su un npc/oggetto, ad esempio quando si ritira un BOD, e sceglieva l'opzione dal menu a tendina che compariva che gli si specificava [1 in questo caso].
ora il comando si limita ad aprire il menu a tendina dell'npc che gli indichi alle coordinate date senza occuparsi di selezionare l'opzione, devi inserire quindi nello script il comando click con le coordinate che servono...
non ho il client a portata di mano per provare, ma un fix semplice e "bovino" è cambiare le righe del popup così (omettendo i commenti in celeste:

wait 5
exevent Popup #findid 0 0 <---- fa comparire il menu a tendina dell'npc specificato alle coordinate 0 0, ovvero nell'angolo in alto a sinistra
wait 3
click 10 5 <---- clicka 10 pixel [asse x] a destra e 5 pixel in basso [asse y]
wait 10


nello script ci sono diversi popup con selezioni differenti, cambia le coordinate dei click dove necessario (esempio per la selezione n° 2 dovrai clickare più in basso quindi metti y > 5 )

[matteomassone]

grazie mille! provo subito a dedicarmici..sperando che la pratica non sia più difficile della già complicata teoria


grazie mille!! se correggo vi posto lo script funzionante, se non riuscirò vi terrò aggiornati ugualmente

[matteomassone]

@fengyr

è più facile a dirse che a farsi, come vedo il numero di pixel X e Y, perhè ho modificato le stringhe con il nuovo comando, ma non vedo nessun cambiamento.

lo script dovrebbe cliccare sulla fukyia fare ricarica e selezionare quelle che ho nella cassa, poi levarle dalla cerbottana e avvelenarle per poi rimetterle in una seconda cassa.. ora ci continuo a studiare, ma le coordinate mi stanno mandando sicuro fuori strada..

[matteomassone]

niente chiedo ufficialmente una mano.. ho provato e riprovato ma non riesco ad applicare queste modifiche=(

[fengyr]

ho cambiato come dicevo gli event popup in:

exevent Popup #findid
set %clickx #contposx + 20
set %clicky #contposy + 40 ;esempio seconda scelta
click %clickx %clicky

con offset di +20 sull'y per la prima scelta e +40 per la seconda....

;metti nella cassa1 gli shuri le pozze e le fukija e setta l'id dove richiesto
;la cassa2 è quella dove vanno a finire le cariche poisonate settala dove richiesto
;tieni nel backpack una ninja belt e un fucile per le fukija
;-----------------------------------------------

set %fucili MDP
set %fujika SGP
set %belt MCP
set %shuri GDP
set %cassa1 HBNOYMD ;metti l'id della cassa
set %cassa2 NQTTJMD  ;metti l'id della cassa
loop:


;carica e scarica il fucile

set #lobjectid %cassa1
event macro 17 0
wait 2s

finditem %fucili C_ , #backpackid
if #findcnt < 1
{
event ExMsg #CHARID 3 50 non hai fucili poisono gli shuri
goto belt
}
wait 5
exevent Popup #findid 100 100
set %clickx #contposx + 20
set %clicky #contposy + 20 ;popup entry 1
click %clickx %clicky
wait 5
finditem %fujika C_ , %cassa1
if #findcnt < 1
{
event ExMsg #CHARID 3 50 hai finito le cariche poisono gli shuri
goto belt
}
    set #ltargetid #findid
    set #ltargetkind 1
    event macro 22 0
wait 5
if You_cannot_add in #sysmsg
{
finditem %fucili C_ , #backpackid
wait 5
exevent Popup #findid
set %clickx #contposx + 20
set %clicky #contposy + 40    ;popup entry 2
click %clickx %clicky
wait 10
gosub poisonadardi
}
goto loop


belt:


;caricascarica belt


finditem %belt C_ , #backpackid
if #findcnt < 1
{
event ExMsg #CHARID 3 50 non hai belt script alt
halt
}
wait 5
exevent Popup #findid
set %clickx #contposx + 20
set %clicky #contposy + 20    ;popup entry 1
click %clickx %clicky
wait 5
finditem %shuri C_ , %cassa1
if #findkind = -1
{
event ExMsg #CHARID 3 50 hai finito gli shuri script alt
halt
}
    set #ltargetid #findid
    set #ltargetkind 1
    event macro 22 0
wait 5
if You_cannot_add in #sysmsg
{
finditem %belt C_ , #backpackid
wait 5
exevent Popup #findid 2
set %clickx #contposx + 20
set %clicky #contposy + 40    ;popup entry 2
click %clickx %clicky
wait 10
gosub poisonabelt
}
goto belt


;poisona i dardi


sub poisonadardi
finditem AVF C_ , #backpackid
if #findkind = -1
{
gosub prendipozze
}
	event macro 13 30
	wait 30

	finditem AVF C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 30

	finditem %fujika C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 50

finditem %fujika C_ , #backpackid
exevent drag #findid #findstack
wait 10
exevent dropc %cassa2
return


;poisona belt


sub poisonabelt
finditem AVF C_ , #backpackid
if #findkind = -1
{
gosub prendipozze
}
	event macro 13 30
	wait 30

	finditem AVF C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 30

	finditem %shuri C_ , #backpackid
	set #LTARGETID #findid
	set #LTARGETKIND 1
	event macro 22 0
	wait 50

finditem %shuri C_ , #backpackid
exevent drag #findid
wait 10
exevent dropc %cassa2
return

sub prendipozze
finditem AVF C_ , %cassa1
     if #findkind = -1
{
display hai finito le pozze script alt
halt
}
         exevent drag #findid 30
         wait 5
         exevent dropc #backpackid
         wait 1s
return

[matteomassone]

lo sto provando in questo momento, sembrerebbe funzionare alla grande!! si l'errore che facevo era, la stringa di comando.. i due valori 20 e 40 erano corretti, che dire.. grazie! se avrai mai bisogno di qualche cosa sono a tua completa disposizione!!