[EASYUO HELP] Cerco script Anti Blood Oath

[Turuzzo93]

Come da titolo mi sapete postare/linkare uno script in grado di tabbare o curare quando fanno bload oath in automatico?
Un warrior assistant o simile.

[Turuzzo93]

Nessuno può postarlo?

Oggi sono morto 752 volte dal df per bload oath

[magichat]

[EASYUO] Warrior's Assistant

[Turuzzo93]

[EASYUO] Warrior's Assistant

L'ho provato questo, ma non è quello che cercavo.
Questo ti cura anche.

Io voglio uno script che quando fa bload oath, tabba subito e al massimo fa remove curse.

[Marino]

L'ho provato questo, ma non è quello che cercavo.
Questo ti cura anche.

Io voglio uno script che quando fa bload oath, tabba subito e al massimo fa remove curse.

salvo l'unico che mi viene in mente ora è l'antiblood oath di fnurov te lo posto qui, non so se cercavi una cosa del genere tu, comunque prima di farlo partire salvalo nella directory di easy uo questo script http://www.easyuo.com/forum/download/file.php?id=3223 serve al fine di un corretto funzionamento, dimmi se funzia se no cerco altro

    ;==================================
    ; Script Name: Anti Blood Oath
    ; Author: Felix
    ; Version: 3
    ; Client Tested with: 6.0.13
    ; EUO version tested with: 1.5.148
    ; Shard FS: UODreams
    ; Public Release: 27/07/2009
    ; Purpose: turns off war-mode, whan blood oath
    ; Requirments: ScanBuffBar
    ;===========================================
     
    ;;;;;;;;;;SETUP
    set %BloodOathScanDelay 250
     
     
    ;;;;;;;DON'T EDIT
    set %InOldOath #false
    set %NextBloodOathScan #systime
    set %EndTurningOffWar 0
    set %OathId xxyyxx
     
    loop:
         if %InOldOath && ( #systime <= %EndTurningOffWar || #enemyid = %OathId ) && G in #charstatus
         {
             if #enemyid = %OathId
             {
                finditem %OathId G
                if #findtype = IS && #findrep = 6
                {
                   event property %OathId
                   if revenant in #property
                      set %OathId xxyyxx
                }
                if #systime > %EndTurningOffWar && #enemyid = %OathId
                {
                   event exmsg #charid 0 0 OATH2
                   set %EndTurningOffWar #systime + 2000
                }
             }
             while #systime <= %EndTurningOffWar && G in #charstatus
             {
                   event macro 6 0
                   set %nexttoggle #systime + 300
                   while #systime <= %nexttoggle && G in #charstatus
                   {
                         sleep 10
                   }
             }
         }
         if #systime >= %NextBloodOathScan
            gosub AntiBloodOath
         else
             sleep 20
    goto loop
     
     
    sub AntiBloodOath
        if G notin #charstatus && %InOldOath = #false
        {
           set %NextBloodOathScan #systime + %BloodOathScanDelay
           return
        }
        Call ScanBuffBar
        set %oathed _CurseBloodOath_ in %BuffBarIconNames
        if %oathed
        {
           if G in #charstatus
           {
              if %InOldOath = #false && #systime > %EndTurningOffWar
              {
                 set %InOldOath #true
                 set %EndTurningOffWar #systime + 2000
                 if #enemyid <> n/a
                    set %OathId #enemyid
                 else
                     set %OathId xxyyxx
                 event exmsg #charid 0 0 OATH
              }
           }
        }
        else
        {
            if %InOldOath
            {
               set %InOldOath #false
               if G notin #charstatus
                  event macro 6 0
               event exmsg #charid 0 0 go go go
            }
        }
        set %NextBloodOathScan #systime + %BloodOathScanDelay
    return

[Turuzzo93]

Perfetto, funziona.

Gentilissimo come sempre mari

[didina]

Ho scaricato i due file. Ma non funzionano. Forse è necessario aggiornali. Qualcuno mi potrebbe soccorrere... Grazie