annuncio

**Marino** · 03-08-2011, 20:23

Originariamente inviato da silenteisback Visualizza il messaggio

Ciao raga ho provato a scaricare qst script: http://www.easyuo.com/forum/viewtopi...=336576#336576 di fnurov lo ho impostato ma nn riesco a farlo partire... qlkn potrebbe spiegarmi come fare? tnx

ciao guarda quello dava qualche problema dopo i fix prova questo, in pratica ora non ricordo bene, ma serve per castare le magie lighting strike puoi attivarla e disattivarla, nella parte inziale cio� questa puoi modificare i parametri e scegliere tu quali tasti assegnare per far partire la macro, in sostanza metti in play lo script su easy uo e poi seleziona il tasto corrispondente qui sotto per far partire la macro

codice:

set %SetupHotkey y ; hotkey to run initialisation for pixel reading

set %SetupMod alt ; hotkey modifier to initialisation

set %UseAbilityKey b ; hotkey to turn on/off mixing primary ability and lighting strike. same key with alt to turn off script

codice:

;==================================

; Script Name: lighting strike

; Author: Felix

; Version: 3.2

; Client Tested with: 6.0.10

; EUO version tested with: 1.5.143

; Shard FS: UODreams

; Public Release: 10/03/2009

; Purpose: reactivating lighting strike or mixing lighting strike and primary ability

;==================================



;-------SETUP--------------

set %SetupHotkey y ; hotkey to run initialisation for pixel reading

set %SetupMod alt ; hotkey modifier to initialisation

set %UseAbilityKey b ; hotkey to turn on/off mixing primary ability and lighting strike. same key with alt to turn off script

set %PrimAbilManaCost 100 ;mana to perform primary ability

set %DoublePrimAbilManaCost 80 ; mana to use ability with double-cost

set %LightManaCost 10 ; mana to perform lighting strike

set %lIconX 262 ; X-posiotn of Ligting strike icon

set %lIconY 649 ; Y-posiotn of Ligting strike icon

set %pIconX 214 ; X-posiotn of Primary ability icon

set %pIconY 649 ; Y-posiotn of Primary ability icon

set %FR 1 ; stop wasting mana whan fire res < value



;don't edit below

set %nextturn #systime

set %nextswitch #systime

set %nextscan #systime

set %abilityactivated #false

set %somethingactivated #false

set %abilityused3000 0

set %scandelay 400

set #lpc 500

wait 30

repeat

      if *LightingScriptSetup <> OK

         gosub Setup first

      else

          gosub Setup

until *LightingScriptSetup = OK



set %abilityon #false

set %scripton #true

loop:

    sleep 10



    onhotkey %UseAbilityKey alt

              gosub ShutDown



    if %scripton = #false

       goto loop



    onhotkey %UseAbilityKey

              gosub switchmode

    onhotkey %SetupHotkey %SetupMod

             gosub Setup first



    if #systime < %nextscan || #mana < %LightManaCost

       goto loop



    set %lighting #false

    cmppix 1 f

       set %lighting #true



    if %abilityon && ( %lighting = #false || %abilityactivated )

    {

       set %abilty #false

       cmppix 2 f

              set %abilty #true

       if %abilty = #false && %abilityactivated

       {

          if a notin #charstatus

          {

                 set %abilityused3000 #systime + 3000

                 set %abilityactivated #false

          }

          else

              set %abilityactivated #false

       }

    }



    if %somethingactivated

    {

       set %somethingactivated #false

       set %nextscan #systime + 100

    }



    if %lighting || ( %abilty && %abilityon )

       goto loop

    while #targcurs = 1 || A in #charstatus

    {

                sleep 10

    }

    wait 1

    if #mana >= %LightManaCost && H notin #charstatus && #FR > %FR

    {

       if %abilityon && %abilty = #false && #mana >= %PrimAbilManaCost && ( #systime >= %abilityused3000 || #mana >= %DoublePrimAbilManaCost )

       {

          event macro 35 0

          ;set %lastmove 2

          set %nextscan #systime + %scandelay

          set %abilityactivated #true

          set %somethingactivated #true

       }

       else

       {

           if %lighting = #false

           {

              event macro 15 149

              ;set %lastmove 1

              set %nextscan #systime + %scandelay

              set %abilityactivated #false

              set %somethingactivated #true

              ;set %asd #systime - %lastactive

              ;event macro 1 0 %asd #stamina

              ;set %lastactive #systime

           }

       }

    }

goto loop



sub Setup

    event macro 36 0

    wait 10

    if %1 = first

    {

       set *LightingScriptSetup OK

       event macro 8 1

       while #CONTNAME <> paperdoll_gump

       {

            sleep 10

       }

       event sysMessage #charid 0 0 drag your lighting strike icon. it should be not active.

       set %posing #true

       repeat

          while #contname <> spellicon_gump

          {

                sleep 10

          }

          contpos %lIconX %lIconY

          wait 10

          if #CONTPOSX = %lIconX && #CONTPOSY = %lIconY

             set %posing #false

       until %posing = #false

    }



    set %pixX %lIconX + 10

    set %pixY %lIconY + 10

    savePix %pixX %pixY 1



    if %1 <> first

    {

       if *LightingScriptLight <> #pixcol

          set *LightingScriptSetup Fail

    }

    if %1 = first

    {

       set *LightingScriptLight #pixcol

       event macro 8 1

       while #CONTNAME <> paperdoll_gump

       {

            sleep 10

       }

       event sysMessage #charid 0 0 drag your prime ability icon. it should be not active.

       set %posing #true

       repeat

          while #contname <> abilityicon_gump

          {

                sleep 10

          }

          contpos %pIconX %pIconY

          wait 10

          if #CONTPOSX = %pIconX && #CONTPOSY = %pIconY

             set %posing #false

       until %posing = #false

    }

    set %pixX %pIconX + 22

    set %pixY %pIconY + 6

    savePix %pixX %pixY 2



    if %1 <> first

    {

       if *LightingScriptPrime <> #pixcol

          set *LightingScriptSetup Fail

    }

    if %1 = first

       set *LightingScriptPrime #pixcol

return



sub switchmode

    if #systime > %nextswitch

    {

       set %nextswitch #systime + 300

       if %abilityon

       {

       set #sysmsgcol  33

          event sysmessage OFF

          ;event exmsg  #charid 3 33  OFF

          set %abilityon #false

              set %lastmove 2

              set %nextlighting #systime

       }

       else

       {

       set #sysmsgcol  68

           event sysmessage ON

           ;event exmsg  #charid 3 68  ON

           set %abilityon #true

       }

    }

return



sub ShutDown

    if #systime > %nextturn

    {

       set %nextturn #systime + 500

       if %scripton

       {

          set #sysmsgcol  33

          event sysmessage Script OFF

          ;event exmsg  #charid 3 33  Script OFF

          set %scripton #false

       }

       else

       {

          set #sysmsgcol  68

           event sysmessage Script ON

           ;event exmsg  #charid 3 68  Script ON

           set %scripton #true

       }

    }

return

**silenteisback** · 04-08-2011, 11:57

nn riesco a farlo funzionare

allora faccio play e mi dice drag your lightning strike icon, quindi la sposto, poi mi dice drag your primary ability e sposto anke quella, e poi che devo fare? perk� continua da dirmi drag your ls... e drag your primary ability.... uff �_� provo a premere i tasti per pixel reading ma nn succede nulla uff

scusate ma nn ne sto capendo pi� nulla

**silenteisback** · 06-08-2011, 11:34

raga qlkn saprebbe aiutarmi?

**silenteisback** · 09-08-2011, 01:25

up

annuncio

[EASY UO HELP]Lightning & Ability

[EASY UO HELP]Lightning & Ability

Commenta

Commenta

Commenta

Commenta