Tweet
Nello script di felix č presente la funzionalitą di usare la primary ability... bč č possibile aggiungere il tastino per attivare la secondary abiliy? grazie 
codice:
;==================================
; Script Name: lighting strike
; Author: Felix
; Version: 3.2
; Client Tested with: 6.0.10
; EUO version tested with: 1.5.143
; Shard FS: UODreams
; Public Release: 10/03/2009
; Purpose: reactivating lighting strike or mixing lighting strike and primary ability
;==================================
;-------SETUP--------------
set %SetupHotkey 9 ; hotkey to run initialisation for pixel reading
set %SetupMod alt ; hotkey modifier to initialisation
set %UseAbilityKey 0 ; hotkey to turn on/off mixing primary ability and lighting strike. same key with alt to turn off script
set %PrimAbilManaCost 20 ;mana to perform primary ability
set %DoublePrimAbilManaCost 33 ; mana to use ability with double-cost
set %LightManaCost 7 ; mana to perform lighting strike
set %lIconX 319 ; X-posiotn of Ligting strike icon
set %lIconY 796 ; Y-posiotn of Ligting strike icon
set %pIconX 319 ; X-posiotn of Primary ability icon
set %pIconY 753 ; Y-posiotn of Primary ability icon
set %FR 10 ; stop wasting mana whan fire res < value
;don't edit below
set %nextturn #systime
set %nextswitch #systime
set %nextscan #systime
set %abilityactivated #false
set %somethingactivated #false
set %abilityused3000 0
set %scandelay 400
set #lpc 500
wait 30
repeat
if *LightingScriptSetup <> OK
gosub Setup first
else
gosub Setup
until *LightingScriptSetup = OK
set %abilityon #false
set %scripton #true
loop:
sleep 10
onhotkey %UseAbilityKey alt
gosub ShutDown
if %scripton = #false
goto loop
onhotkey %UseAbilityKey
gosub switchmode
onhotkey %SetupHotkey %SetupMod
gosub Setup first
if #systime < %nextscan || #mana < %LightManaCost
goto loop
set %lighting #false
cmppix 1 f
set %lighting #true
if %abilityon && ( %lighting = #false || %abilityactivated )
{
set %abilty #false
cmppix 2 f
set %abilty #true
if %abilty = #false && %abilityactivated
{
if a notin #charstatus
{
set %abilityused3000 #systime + 3000
set %abilityactivated #false
}
else
set %abilityactivated #false
}
}
if %somethingactivated
{
set %somethingactivated #false
set %nextscan #systime + 100
}
if %lighting || ( %abilty && %abilityon )
goto loop
while #targcurs = 1 || A in #charstatus
{
sleep 10
}
wait 1
if #mana >= %LightManaCost && H notin #charstatus && #FR > %FR
{
if %abilityon && %abilty = #false && #mana >= %PrimAbilManaCost && ( #systime >= %abilityused3000 || #mana >= %DoublePrimAbilManaCost )
{
event macro 35 0
;set %lastmove 2
set %nextscan #systime + %scandelay
set %abilityactivated #true
set %somethingactivated #true
}
else
{
if %lighting = #false
{
event macro 15 149
;set %lastmove 1
set %nextscan #systime + %scandelay
set %abilityactivated #false
set %somethingactivated #true
;set %asd #systime - %lastactive
;event macro 1 0 %asd #stamina
;set %lastactive #systime
}
}
}
goto loop
sub Setup
event macro 36 0
wait 10
if %1 = first
{
set *LightingScriptSetup OK
event macro 8 1
while #CONTNAME <> paperdoll_gump
{
sleep 10
}
event exmsg #charid 0 0 drag your lighting strike icon. it should be not active.
set %posing #true
repeat
while #contname <> spellicon_gump
{
sleep 10
}
contpos %lIconX %lIconY
wait 10
if #CONTPOSX = %lIconX && #CONTPOSY = %lIconY
set %posing #false
until %posing = #false
}
set %pixX %lIconX + 10
set %pixY %lIconY + 10
savePix %pixX %pixY 1
if %1 <> first
{
if *LightingScriptLight <> #pixcol
set *LightingScriptSetup Fail
}
if %1 = first
{
set *LightingScriptLight #pixcol
event macro 8 1
while #CONTNAME <> paperdoll_gump
{
sleep 10
}
event exmsg #charid 0 0 drag your prime ability icon. it should be not active.
set %posing #true
repeat
while #contname <> abilityicon_gump
{
sleep 10
}
contpos %pIconX %pIconY
wait 10
if #CONTPOSX = %pIconX && #CONTPOSY = %pIconY
set %posing #false
until %posing = #false
}
set %pixX %pIconX + 22
set %pixY %pIconY + 6
savePix %pixX %pixY 2
if %1 <> first
{
if *LightingScriptPrime <> #pixcol
set *LightingScriptSetup Fail
}
if %1 = first
set *LightingScriptPrime #pixcol
return
sub switchmode
if #systime > %nextswitch
{
set %nextswitch #systime + 300
if %abilityon
{
event ExMsg #charid 0 33 OFF
set %abilityon #false
set %lastmove 2
set %nextlighting #systime
}
else
{
event ExMsg #charid 0 68 ON
set %abilityon #true
}
}
return
sub ShutDown
if #systime > %nextturn
{
set %nextturn #systime + 500
if %scripton
{
event ExMsg #charid 0 0 Script OFF
set %scripton #false
}
else
{
event ExMsg #charid 0 0 Script ON
set %scripton #true
}
}
return
Commenta