[EASYUO HELP] Aegis Uber Tamer

[Gianmarco189380]

.....sto impazzendo XDXD...
Dopo aver tentato di utilizzare lo script ho avuto dei problemi. Dopo innumrevoli prove e tentativi si ripresentavano puntualmente alcune situazion. Risolte le quali l' unico dilemma risiede nella rail! Quella x gli spazi brevi fornita dal forum non funge. Tentando di scriverla con lo script di CEO x le rail la questionenon si è risolta.

PLS HELP MY TAMER!

Magari non ce qualche gentile player che nel suo archivio di rail ne ha qualcuna x le location di respawn dei mob tipici x skillare Taming? (ad es. recinto skara brae x lalli)

O anche mi sappia dare qualche dritta x far fungere l' utilissimo/dannatissimo script?

Dal basso delle mie scarse capacità " nerdiche" chiedo un umile XD aiuto ad un qualche pro dello shard!

GRAZE GRAZIE GRZIE GRAZIE

P.S. la prima droppat DOOM di qusto PG sarà completamente dedicata al buon samaritano che mi aiutera!! asdasd XDD
uu
uu

[Marino]

ciao guarda ti aiuto volentieri, partiamo dai problemi che hai, inanzitutto hai utilizzato questo script per creare la rail?

;==================================
; Script Name: CEOAutoRailWriter
; Author: CEO
; Version: 1.3a
; Client Tested with: 4.0.1b
; EUO version tested with: 1.4 (005F)
; Shard OSI / FS:
; Revision Date: 12-22-03
; Public Release:12-22-03
; Purpose: Simple method for writing a rail file. Just hit Record and walk the path.
;============================================
initevents
;--------------------------- Change these to fit your needs
set %ztolerance 3
set %dtolerance 4
set %targetx_text ltargetx
set %targety_text ltargety
set %targetz_text ltargetz
set %filename railspots.txt
;might need to set this use "command" instead of "cmd" for your OS
set %cmd cmd
;----------------------------
set %version 1.3a
set %debug #false
set %totalspots 0
set %totalltargets 0
set %testrail #false
if EXEC notin #opts
{
  display ok In order to save the rail file you must have $"Allow Execute" on.
+ Enable this option$from the Easyuo menu:$$Options>Configuration>Allow Execute$$Halting...
  halt
}
gosub initmenu
set #menubutton N/A
Mainloop:
wait 5
if #menubutton <> N/A
  gosub #menubutton
if *500 = waiting && ! %testrail
{
  menu font bgcolor silver
  menu font color black
  menu button TestRail 200 5 60 20  Test Rail
  menu font bgcolor black
  menu font color red
  set %testrail #true
}
gosub DisplayCords
goto Mainloop

sub TestRail
set *502 railspots.txt
set *503 1
set *504 run
set *501 start
set #menubutton N/A
return

sub Write
show menu
menu delete record
set #menubutton N/A
menu delete write
menu font bgcolor blue
menu font color white
menu text status 55 5 Writing File
menu font bgcolor black
menu font color red
str mid #date 3 2
set %date #strres
str right #date 2
set %date %date , / , #strres
str left #date 2
set %date %date , / , #strres
execute %cmd /c echo #smc , * Created with CEOAutoRailWriter on , #spc , %date , #spc , * > %filename
execute %cmd /c echo #smc , #spc >> %filename
execute %cmd /c echo set % , endspot , #spc , %totalspots >> %filename
menu text hs 10 30 Saving Spot:
menu font color white
for %i 1 %totalspots
{
  menu delete ss
  menu text ss 85 30 %i
  wait 1
  execute %cmd /c echo set % , X , %i , #spc , %railspotx . %i >> %filename
  execute %cmd /c echo set % , Y , %i , #spc , %railspoty . %i >> %filename
  execute %cmd /c echo set % , Z , %i , #spc , %railspotz . %i >> %filename
  if %target . %i = #true
  {
    execute %cmd /c echo set % , %targetx_text , %i , #spc , %ltargetx . %i >> %filename
    execute %cmd /c echo set % , %targety_text , %i , #spc , %ltargety . %i >> %filename
    execute %cmd /c echo set % , %targetz_text , %i , #spc , %ltargetz . %i >> %filename
    execute %cmd /c echo set % , ltargetkind , %i , #spc , %ltargetkind . %i >> %filename
    execute %cmd /c echo set % , ltargettile , %i , #spc , %ltargettile . %i >> %filename

  }
}
menu font bgcolor silver
menu font color black
menu button Record 10 150 50 20  Record
menu font bgcolor black
menu font color red
set %totalspots 0
menu delete rx
menu delete ry
menu delete rz
menu delete ss
menu delete hs
menu delete fh
gosub DisplayTotalSpots
menu delete status
return

sub Record
show menu
set %lpc #lpc
set #lpc 1000
for %i 1 %totalspots
{
  set %ltargetx . %i n/a
}
set #lpc %lpc
set %totalspots 1
set %totalltargets 0
gosub WalkOn
gosub DisplayTotalSpots
gosub RecordSpot
menu delete Record
menu font bgcolor silver
menu font color black
menu button Stop 10 150 50 20  Stop
menu button LTARGET 110 150 50 20  Ltarget
menu font bgcolor black
menu delete recording
menu font bgcolor red
menu font color white
menu text status 55 5 Recording
menu font bgcolor black
menu font color red
menu text ath 10 30 Auto Timer:
set %recording #true
set #menubutton N/A
Record1:
show menu
if #menubutton = ltarget
{
  if %lastpos <> %lastrailspot
  {
       set %totalspots %totalspots + 1
      gosub DisplayTotalSpots
       gosub RecordSpot
      gosub DisplayCords
  }
  gosub record_ltarget
  gosub DisplayTotalSpots
}
if #menubutton <> N/A
{
  gosub #menubutton
  if ! %recording
  {
    menu delete ltarget
    return
  }
}
wait 5
if %lastpos <> %lastrailspot
{
  set %timetowrite %lastmoved - #scnt
  menu delete ttw
  if %timetowrite <= 5
  {
    menu font color yellow
    menu text ttw 75 30 %timetowrite
    menu font color red
    if %timetowrite <= 0
    {
       set %totalspots %totalspots + 1
      gosub DisplayTotalSpots
       gosub RecordSpot
    }
  }
}
gosub DisplayCords
if %record_spot
{
   set %totalspots %totalspots + 1
  gosub DisplayTotalSpots
   gosub RecordSpot
}
goto Record1

return

sub RecordSpot
set %lastspotx #charposx
set %lastspoty #charposy
set %lastspotz #charposz
set %railspotx . %totalspots %lastspotx
set %railspoty . %totalspots %lastspoty
set %railspotz . %totalspots %lastspotz
gosub DisplayRecordedSpot
set %lastrailspot %lastspotx , _ , %lastspoty , _ , %lastspotz
set %lastpos %lastrailspot
set %lastmoved #scnt + 5
menu delete ttw
return

sub DisplayRecordedSpot
menu font align right
menu font color white
menu delete rx
menu text rx 135 70 %lastspotx
menu delete ry
menu text ry 175 70 %lastspoty
menu delete rz
menu text rz 215 70 %lastspotz
menu font color red
menu font align left
return

sub stop
menu delete Stop
menu font bgcolor silver
menu font color black
menu button Record 10 150 50 20  Record
set #menubutton N/A
menu delete status
menu delete ath
menu delete ttw
set %recording #false
if %totalspots > 1
  menu button Write 60 150 50 20  Write
menu font bgcolor black
menu font color lime
gosub RunON
return

sub InitMenu
menu clear
menu font alight left
menu window size 270 200
menu window title CEOAutoRailWriter %version
menu window color black
menu font bgcolor BLACK
menu font color red
menu show
menu font size 9
menu text s 10 5 Status:
menu text fnameheader 5 180 Filename:
menu font size 8
menu font color white
menu edit fname 70 175 130 %filename
menu font size 9
menu font color red
menu text h1x 130 35 X
menu text h1y 170 35 Y
menu text h1z 210 35 Z
menu text h1 10 50 Current Position:
menu text h5 10 70 Last Recorded:
menu text h4 10 85 Total Railspots:
menu text h4 145 85 Total # , LTargets:
gosub DisplayTotalSpots
menu font align left
menu font style b
menu font color yellow
menu text hh 5 100 Rail Parameters :
menu font style n
menu font color red
menu text h2 10 115 Max distance between spots:
menu text h3 10 130 Z tolerance:
menu font color yellow
menu text t2 175 115 %dtolerance
menu text t3 80 130 %ztolerance
menu font color red
gosub displayCords
menu font bgcolor silver
menu font color black
menu button Record 10 150 50 20  Record
menu button getfname 201 178 30 20 upd
if *500 = waiting
{
  menu button TestRail 200 5 60 20  Test Rail
  set %testrail #true
}
menu font bgcolor black
menu font color red
set #menubutton N/A
menu delete total
menu font color lime
if ! %debug
  menu hideeuo
return


sub DisplayTotalSpots
menu font align right
menu font color white
menu delete tspots
menu delete tltargets
menu text tspots 120 85 %totalspots
menu text tltargets 255 84 %totalltargets
menu font align left
menu font color red
return

sub DisplayCords
set %record_spot #false
if #charposx , _ , #charposy , _ , #charposz = %lastpos
  return
menu font align right
menu font color lime
X:
if %lastposx = #charposx
  goto Y
menu delete x
menu text x 135 50 #charposx
set %dif abs ( %lastspotx - #charposx )
if %dif > %dtolerance
  set %record_spot #true
set %lastposx #charposx
Y:
if %lastposy = #charposy
  goto Z
set %dif abs ( %lastspoty - #charposy )
if %dif > %dtolerance
  set %record_spot #true
menu delete y
menu text y 175 50 #charposy
set %lastposy #charposy
Z:
if #lastposz = #charposz
  goto DC_End
set %dif abs ( %lastspotz - #charposz )
if %dif > %ztolerance
  set %record_spot #true
menu delete z
menu text z 215 50 #charposz
set %lastposx #charposz

DC_End:
set %lastpos #charposx , _ , #charposy , _ , #charposz
menu font align left
menu font color red
set %lastmoved #scnt + 7
menu delete ttw
return

Sub WalkOn
;purpose: toggle always run off
event macro 32 0
wait 10 10
if now_off IN #SYSMSG
  return
event macro 32 0
return

Sub RunON
;purpose: toggle always run on
event macro 32 0
wait 10 10
if now_on IN #SYSMSG
  return
event macro 32 0
return

sub closed
if ! %debug
  terminate euo
return

sub record_ltarget
event macro 13 14
targetloop:
  if #targcurs = 1
    goto targetloop
if %ltargetx . %totalspots <> n/a
{
  set %totalspots %totalspots + 1
  gosub DisplayTotalSpots
  gosub RecordSpot
}
set %ltargetx . %totalspots #ltargetx
set %ltargety . %totalspots #ltargety
set %ltargetz . %totalspots #ltargetz
set %ltargetkind . %totalspots #ltargetkind
set %ltargettile . %totalspots #ltargettile
set %totalltargets %totalltargets + 1
set %target . %totalspots #true
set #menubutton n/a
return

sub getfname
menu get fname
if #menuRes <> %filename
{
  set %filename #menuRes
  menu font color white
  menu font size 8
  menu edit fname 70 175 130 %filename
  menu font color lime
  menu font size 9
}
set #menubutton n/a
return

[Marino]

ora mi devi dire, quanto hai di skill taming da li poi partiamo dove poter macrare la skill,
lo script per skillare taming usa questo lo trovi qui http://forum.gamesnet.it/f667/easyuo...update-546503/ copiati solo i primi due post code 1/2 e 2/2 per quanto riguarda su come impostarlo leggi qui http://forum.gamesnet.it/f667/easyuo...-tamer-324678/, cmq per quanto riguarda il posto dove poterla macrare mandami un pm quando ci sie che ci troviamo in game e ti faccio vedere, se non dovessi capire qualcosa o hai domande nello specifico chiedimi pure

[Gianmarco189380]

XD Grazie 1K x la gentilzza e l' interessamento!!!

Si lo script x creare la rail è quello ma forse commetto qualche errore !?!?
In genere dopo aver scritto la rail uso il file su EUO ma non parte...

Cmq lo script di Uber scaricato dal link che mi hai postato sembra avviarsi con la rail generica preimpostata!
Penso possa andare bne anche cosi...

Dunque :

Dopo aver impostato i target da tamare, definisco quella del mio scarrafone come pet ID. Il pg tama il cavallo e dopo lo scarrafone sega me invece dell' animale tamato O.o

Mi è stato suggerito di sostituire nello script, nella sezione del " Killa col mount pet", la parola "all guard me" con " all follow me". Ma purtroppo non cambia nulla.

Inoltre anche se x qualche "oscura ragione" (asd) lo scarrafone sega il pet e non me, lo script non riprende il suo corso e si blocca. Riavviandolo nuovamente non funziona!!!!

L' unico modo è chiudere EUO e fare tutto da capo!

XD so di essere un caso disperato più che difficile XD ma spero di riuscirea skillarmi sto tamer uu uu

I pet ho compreso quali e dove si tamano x quello non ce nessunissimo problema!

P.S. non desisto dall' esternare un plauso x l' appassionante report fotografico! asdasdasdasdXDXD uu uu

[Marino]

tnx per il culo in firma speriamo d'averne a sufficenza anche noi per riuscire a risolvere il problema ora spero sia un problema di digito, tu con questo script non devi usare EUO ma easy uo ( scaricabile da qui http://download.easyuo.com/cheffe/euox176.zip) euo qui in questa sezione del forum non ci sono ancora pubblicati script con il linguaggio LUA per ora, ora detto ciò leggendo un po in giro questo script dopo gli utlimi fix fatti sui pet da qualche problemino, se tu avessi magery sul pg andresti meglio utilizzando come metodo earth elemental per uccidere i pet che tami, per quanto riguarda il metodo di movimento tu ora lo stai utilizzando senza rail in eventualità proviamo con la rail non dovesse continuare a funzionare, cmq dimmi cosè che stai utilizzando come programma EUO o easy uo?

inoltre volevo sapere che pg hai? se umano o elfo? non sei l'unico cmq che ha il problema che i pet attaccati dal beetle attaccano te, per questo ti dicevo prima d'utilizzare gli earth elemental con la skill magery vai molto meglio credimi

[Gianmarco189380]

Scusa forse mi sono espresso male!

Effettivamente la versione di Easy Uo che ho io è differente da quella del link che mi hai postato! Xò provandola non è cambiato nulla.

Io ho il pg tamer discorder e sono elfo, ma essendo in via di "macraggio"posso anche fare un piccolo sacrificio ed utilizzare magery.

Se non mi convince posso sempre sostituirla, il problema non si creerebbe...

[Marino]

Scusa forse mi sono espresso male!

Effettivamente la versione di Easy Uo che ho io è differente da quella del link che mi hai postato! Xò provandola non è cambiato nulla.

Io ho il pg tamer discorder e sono elfo, ma essendo in via di "macraggio"posso anche fare un piccolo sacrificio ed utilizzare magery.

Se non mi convince posso sempre sostituirla, il problema non si creerebbe...

ok allora, io ti consiglio di macrarla con magery poi eventualmente la butti giù se non ti serve, il fatto è che i pg elfi come il tuo in fase di macraggio con questo script presenta qualche problema leggi qui quello che scrive marx1983 http://forum.gamesnet.it/f667/easyuo...3/#post5625251, se stai facendo un tamer discorder devi cmq usare una delle due skill per curati e reccalarti, o chiverly o magery, io ti consiglio chiverly, magery magari la tiri su ora per macrare con lo script, da quello che leggo sul post che ti ho messo con gli erth elemental problemi non ne hai, macri taming tranquillamente, inoltre ti consiglio di macrarla a delucia dove c'è un bel respon di bull, per tamare e controllare tutti i pet ti consiglio di macrarla fino a 110 è sufficente a controllare tutti pet, se hai qualche domanda chiedi pure via pm

[Gianmarco189380]

OK!

Si efettivamente la mia idea era x chiva!

Cmq proverò a skillarla con magery!

Grazie dell' aiuto t farò sapere com'è andata!!!!!

uu uu uu uu