[EASYUO] Auto-PetResser

[Khaliizi]

ecco lo script, basta avere un mucchietto di bende nel backpack e dare play.
Lo script cerca i pet della "%petlist" entro due tiles, controlla se hai bende e inizia a bendare (dà massimo 5 bendate di seguito allo stesso pet, dopo lo hidda).

;***autoresspet by Khaliizi***
;      UoDreams 15/05/10
;*****************************
set %petList CG_JG_KG_OF_SG_SF_MG_BO_WN_HHB_JHB_MHB_EG_ZGB_WJ_QC_YJ_OJ_TJ_SF_MG_JB_
+_TE_DF_CD_YE_XE_HH_FN_CH_JJ_YIO_XVO_ZNO_RQM_CRM_BRM_YQM_ARM_GKM_ZQM_HNO_OHP_BO_GN

Menu HideEUO
Menu Clear
Menu Window size 136 40
Menu Window Title #SHARD , ' Vet
Menu Window Color Black
Menu Font Bgcolor Black
Menu Font Name tahoma
Menu Font Size 8
Menu Font Style B
menu font color $eeeeee
Menu Button PetList 3 6 130 25 IgnorePet
set #MENUBUTTON none
set %tmpSpk #SCNT

main:
if #SCNT > %tmpSpk
{
 event macro 1 0 Resso Pet!
 set %tmpSpk #SCNT + 10
}
if #MENUBUTTON = petlist
 gosub ignorelist
finditem ZLF C_ , #backpackid
if #FINDSTACK < 250
{
 finditem ZLF G_2
 if #findcnt > 0
 {
  exevent drag #findid #findstack
  wait 20
  exevent dropc #backpackid
  wait 20
  event macro 1 0 Grazie!
  wait 5
 }
}
finditem %petlist G_2
if #findcnt > 0
{
 if ( 1 in #FINDREP ) || ( 2 in #FINDREP ) ; cut if in no-guards zone
 {                                         ; cut *******************|
  if #FINDID = %FPet
   set %npet %npet + 1
  else
   set %npet 1
  event sysmessage No.Bendata: %npet di 5
  if %npet > 5         ; cut for vet macroing
  {                    ; cut ***************|
   hideitem #FINDID    ; cut ***************|
   set %npet 0         ; cut ***************|
   goto main           ; cut ***************|
  }                    ; cut for vet macroing
  set %FPet #FINDID
  gosub findband
  gosub vetPet
 }                                         ; cut *******************|
 else                                      ; cut *******************|
  hideitem #FINDID                         ; cut if in no-guards zone
}
wait 1s
goto main

sub vetpet
event macro 2 0 Medica le Ferite
set #LTARGETID %FPet
set #ltargetkind 1
set %index #JINDEX
event macro 17 0
target 10s
event macro 22 0
wait 20
for %m %index #JINDEX
{
 scanjournal %m
 wait 1
 if that_being_is_not_damaged! in #JOURNAL
 {
  hideitem #LTARGETID
  break
 }
}
wait 25
return

sub findband
finditem ZLF C_ , #backpackid
if #FINDSTACK > 0
{
 if #FINDSTACK < 100
  event macro 1 0 Mi restano #FINDSTACK bende
 set #LOBJECTID #FINDID
 return
}
else
{
 event macro 1 0 Ho finito le bende, buttamene un po' a terra
 wait 10
 set %tempo #SCNT + 10
 while #SCNT < %tempo
 {
  finditem ZLF G_2
  if #findcnt > 0
  {
   exevent drag #findid #findstack
   wait 20
   exevent dropc #backpackid
   wait 20
   event macro 1 0 Grazie!
   wait 10
   break
  }
 }
 goto main
}
return

sub ignorelist
set #MENUBUTTON none
event SysMessage Select Now
wait 5
set #targCurs 1
AddPetLoop:
if #targCurs = 1
{
 wait 3
 goto AddPetLoop
}
ignoreitem #LTARGETID
event SysMessage IgnoreList Aggiornata: #LTARGETID
return

Lo script, così com'è, cura solo i pet che vede BLU o VERDI, ma se volete piazzarvelo in casa a felucca per ressare i pet ROSSI, potete farlo ma dovete tagliare le 5 righe che ho evidenziato con "Cut if in no-guards zone" (righe 46-47/62-64).

Può essere utilizzato anche per macrare Veterinary, in questo caso dovete eliminare le righe evidenziate con "Cut for vet macroing" (righe 53-58) e magari modificare la riga 24 (quella che ti fa dire "resso pet"), così da evitare equivoci^^

E', in oltre, possibile aggiungere dei pet in una "IgnoreList" temporanea (si resetta quando stoppate lo script) selezionando il pet da ignorare dopo aver pigiato il bottone "IgnorePet" (ovviamente ignorare due volte lo stesso pet lo toglierà dalla lista pet ignorati).
Questo bottone l'ho messo per ignorare manualmente i pet dei macratori, o i propri, in modo da non sprecare bende e garantire una ressata veloce a tutti, quindi usatelo bene e non mi fate pentire di aver postato sto script, tipo, ignorando i pet di chi vi sta antipatico...

NB: mettere nel backpack diversi tipi di bende (di colore differente, incantate...) potrebbe bloccare o rallentare lo script, quindi se vi capita di trovarvi nel backpack più mucchietti di bende vi consiglio di spostarle in una bag (che può essere contenuta nel backpack), oppure usando il bottone "IgnorePet" sul mucchietto di bende incriminate.