[EASYUO] Vash Targeting

[Vash1986]

Maghi, siete stufi di perdere il precast delle spell quando usate i tasti di razor per targettare nemici rossi e arancioni? Siete stufi di targettare i vortex e gli healer?

Warrior, siete stufi di dover premere due tasti, target next e attack last, per attaccare un nemico?

Allora ho la soluzione per voi: Vash Targeting 1.2

Come funziona? Innanzitutto non è uno script in cui basta premere play o con setup automatizzato. Dovrete sporcarvi un po' le mani modificandolo. Se non siete in grado, fatevi aiutare da qualcuno. Nulla di esageratamente difficile: dovete solo sapere inserire gli ID dei vostri compagni, e poi modificare o aggiungere i tasti per i target.

Detto questo, andando a modificare lo script potrete impostare diversi tasti per i vari "colori" dei nemici che volete attaccare: blu, grigi, rossi, arancio, verdi. Per ogni tasto potete impostare uno o più colori.

Disporrete inoltre di un tasto per ritargettare l'ultimo target, utile per far rispuntare la barra della vita o per riprendere il target dopo aver curato un vostro compagno.

Affinchè sia chiaro quale nemico state targettando, lo script lo attacca automaticamente, in modo da farlo "illuminare". Pertanto state attenti coi blu nelle zone guardie: ovviamente con loro è meglio usare il target next di razor.

Ma a parte questo piccolo inconveniente, il mio script è molto comodo perchè se avete una spell in precast, non verrà droppata sul nemico che attaccherete. Questo vi consente di scorrere vari target e decidere su quale droppare. Se invece non avete una spell in precast, allora lo script targetterà velocemente il nemico, in modo da impostarlo come last target per razor o per il client. Utile sia per i maghi, sia per i warrior che magari vogliono lanciare bolas o castare magie da scroll.

Una sola avvertenza: non chiamatemi su ICQ per chiedermi come far funzionare lo script, nè per come modificarlo. Leggete attentamente le istruzioni e fatevi aiutare da qualcuno magari con un minimo di dimestichezza con easyuo.

Ovviamente potete segnalare qui eventuali malfunzionamenti. Spero di aver incollato correttamente tutto il contenuto dello script nella finestrella qui sotto.

; =======================
; Vash Targeting 1.2
; =======================
;
; Come funziona
; -------------
; Lo script nasce come alternativa al pessimo sistema di targeting di
; Razor, che droppa le spell che avete in precast.
; E' possibile settare un tasto per ogni tipo di personaggio
; (pk, arancione, grigio, blu), oppure associare ad ogni tasto
; più colori, ma qualsiasi modifica allo script richiede un minimo
; di abilità, insomma fatevi aiutare (anche per la friend list).
; Al fine di rendere "visibile" il targeting, il nemico verrà automaticamente
; attaccato, in modo che risulti illuminato e quindi subito visibile.
; Ciononostante, non verranno droppate le spell in precast.
; Di contro, state molto attenti a non targettare blu in zona guardie.

; Istruzioni:
; -----------
; 1- Compilare la friend list qui sotto ricordando di mettere anche il tuo ID.
;
; 2- Sotto la friend list ci sono i tasti da settare. A ogni tasto si può
;    associare una sub che compie una specifica funzione.
;    a) La sub Targetta serve ad attaccare i nemici. Se avete una spell in
;    precast, una volta targettato dovrete usare la sub LastTarget.
;    Altrimenti sarà già bello e pronto il last target di client o razor.
;    Noterete che tale sub va invocata con un parametro.
;    Tale parametro potrà contenere varie cifre, che indicano il colore
;    dei nemici che intendete attaccare.
;    1=blu, 2=verde, 3=grigio, 4=criminal, 5=arancione, 6=rosso
;    Se per esempio volete attaccare qualsiasi tipo di nemico,
;    dovete scrivere goSub Targetta 3456
;    Se invece volete un tasto diverso per ogni colore, potete invocare
;    varie sub targetta, ognuna con un parametro diverso, e associata
;    ovviamente ad un tasto diverso.
;    b) La sub LastTarget come già detto serve per i precast.
;    c) La sub Ritargetta tabba e riattacca in modo da far rispuntare la barra
;    della vita sotto il nemico, nel caso vi fosse scomparsa.
;    d) Ricordate che le sub LastTarget e Ritargetta possono essere usate
;    per attaccare o targettare il nemico dopo che avete perso target
;    crosshealando qualcuno.
;
; 3- Lo script attacca umani, elfi e alcune trasformazioni di ninjitsu.
;    Non attacca healer. In futuro è possibile che ci saranno nuove trasformazioni
;    e nuove tipologie di player, in tal caso bisogna inserire i nuovi ID nella
;    variabile %id sotto la friend list.


; Questa è la friend list:
ignoreitem RDAB 1 ; Vash U'Sgrav
ignoreitem KFGC 1 ; Geonortsort
ignoreitem PWBN 1 ; Okuto


; Fine Friend. Qui potete modificare la lista %id (vedi istruzioni punto 3)
set #lpc 30
set %id IS_HS_AV_XU_VD_EH_KG_EG_SC_SH

; Setta i tasti:
_mainloop:

onhotkey F10
    goSub Targetta 3456
onhotkey F4
    goSub Ritargetta
onhotkey F11
    goSub LastTarget
    
; Ok non toccare più niente da qui in giù.

sleep 20
goto _mainloop




Sub Targetta

  set #lpc 100
  set %retried #false
  set %targeted #false
  set %distance 4

  _targetta:
  finditem %id G_ , %distance
  if #findcnt = 0
  {
      set %distance %distance + 6
      if %distance > 16
      {
          if ! %retried
          {
              set %retried #true
              ignoreitem reset 2
              goto _targetta
          }
          
          event sysmessage Nessun nemico
          wait 1
          return
      }
      goto _targetta
  }
  
  for %i 1 #findcnt
  {
      set #findindex %i
      if #findrep notin %1
      {
          ignoreitem #findid 2
          continue
      }
      else
      {
          if #findid = #charid
          {
              event sysmessage Non sei nella friend list! Script stoppato.
              halt
          }
          
          event property #findid
          if ( the , #spc , priest , #spc , of , #spc , Mondain ) in #property || ( the , #spc , wandering , #spc , healer ) in #property
          {
              ignoreitem #findid 3
              continue
          }
          
          if #findid = #enemyid
          {
             event macro 6 0
             wait 5
             event macro 6 0
             wait 5
          }
          
          set #ltargetid #findid
          set #ltargetkind 1
          event macro 27 0
          
          if #targcurs = 0
          {
              set #targcurs 1
              target 5
              event macro 22 0
          }

          set %targeted #true
          set %lastTarget #findid
          ignoreitem #findid 2
          break
      }

      goto _targetta
  }
  
  if ! %targeted
      event sysmessage Nessun nemico.
      
  set #lpc 30
  wait 4
  
return




Sub Ritargetta

  if #enemyid = N/A
  {
      event sysmessage Nessun nemico
      wait 1
      return
  }

  set %retarget #enemyid
  event macro 6 0
  wait 5
  event macro 6 0
  wait 5
  set #ltargetkind 1
  set #ltargetid %retarget
  event macro 27 0 ; attack last
  wait 5

return



Sub LastTarget

  set #ltargetkind 1
  set #ltargetid %lastTarget
  event macro 22 0
  wait 4

return

[Simo63]

domanda stupida , il target verrà poi considerato last target da razor? se ho delle magie con last target le prende?

[MarioTidus2000]

al posto di far mettere il proprio id nella friend list nn bastava fare un ignoreitem #charid?

così puoi anche eliminare sto controllo
if #findid = #charid
{
event sysmessage Non sei nella friend list! Script stoppato.
halt
}

[Vash1986]

domanda stupida , il target verrà poi considerato last target da razor? se ho delle magie con last target le prende?

Se targetti senza precast, allora lo script fa uscire per un brevissimo istante il target e lo targetta. In questo modo sarà impostato come last target di Razor.

Se targetti con precast, per droppare la spell devi usare il tasto LastTarget dello script, e a quel punto gli verrà droppata la spell e sarà impostato come last target di razor.

al posto di far mettere il proprio id nella friend list nn bastava fare un ignoreitem #charid?

così puoi anche eliminare sto controllo
if #findid = #charid
{
event sysmessage Non sei nella friend list! Script stoppato.
halt
}

E se slogghi un pg da pvp e logghi un altro senza ricordarti di riavviare lo script?
Ma più che altro è un modo comodo per scambiarsi le friend list tra gildati. Il #charid stona un po', abbiamo sempre fatto così anche con gli script del passato.

[Spino]

Scusate l'ignoranza, come recupero l'ID di un alleato per metterlo nella friendlist?
L'ID lo devo mettere una sola volta e poi sarà sempre valido oppure è dinamico ed ogni volta che loggo devo ributtarlo entro?

[MarioTidus2000]

Scusate l'ignoranza, come recupero l'ID di un alleato per metterlo nella friendlist?
L'ID lo devo mettere una sola volta e poi sarà sempre valido oppure è dinamico ed ogni volta che loggo devo ributtarlo entro?

dopo che hai inserito gli id degli alleati salvi lo script, così che quando lo riapri sarà sempre uguale a quando l'hai chiuso

per trovare l'id o targhetti con una qualsiasi magia un tuo alleato, vai nella finestra di euo e leggi cosa c'è scritto a lasttarget id, oppure usi questo scriptino fatto da me :P

display TARGHETTA OGGETTO
set #targcurs 1
while #targcurs = 1
{
 wait 5
}
finditem #ltargetid C_ , #backpackid
finditem #ltargetid G_
display Target ID: #findid Target Type: #findtype
halt

a Vash:
puoi inserire un controllo, quando il #charid cambia (N\A) lo script si mette in attesa d iuno nuovo, cancelleresti quel controllo ugualmente, poi se uno vuole aggiungere il suo nome alla lista ben venga

[Vash1986]

a Vash:
puoi inserire un controllo, quando il #charid cambia (N\A) lo script si mette in attesa d iuno nuovo, cancelleresti quel controllo ugualmente, poi se uno vuole aggiungere il suo nome alla lista ben venga

Ecchecavolo saifer, ti ho già detto che è più comodo avere una friend list col proprio ID in modo da facilitare lo scambio tra compagni =|

[Spino]

dopo che hai inserito gli id degli alleati salvi lo script, così che quando lo riapri sarà sempre uguale a quando l'hai chiuso

per trovare l'id o targhetti con una qualsiasi magia un tuo alleato, vai nella finestra di euo e leggi cosa c'è scritto a lasttarget id, oppure usi questo scriptino fatto da me :P

display TARGHETTA OGGETTO
set #targcurs 1
while #targcurs = 1
{
 wait 5
}
finditem #ltargetid C_ , #backpackid
finditem #ltargetid G_
display Target ID: #findid Target Type: #findtype
halt

a Vash:
puoi inserire un controllo, quando il #charid cambia (N\A) lo script si mette in attesa d iuno nuovo, cancelleresti quel controllo ugualmente, poi se uno vuole aggiungere il suo nome alla lista ben venga

ok grazie

[MarioTidus2000]

Ecchecavolo saifer, ti ho già detto che è più comodo avere una friend list col proprio ID in modo da facilitare lo scambio tra compagni =|

sei peggio di stroustrupt, non accetti mai le critiche XD

[starmage]

l'unica cosa che non ho capito è come si fà a far riapparire la barra della vita di un nemico se è fuori schermo...potete spiegarmelo?grazie

PS: và bene anche se scrivete direttamente le istruzioni,conosco il linguaggio.

[Napster4]

a mio parere sarebbe melgio se non ataccasse subito il target... almeno io sfrutto il fattore dell'atacco a sorpresa perche nel momento in qui uno si accorge di essere target incomincia a runnare... non ce modo di far apparire una scritta sulla testa invece di atakkare subito?

[Vash1986]

a mio parere sarebbe melgio se non ataccasse subito il target... almeno io sfrutto il fattore dell'atacco a sorpresa perche nel momento in qui uno si accorge di essere target incomincia a runnare... non ce modo di far apparire una scritta sulla testa invece di atakkare subito?

In battaglie affollate, scorrendo vari target ti ritroveresti con 5-6 scritte sopra le teste fino a non capirci più niente.

Peraltro, da alcune strane coincidenze avvenute nel 2006 quando giocavo coi NoX, siamo giunti alla conclusione che i messaggi sopra le teste altrui, tramite easyuo, rischiano di far crashare il client.

Purtroppo mi rendo conto che l'auto-attack non sia proprio una bella cosa, ma non c'è altro modo per "illuminare" il target, almeno che io sappia. Comunque se sei warrior e vuoi sfruttare l'effetto sorpresa, i target di razor per te sono l'ideale. Trovi il tuo bel target, e poi BUM fai attack last a sorpresa.

Altrimenti che differenza ci sarebbe tra razor e il mio script? Per fare come dici tu sempre due tasti ci vogliono, uno per targettare e uno per attaccare. La comodità dello script invece, per i warrior, è quella di offrire un tasto solo.

l'unica cosa che non ho capito è come si fà a far riapparire la barra della vita di un nemico se è fuori schermo...potete spiegarmelo?grazie

PS: và bene anche se scrivete direttamente le istruzioni,conosco il linguaggio.

Devi solo stabilire una hotkey per la sub Ritargetta. E poi premi quel tasto quando vuoi far riapparire la barra.

[Napster4]

In battaglie affollate, scorrendo vari target ti ritroveresti con 5-6 scritte sopra le teste fino a non capirci più niente.

Peraltro, da alcune strane coincidenze avvenute nel 2006 quando giocavo coi NoX, siamo giunti alla conclusione che i messaggi sopra le teste altrui, tramite easyuo, rischiano di far crashare il client.

Purtroppo mi rendo conto che l'auto-attack non sia proprio una bella cosa, ma non c'è altro modo per "illuminare" il target, almeno che io sappia. Comunque se sei warrior e vuoi sfruttare l'effetto sorpresa, i target di razor per te sono l'ideale. Trovi il tuo bel target, e poi BUM fai attack last a sorpresa.

Altrimenti che differenza ci sarebbe tra razor e il mio script? Per fare come dici tu sempre due tasti ci vogliono, uno per targettare e uno per attaccare. La comodità dello script invece, per i warrior, è quella di offrire un tasto solo.

il fatto e che non uso + razor da tempo uso injection... e al momento uso uno script di easyuo per targettare che mi scrive target sopra la testa e devo dire che mi trovo molto bene... volevo provare il tuo ma la cosa che mi atacca subito il target non mi piace per quello che ho chiesto ;P
per il fatto delle tante scritte sulla testa hai ragione ma ormai ci ho fatto l'abitudine :O

[MarioTidus2000]

il fatto e che non uso + razor da tempo uso injection... e al momento uso uno script di easyuo per targettare che mi scrive target sopra la testa e devo dire che mi trovo molto bene... volevo provare il tuo ma la cosa che mi atacca subito il target non mi piace per quello che ho chiesto ;P
per il fatto delle tante scritte sulla testa hai ragione ma ormai ci ho fatto l'abitudine :O

in effetti lo script di vash sotto questo punto di vista è di una inefficienza storica, così come se devi tirare un xheal a un tuo compagno e targhettarlo dopo aver precastato, così andresti ad attaccare tutti i tuoi compagni :S
senza fare critiche, ma secondo me razor per targhettare funziona da dio

[Vash1986]

in effetti lo script di vash sotto questo punto di vista è di una inefficienza storica, così come se devi tirare un xheal a un tuo compagno e targhettarlo dopo aver precastato, così andresti ad attaccare tutti i tuoi compagni :S
senza fare critiche, ma secondo me razor per targhettare funziona da dio

Questione di gusti: usate ciò con cui vi trovate meglio.

Io preferisco il vecchio troboh che usavano gli angels per injection come metodo per targettare. Infatti questo script di easyuo non fa altro che emulare lo script che uso con injection. Se vi trovate meglio con razor, usate razor.