[EASYUO HELP] Boscags7: Diario di sviluppo

[Simo63]

già è vero quel che dici ma a me 24h ore sembrano cmq un pò troppe

[djtano]

nn vorrei far complicare la vita a kusanagi ma potrebbe aggiungere anke un opzione modifica tempo nelle avanzate

[kusanagi97]

Mentre vi parlo, il mio worker sta fillando bod large!
La fase di debugging è stata un pò lunghetta, e quella di ottimizzazione lo è stata ancora di più. Tuttavia, posso ritenermi soddisfatto del lavoro fatto.
La procedura è abbastanza veloce e particolarmente stabile. Ho migliorato di molto le procedure per interagire con i bodbook (settaggio filtri ed estrazione di un bod), ed ora procedono alla massima velocità possibile.

Ho scoperto, inoltre, un bug nella sub analyzeBod, cioè la sub "madre" di tutto il mio script. I bod large che presentano elementi misti in cloth e leather vengono identificato come bod da leather, mentre dovrebbero essere identificati come bod da cloth. Provvedo a correggere.

Edit: ho corretto il bug nella procedura analyzeBod. Esso risaliva fino alle sub di Boydon. Per chi fosse interessato, ecco come modificare la sub GetBodMaterial di BodFunctions.euo per adattarla anche ai bod large.

;==================
;**
;* @name GetBodMaterial
;* @ver 1.2 07Oct05
;* @author  Boydon
;* @purpose This sub will tell you wich material is required by the BOD
;*					The material will be returned in a var defined by the user without the "%" symbol.
;*					Default variable name is "material"
;*
;* @params %1 req bod type (tailor|smithy) or the #findcol of the bod (1155|1102)
;*				 %2 req bod #property
;*				 %3 opt name of the var containing the material without the "%" symbol (default is "material")
;*
;* @returns
;*
;* @example call GetBodParameters.euo GetBodMaterial tailor #property
;*							this is the standar call
;*					call GetBodParameters.euo GetBodMaterial tailor #property material_needed
;*							this is a call with the material being returned to %material_needed
;* @status BlackSmithy support needs to be tested

sub GetBodMaterial

	if %0 < 2 || %1 = N/A || %2 = N/A
	{
		display ok Wrong use of Sub GetBodParameters: some required arguments are missing!
			+$Script will be halted.
		halt
	}

	if %1 <> tailor && %1 <> smithy && %1 <> 1155 && %1 <> 1102
	{
		display ok Wrong value for parameter 1 in sub GetBodParameters!
			+$Script will be halted!
		halt
	}

	if %3 = N/A || %0 <= 2
		set %3 material

	nameSpace Push
	nameSpace Local GetBodMaterial , #time , #random , #scnt2

	set !lpc #lpc
	set #lpc 500

	set !BodType %1
	set !Property %2
	set !Material %3

	if !BodType = tailor || !BodType = 1155
	{
		if leather notin !Property && studded notin !Property && bone notin !Property && boots notin !Property && shoes notin !Property && sandals notin !Property
	    set % . !Material cloth

		if leather in !Property || studded in !Property || bone in !Property || boots in !Property || shoes in !Property || sandals in !Property
		{
       if Large , #spc , Bulk in !property && ( #spc , Hat in !property || Bandana in !property || Bonnet in !property || Skullcap in !property )
          set % . !Material cloth
       else
  		    set % . !Material 0
  	}

		if All , #SPC , Items , #SPC , Must , #SPC , Be , #SPC , Made , #SPC , With in #property
		{
			if spined , #SPC , Leather in !Property
				set % . !Material 2220
			if horned , #SPC , Leather in !Property
				set % . !Material 2117
			if barbed , #SPC , Leather in !Property
				set % . !Material 2129
		}
	}

	if !BodType = smithy || !BodType = 1102
	{
		set % . !Material 0

		if All , #SPC , Items , #SPC , Must , #SPC , Be , #SPC , Made , #SPC , With in #property
		{
			if Dull , #SPC , Copper , #SPC , Ingots in #property
				set % . !Material 2419
			if Shadow , #SPC , Iron , #SPC , Ingots in #property
				set % . !Material 2406
			if Copper , #SPC , Ingots in #property && Dull notin #property
				set % . !Material 2413
			if Bronze , #SPC , Ingots in #property
				set % . !Material 2418
			if Gold , #SPC , Ingots in #property
				set % . !Material 2213
			if Agapite , #SPC , Ingots in #property
				set % . !Material 2425
			if Verite , #SPC , Ingots in #property
				set % . !Material 2207
			if Valorite , #SPC , Ingots in #property
				set % . !Material 2219
		}

	}

	set #lpc !lpc

	namespace Clear
	namespace Pop

return

Purtroppo, questo bug mi costringe a ripensare parte della procedura. Infatti, per fillare i bod misti cloth+leather, dovrei estrarre dal bodbook tutti i bod sia in cloth che in leather. E' piuttosto verosimile che, facendo a questo modo, si superi i limite dei 125 items nel backpack.
Modificherò la procedure come segue:
- metti tutti i large bod fra loro simili nel backpack, determina le priorità, eccetera eccetera
- imposta il filtro del bodbook per i bod small
- estrai un bod small per volta dal bodbook, e prova ad inserirlo in ognuno dei bod large già nel backpack, in ordine di priorità.

Sapevo che non poteva essere tanto facile quanto sembrava! Sigh!

[Simo63]

ok settando meglio il bod filter non ho più grossi problemi ,ho tolto anche le sop +20 che conserva gli small in leather e a me non interessano le sop ,meglio consegnare...per il resto up per il 4 bodobook ,secondo me andrebbe modificata la procedura dei bod che non riesce a fillare..cioè al momento ho 3 bod che non riesce a fillare perchè : 1 è in bones e manco ho capito perchè non lo scarta ma vbè..un'altro è in spined e l'altro mi sembra horned e è qui da 5 minuti che li prende dal bodbook li mette nel backpack e poi li rimette dentro ..uno per uno..certo mi sembra ovvio che vada in loop ..è colpa mia che non ho altri bod nell zaino ..cmq il 4 bodbook sarebbe molto utile

[kusanagi97]

@Simo: aspetta, aspetta! qual'è il bod in bones che non ti scarta? Vedo se posso riprodurre il bug pure io, così lo correggo.

@tutti: La sub *dovrebbe* essere pronta, ma è un "dovrebbe" molto vago, poiché non riesco a connettermi e quindi a testarla. Ma è down, o è linux che da problemi?
Intanto vi posto la sub. E' purtroppo molto complessa, ma credetemi che cercando di semplificare mi sfuggiva sempre qualche cosa...

;=======================================
;* @name    Model_FillLargeBodCycle
;* @author  AG
;* @purpose Ciclo per riempire tutti i bod large che si trovano nel bodbook "da conservare".
;* @returns
;* @example gosub safecall Model_FillLargeBodCycle
;* @status  Under development
;* @todo    Introdurre alternanza fra book tailor e book smith, in caso di opzioni avanzate (?)

sub Model_FillLargeBodCycle
    set !book %Config_BodBooks_Tailor_Keep
    set !clsBod %Constants_Bod
    
    while #true
    {
        ;---------------------------------
        ; Fase 1: Estrazione large BODs
        ;---------------------------------

        if !moreSmall <> #true
        {
            ; rimetti a posto tutti i bod nel backpack
            ignoreitem reset
            gosub safecall Model_PlaceObjects

            ; estrai un bod large
            gosub safecall Std_SetBodbookFilter !book large all all all
            gosub safecall Std_ExtractBod !book
            if #result = #false
                break
            finditem !clsBod C_ , #backpackid
            if #findkind = -1 ; should never happer
                break
            set !largebod #findid

            ; analizza il bod corrente
            gosub libcall BodFunctions.euo AnalyzeBod !largebod Model_FillLargeBod_ obmq
            if %Model_FillLargeBod_Exceptional
               set !exceptional exceptional
            else
               set !exceptional normal

            ; salva la tipologia di filtro, in maniera da non ripeterla in seguito
            set !filterId !exceptional , _ , %Model_FillLargeBod_MaterialName , _ , %Model_FillLargeBod_Quantity
            if !firstFilterId = !null
            {
                set !firstFilterId !filterId
            }
            else
            {
                if !firstFilterId = !filterId
                {
                    event exmsg #charid 3 0 Ho analizzato l'intero libro.
                    break
                }
            }

            ; estrai i bod simili a quello corrente (solo large)
            gosub safecall Std_SetBodbookFilter !book large !exceptional %Model_FillLargeBod_MaterialName %Model_FillLargeBod_Quantity
            gosub safecall Std_ExtractBod !book all
        }
        
        ;-----------------------------
        ; Fase 2: Analisi large BODs
        ;-----------------------------

        ignoreitem reset
        event exmsg #charid 3 0 Sto analizzando i large BOD nel backpack.

        ; salva tutti i large bod estratti in !listLarge
        set !listLarge_count 0
        finditem !clsBod C_ , #backpackid
        if #findkind <> -1
        {
            for #findindex 1 #findcnt
            {
                set !listLarge_count !listLarge_count + 1
                set !listLarge_ . !listLarge_count #findid
            }
        }
        if !listLarge_count = 0
           break

        ; riempi le liste list0...list6 in base al valore di Quantity - FillCount
        set !list0_count 0
        set !list1_count 0
        set !list2_count 0
        set !list3_count 0
        set !list4_count 0
        set !list5_count 0
        set !list6_count 0
        for !i 1 !listLarge_count
        {
            set !bod !listLarge_ . !i
            set !timeout #systime + 2000
            repeat
                gosub libcall BodFunctions.euo AnalyzeBod !bod Model_FillLargeBod_ obmq
            until #result = #true || #systime > !timeout
            if #result = #false
                continue
               
            set !leftCount %Model_FillLargeBod_Cardinality - %Model_FillLargeBod_FillCount
            set !listname list , !leftCount , _
            
            ; aggiorna list[i]_count
            set !varname !listname , count
            set !count ! . !varname
            set !count !count + 1
            set ! . !varname !count
            
            ; aggiungi a list[i]
            set !varname !listname , !count
            set ! . !varname !bod
        }

        ;----------------------------------
        ; Fase 3: Estrazione small BODs
        ;----------------------------------

        ; ignora momentaneamente i large bods
        for !i 1 !listLarge_count
        {
            set !largebod !listlarge_ . !i
            ignoreitem !largebod
        }
        
        ; estrai i bod simili a quello corrente (solo small)
        gosub safecall Std_SetBodbookFilter !book small !exceptional %Model_FillLargeBod_MaterialName %Model_FillLargeBod_Quantity
        gosub safecall Std_ExtractBod !book 25

        ; salva gli small bod estratti dentro !listSmall
        set !listSmall_count 0
        finditem !clsBod C_ , #backpackid
        if #findkind <> -1
        {
            for #findindex 1 #findcnt
            {
                set !listSmall_count !listSmall_count + 1
                set !listSmall_ . !listSmall_count #findid
            }
        }

        ;----------------------------------
        ; Fase 4: Fillaggio
        ;----------------------------------

        if !listSmall_count > 0
        {
            for !i 1 6 ; itera attraverso le liste
            {
                set !listname list , !i , _
                set !varname !listname , count
                set !list_count ! . !varname
                if !list_count = 0
                   continue

                for !j 1 !list_count ; itera nella lista corrente
                {
                    set !varname !listname , !j
                    set !largebod ! . !varname

                    gosub safecall Std_UseObject !largebod
                    set !timeout #systime + 3000
                    while ( #systime < !timeout ) && ( 510_ notin #contsize )
                    {
                    }
                    if 510_ notin #contsize
                       continue ; fallimento
                    set !x #contposx + 140
                    str right #contsize 3
                    set !y #contposy + #strres - 70

                    for !k 1 !listSmall_count ; itera fra gli small bods
                    {
                        set !smallbod !listSmall_ . !k

                        finditem !smallbod C_ , #backpackid
                        if #findkind = -1
                            continue

                        gosub safecall Std_ClickGumpButton !x !y
                        gosub safecall Std_SelectTarget !smallbod
                        if #result = #false ; mirino non visualizzato: probabilmente il large bod è pieno
                            break
                    }
                }
            }
        }
        
        ; ci sono ancora small da estrarre se: "ne erano estratti 25 o più" e "ne è stato inserito almeno uno" (evita cicli)
        finditem !clsBod C_ , #backpackid
        set !smallbod_count #findcnt
        set !moreSmall ( !listSmall_count >= 25 && !smallbod_count < !listSmall_count )
        
        ; piccolo trucco per "ingannare" lo script nel caso di bod misti cloth + leather
        if %Model_FillLargeBod_MaterialName = cloth && !moreSmall = #false
        {
            set %Model_FillLargeBod_MaterialName leather
            set !moreSmall #true
        }

        gosub safecall Model_PlaceObjects ; sposta solo i bod small, poiché i large sono in ignoreitem
        ignoreitem reset
    }
    
    ignoreitem reset
    gosub safecall Model_PlaceObjects
return

Per esperienza so che, prima del testing, i bug sono parecchi. Tuttavia, se notate qualcosa già dal codice (davvero avete la pazienza di leggervelo???) fatemi notare.

[Simo63]

tranquillo è crashato il server da un paio d'ore...appena loggo ti dico qual'è il bod...anche se da come mi vanno le cose , ritengo che i bod in bones siano da conservare in un libro a parte ^^ tanto penso che tutti quando non hanno soldi per comprare bod ,tentano di fillare tutto ..quindi che costa fare un pò di bones e fillare pure quelli? magari metterli in un bodbook di seconda scelta ,quando siamo disperati andiamo a fillare quelli ^^

[kusanagi97]

Nel frattempo, faccio un pò di lavoro extra:
- Corretto il bug segnalato qui (riciclaggio item indossati): adesso ricicla solo da backpack. Può comunque riciclare altri item rispetto ai soli item craftati, ma mi sembra un comportamento accettabile (in fondo, blessed ed insured continuano ad essere al sicuro!).

[TakilianRueshin]

PEr quanto riguarda i bod in bones, sembra che non scarti proprio, anche se è stato settato. Prima del crash stavo proprio cercando di caprie il perchè, appena isolo il codice incriminato te lo posto.
Cmq un esempio di bod in bones che non scarta: bone arms 20 exec

[kusanagi97]

La vecchia versione scartava? Se è così l'errore sta a livello di menu.

[TakilianRueshin]

La vecchia versione scartava? Se è così l'errore sta a livello di menu.

La vecchia mi sa' proprio di si.

[kusanagi97]

Trovato: il filtro che determina la "qualità" di un bod (cioè se è da conservare o meno) ha la precedenza su quello che determina il comportamento con i bone bods.

Esempio: bone arms 20 exc.
- Questo è un bod che può potenzialmente fornire un bless deed -> "da conservare"
- Questo è un bod che richiede ossa -> "da trashare"

Quale comportamento dovrebbe avere la meglio?
Il comportamento attuale, pur non fillando il bod, lo conserva. In effetti potrebbe avere un senso conservare almeno quei bod in bones che permettono di ottenere un premio importante...
Cosa ne pensate?

[TakilianRueshin]

Che va bene, l'importante è saperlo

[kusanagi97]

MEGAUPLOAD - The leading online storage and file delivery service
Versione provvisoria per chi voglia testare il large bodfilling.
La posto, ma guardate che c'è ancora parecchio da lavorare.
Attivate tramite Strumenti->Riempi BOD large, con "ciclo" on.

[Simo63]

ehm se puoi cambiare il menù emettere l'opzione trasha bod in bones o conserva mi faresti un favore^^ ho solo i bones da fillare ,non mi è rimasto altro ..se poi con lo script me li trasha qando avrò finito i bod in cloth devo fermarmi...puoi mettere una modifica del genere? magari appunto che l metta in un bodbook di seconda scelta



ps kusanagi bella firma aahsuahsua ..è un mago topo quello che casta quelle magie asd?

[TakilianRueshin]

sub ChooseMaterial

	if %0 < 1 || %1 = N/A
	{
		display ok Wrong use of Sub ChooseMaterial: some required arguments are missing!
			+$Script will be halted.
		halt
	}

	nameSpace Push
	nameSpace Local ChooseMaterial , #time , #random , #scnt2

	set !Material #false

	if %1 = iron || %1 = leather || %1 = 0
		set !Material 1
	if %1 = dull || %1 = spined || %1 = 2220 || %1 = 2419
		set !Material 2
	if %1 = shadow || %1 = horned || %1 = 2117 || %1 = 2406
		set !Material 3
	if %1 = copper || %1 = barbed || %1 = 2129 || %1 = 2413
		set !Material 4
	if %1 = bronze || %1 = 2418
		set !Material 5
	if %1 = gold || %1 = 2213
		set !Material 6
	if %1 = agapite || %1 = 2425
		set !Material 7
	if %1 = verite || %1 = 2207
		set !Material 8
	if %1 = valorite || %1 = 2219
		set !Material 9
	if %1 = nocolor || %1 = -1
		set !Material 11

	if ! !Material
	{
		display ok Unknown material %1 ! $Script will be halted.
		halt
	}

	set !CraftContKind #contkind
	set !CraftContName #contname
	set !CraftContSize #contsize

	clickMaterialCategory:
	set !MaterialX #contposx + 30
	set !MaterialY #contposy + 370
	click !MaterialX !MaterialY f

	gosub waitForSysVars contkind = !CraftContKind contname = !CraftContName contsize = !CraftContSize 5
	if ! #result
		goto clickMaterialCategory

	clickMaterialColor:
	set !ColorX #contposx + 235
	set !ColorY #contposy + ( 50 + ( 20 * !Material ) )
	click !ColorX !ColorY f

	gosub waitForSysVars contkind = !CraftContKind contname = !CraftContName contsize = !CraftContSize 5
	if ! #result
		clickMaterialColor

	nameSpace Clear
	nameSpace Pop
return

Non so' ancora come sia sucesso, ma te lo inizio a segnalare.
Nella sub precedente, le seguenti righe:

	set !CraftContKind #contkind
	set !CraftContName #contname
	set !CraftContSize #contsize

contenevano i dati relativi al paperdoll, invece del gump di crafting. Le successive istruzioni portano ad un loop infinito.