Tweet
;Test Cast Speed v0.5 by DJ_Flash
;Dopo qualche minuto lo script farà dire al vostro PG le velocità di cast.
;Le velocità di cast a parita di Fc/Fcr sono influenzate dal client, conessione e pc.
initevents
linesPerCycle 200
menu hideEUO
set %ok_targ no
Chooseskill mage
set %magery #skill
Chooseskill necr
set %necro #skill
if ( %magery > 0 && %necro > 0 )
set %pg Il , #spc , PG , #spc , è , #spc , un , #spc , mago-necro , #spc , con:$ , %magery , #spc , magery$ , %necro , #spc , necromancy
if ( %magery = 0 && %necro > 0 )
set %pg Il , #spc , PG , #spc , è , #spc , un , #spc , necro , #spc , con:$ , %necro , #spc , necromancy
if ( %magery > 0 && %necro = 0 )
set %pg Il , #spc , PG , #spc , è , #spc , un , #spc , mago , #spc , con:$ , %magery , #spc , magery
if ( %magery = 0 && %necro = 0 )
{
display ok Il , #spc , PG , #spc , non , #spc , è , #spc , ne , #spc , mago , #spc , ne , #spc , necro. , #spc Ok , #spc , per , #spc , uscire.
halt
}
set #menubutton N/A
menu window title Speed Cast Test v.0.5
menu window size 400 250
menu show 0 0
menu text text1 5 0 %pg
menu text text2 5 60 Inserisci qua la tua Faster Casting Recovery:
menu edit fcr 265 60 20 6
menu text text3 5 100 Targetta un oggetto fermo e lockato in casa anche non$propria (Es. pouch lockato a terra).$Non targettare se stessi o pet o altri pg.
menu button targetta 5 150 50 20 Target
menu text text_target 70 150 Target: , #ltargetid
menu text text_corretto 200 150 Corretto: , %ok_targ
menu text text4 5 190 Precisione Test(1=Poco Preciso):
menu edit veloc 200 190 20 3
menu button start 5 220 80 20 Start Test
loop:
if #menubutton = targetta
{
gosub target
menu delete text_target
menu delete text_corretto
menu text text_target 70 150 Target: , #ltargetid
menu text text_corretto 200 150 Corretto: , %ok_targ
set #menubutton N/A
}
if #menubutton = start
{
if %ok_targ = si
goto inizio
if %ok_targ = no
{
display ok Il target non è corretto.$Rifai il target!
set #menubutton N/A
}
}
goto loop
inizio:
set #menures N/A
menu getnum fcr 6
set %fcr ( 6 - #menures ) * 5
menu getnum veloc 3
set %veloc #menures
menu clear
menu window title Speed Cast Test v.0.5 Testing ...
menu window size 220 400
menu button stop 5 5 60 20 Stop Test
set %previsto 0
for %i 1 8
{
set %y 10 + %i * 20
set %cicle ( 10 - %i ) * %veloc
set %previsto %previsto + %cicle * ( %i * 250 + 250 )
menu text text_cast . %i 5 %y %i , ° Circolo: Ready Cicles: , #spc , %cicle
}
set %previsto %previsto / 1000
set %y %y + 40
menu text text_previsto 5 %y Tempo previsto: , %previsto , sec
for %i 1 8
{
menu delete text_cast . %i
set %y 10 + %i * 20
menu text text_cast . %i 5 %y %i , ° Circolo: Testing ...
if %i = 1
set %magia 3
if %i = 2
set %magia 10
if %i = 3
set %magia 17
if %i = 4
set %magia 29
if %i = 5
set %magia 37
if %i = 6
set %magia 42
if %i = 7
set %magia 50
if %i = 8
set %magia 58
set %inizio #systime
set %fine ( 10 - %i ) * %veloc
for %z 1 %fine
{
event macro 15 %magia
target 110
event macro 22 0
if #menubutton = stop
halt
wait %fcr
}
set %tempo . %i ( ( #systime - %inizio ) / ( %z - 1 ) )
menu delete text_cast . %i
menu text text_cast . %i 5 %y %i , ° Circolo: , %tempo . %i , ms
}
wait 100
menu clear
menu show 0 0
menu window title Speed Cast Test v.0.5 Finish
menu window size 800 50
set %risultati #spc
for %i 1 8
{
set %risultati %risultati , %i , °: , %tempo . %i , #spc
}
set %risultati %risultati , #spc , Velocità: , %veloc , #spc , Wait_Fcr: , %fcr , #spc , Client: , #cliver , #spc , EUO: , #euover
menu text text_risul 5 0 Risultati:
menu edit edit_risultati 5 20 750 %risultati
halt
sub target
set #targcurs 1
target 10
target_loop:
if #targcurs = 1
goto target_loop
deletejournal
event macro 15 3
target 110
event macro 22 0
wait 4
scanjournal 1
set %ok_targ no
if That_is_not_accessible. in #journal
set %ok_targ si
return
Commenta