[EASYUO-HELP] Modifica al BodGather di Raziel

[TredLibero]

Salve,
Io uso lo script di Raziel Bod Collection, che funziona benissimo e non mi ha mai dato problemi(sotto allegato il codice). Vorrei però aggiungere una variante e non ci riesco: ora come ora lo script parte solo se i pg sono sloggati. Io vorrei che alla fine del conteggio di tempo lo script mettesse in pausa un altro script che ho in play, faccesse un recall su una runa che ho in un libro (il libro si chiama home e la runa e' la numero 1,l'unica), dopo di che slogga il pg, si fa il suo giretto di bod, e torna a loggarsi con pg numero 3(numero 2 per lo script che li conta partendo dal 0), che è quello che era loggato, rimettendo in play lo script messo in pausa. Non so se tutto ciò sia possibile, complicato o lungo. Mi appello all'abilità degli scripter che bazzicano questo forum !
Grazie in anticipo!

Lo script:

;==================================
; Script Name: Raziel's Bod Gathering Script
; Author: Raziel
; Version: 1.52
; Client Tested with: 4.0.9b
; EUO version tested with: EasyUO V1.42 [Build 00A3]
; Shard OSI / FS: OSI
; Revision Date: 27/08/2005
; Public Release: 10/08/2003
; Global Variables Used:
; Purpose: Auto Gathers bods ( multi chars/accounts/shards )
;==================================
set %BODRitirati 0
;************************************************* *****************
; edit these options if you like, though defaults are fine.
set %sortDesktop #false ; #true or #false, organises your desktop
set %cancelRewards #false ; #true or #false, cancels AOS gift and vet reward gump
set %clickMod MC ; MC = move cursor, DMC = don't move cursor. MC will improve your bod gathering speed ( but will move your cursor when it clicks the npc )
set %option 4 ;this is the option on the context menu you must click to get a bod "bod info" OSI is 2 but freeshards may vary, set this here.
set %hoursBetweenBods 1 ;this is how many hours between each bod being availible. default is 6 hours.
;************************************************* *****************
goto Begin ;do not delete this line
;************************************************* ****************
sub account1
msg xxxxxxxx ;<-- NickName dell'account
wait 10
click 530 400
msg xxxxxxxx ;<-- Password dell'account
wait 20
msg $
return
;************************************************* *****************
sub account2
msg Account2
wait 10
click 530 400
msg Password2
wait 20
msg $
return
;************************************************* *****************
sub account3
msg Account3
wait 10
click 530 400
msg Password3
wait 20
msg $
return
;************************************************* *****************
sub account4
msg Account4
wait 10
click 530 400
msg Password4
wait 20
msg $
return
;************************************************* *****************
sub account5
msg Account5
wait 10
click 530 400
msg Password5
wait 20
msg $
return
;************************************************* *****************
bodlines:
;************************************************* *****************
;************************************************* *****************
;gosub bod lines below this
;************************************************* *****************
;************************************************* *****************
;gosub bodcycle Account Char rail|recall { 0 1 2 ) [Shard] <------ Delete this line

gosub bodcycle 1 0 rail_umbra 0 ;<-- Primo personaggio
gosub bodcycle 1 1 rail_umbra 0 ;<-- Secondo personaggio
gosub bodcycle 1 3 rail_umbra 0 ;<-- Quarto Personaggio
gosub bodcycle 1 4 rail_umbra 0 ;<-- Quinto Personaggio


;************************************************* *****************
;************************************************* *****************
;Edit nothing below this line
;************************************************* *****************
;************************************************* *****************
wait 100
Begin:
gosub timeOld
gosub makeMenu
gosub waitBOD
gosub _waitSysVar clilogged = 0
set *RazielBodTime #time
set *RazielBodDate #date
goto bodlines
;************************************************* *****************
sub bodCycle
namespace push

namespace local bodCycle
set !loginAttemps 0
set !account %1
set !char %2
set !recallOrRail %3
set !bodType %4
set !shard %5
set !numVars %0
set *RBG4SAccount !account
set *RBG4SChar !char

;Check for errors in bod cycle line
set !accountCheck #false
set !charCheck #false
set !recallOrRailCheck #false
set !bodTypeCheck #false
set !shardCheck #false
gosub checkNumber !account
if ! #result
set !accountCheck #true
gosub checkNumber !char
if ! #result || !char > 6
set !charCheck #true
if rail notin !recallOrRail && !recallOrRail recall_sacred
set !recallOrRailCheck #true
if _ , !bodType , _ notin _0_1_2_
set !bodTypeCheck #true
if !numVars > 4
{
gosub checkNumber !shard
if #result
set !shardCheck #true
}
gosub checkBodCycleLine !accountCheck !charCheck !recallOrRailCheck !bodTypeCheck !shardCheck !numVars
if ! #result
{
namespace pop
return
}
;end error checking

_tryLoginAgain:
if !numVars = 5
gosub InfoMenu !account !char !recallOrRail !bodType !shard
else
gosub InfoMenu !account !char !recallOrRail !bodType
if !numVars = 5
gosub login !account !char !shard
if !numVars = 4
gosub login !account !char
set !loginAttemps !loginAttemps + 1
if ! #result
{
if !loginAttemps > 5
{
namespace pop
return
}
gosub loginFailMenu
if #result = skip
{
namespace pop
return
}
if #result = tryAgain
goto _tryLoginAgain
}
wait 40
if %sortDesktop
gosub SortDesktop
if %cancelRewards
gosub cancelRewards
ignoreitem reset
if !bodType = 0 || !bodType = 2
{
gosub moveTo tailor !bodType !recallOrRail
if ! #result
{
gosub logout
wait 300s
namespace pop
return
}
}
if !bodType = 1 || !bodType = 2
{
gosub MoveTo smith !bodType !recallOrRail
if ! #result
{
gosub logout
wait 300s
namespace pop
return
}
}
gosub moveTo inn !bodType !recallOrRail
if ! #result
{
gosub logout
wait 300s
namespace pop
return
}
finditem DYM C_ . #backpackid
if #findkind = 0
gosub bodbook
wait 10
gosub logout
namespace pop
return
;************************************************* *****************

[TredLibero]

sub findNpc
namespace push
namespace local findNpc
set !type %1
set !previous %2
set !arraySize 0
set !element 1
_findNpc:
finditem IS_HS G_10
ignoreitem #findid
if #findkind <> -1
{
if #findrep = 7
{
event property #findid
if !type = tailor
{
if guild notin #property
{
if weaver in #property || tailor in #property
{
set !npc . !element #findid
set !arraySize !arraySize + 1
set !element !element + 1
}
}
}
if !type = smith
{
if blacksmith in #property || armourer in #property
{
set !npc . !element #findid
set !arraySize !arraySize + 1
set !element !element + 1
}
}
}
goto _findNpc
}
ignoreitem reset
set !npc none
for !i 1 !arraySize
{
if !npc . !i <> !previous
{
set !npc !npc . !i
set !i !arraySize
}
}
if !npc = none
set #result !previous
else
set #result !npc
namespace pop
return #result
;************************************************* *****************
sub findRune
ignoreitem reset
if %0 = 2
ignoreitem %2
get_rune:
finditem QWL C
if #findkind = -1
return -1
event property #findid
if #property = $
goto get_rune
if %1 in #property
return #findid
ignoreitem #findid
goto get_rune
;************************************************* *****************
sub login
namespace push
namespace local login
set !loginMax 3 ;max number of times to look throught shardlist
set %charCreate #false;for use later to determine if char creation came up
;key combo to restore/maximize
set !key1 space
set !key2 alt
set !key3 x
;info on what char to login
set !login0_ %0
set !account %1
set !char %2
set !shard %3
;conditional inclusion of shard scanner
if ! !shardScannerInit && !login0_ = 3
{
call shardScanner.txt init
set !shardScannerInit #true
}
login:
;wait for char to be logged out and at main login
gosub _waitSysVar clilogged = 0 contname = mainmenu_gump 60
if ! #result
{
if #contsize = 356_212
gosub backTrack login_gump mainMenu_gump
goto login
}
set !shardloc 1 ;initialize
;clear old Account and pass
set !y !char * 40 + 130
click 530 360
for !i 1 16
{
key back
}
wait 10
click 530 400
for !i 1 16
{
key back
}
wait 20
click 530 360
;type account and pass
gosub account . !account
;wait for shard select screen
_waitShard:
gosub _waitSysVar contname = normal_gump 60
if ! #result
{
;wait shard select timed out, determine what to do next
gosub determineAction normal_gump
goto #result
}
set %shardContKind #contkind;for use later to determine if char creation came up
;shard selection
if !login0_ = 3
{
;use key combo to restore/maximize uo
;shard scanner must be able to "see" uo
key !key1 !key2
wait 40
key !key3
wait 20
click 640 480 mc ;move cursor out of the way so it doesn't mess up shardscanner
;check choosen shard is selected
call shardScanner.txt isShardNameSupported !shard
if #result = #false
{
;shard not supported
display ok Either your choosen shard is not supported or you have mis-spelt the shard name. Please check and try again. Shard name ( %shard )
halt
}
set !recheck 0;initialize
set !listCheck 0;number of times the list has been checked
_shardList:
if !recheck > 4 ;4 = number of pages of shards
{
set !listCheck !listCheck + 1
if !listCheck > !loginMax ;reached max login attemps
{
gosub determineAction loginMax
namespace pop
return #false
}
;reached the bottom of the shard list
click 540 100 x 40 ;goto top
set !recheck 0
}
set !login_i -1
_shardloop: ;check all 9 shards visible on the list
set !login_i !login_i + 1
call shardScanner.txt checkLineForShard !login_i !shard
if ! #result && !login_i <= 8 ;shard is not target, but there are other shards visible to check, try next
goto _shardloop
if ! #result ;shard is not target shard, go down a page
{
set !recheck !recheck + 1
wait 10
click 535 350 x 9
wait 20
goto _shardList
}
;shard found
set !clicky 25 * !login_i + 110
click 300 !clicky g
}
if !login0_ < 3 ;if no shard specified
msg $ ; just login to last shard
_waitCharSelect:
gosub _waitSysVar contname = login_gump 20
if ! #result
{
if %charCreate
{
gosub backTrack unknown mainMenu_gump
namespace pop
return #false
}
gosub determineAction login_gump
goto #result
}
wait 15
click 300 !y d
wait 20
_login3:
gosub _waitSysVar contname = login_gump 2
if #result
{
click 612 452
wait 5
click 612 452
wait 5

click 612 452

wait 5
goto _login3
}
_waitlogin:
gosub _waitSysVar clilogged = 1 5
if ! #result
{
gosub determineAction login
goto #result
}
wait 80
if #charname = N/A
{
event macro 8 2
gosub _waitSysVar contname = status_gump 10
if ! #result
goto _waitlogin
}
namespace pop
return #true
;************************************************* *****************

...

[TredLibero]

sub _waitSysVar
namespace push
namespace local _waitForSysVar
set !timeout #scnt + % . %0
set !cnt %0 / 3
set !break #false
for !i 1 !cnt
{
set !x !i * 3 - 2
set !y !x + 1
set !z !y + 1
if ! ( # . % . !x % . !y % . !z )
set !i 0
if %0 % 3 = 1 && #scnt > !timeout
{
namespace pop
return #false
}
}
namespace pop
return #true
;************************************************* **************************************************
sub determineAction
namespace push
namespace local determineAction
set !problem %1
_Action:
if !problem = normal_gump
{
if #contname = normal_gump
{
namespace pop
return _waitShard
}
if #contname = waiting_gump
{
gosub backTrack normal_gump mainMenu_gump
if #result
{
namespace pop
return login
}
if ! #result
goto _Action
}
}
if !problem = loginMax
{
gosub backTrack login_gump mainMenu_gump
if #result
{
namespace pop
return
}
}
if !problem = login_gump
{
if #contname = login_gump
{
namespace pop
return _waitCharSelect
}
if #contname = normal_gump && #contkind <> %shardContKind && ! %charCreate
{
set %charCreate #true
gosub backTrack unknown mainMenu_gump
if #result
{
namespace pop
return login
}
}
gosub backTrack login_gump normal_gump
if #result
{
namespace pop
return _waitShard
}
gosub backTrack login_gump mainMenu_gump
if #result
{
namespace pop
return login
}
}
if !problem = login
{
if #clilogged = 1
{
namespace pop
return _waitlogin
}
gosub backTrack unknown login_gump
if #result
{
namespace pop
return _waitCharSelect
}
if #contname = normal_gump
{
namespace pop
return _waitShard
}
if #contname = mainMenu_gump
{
namespace pop
return login
}
gosub backTrack unknown mainMenu_gump
goto _Action
}
display ok Unknown Problem. Halting!
halt
;************************************************* *****************
sub backTrack
namespace push
namespace local backTrack
set !currentScreen %1
set !targetScreen %2
gosub convertScreen !currentScreen
set !currentScreen #result
gosub convertScreen !targetScreen
set !targetScreen #result
;3 = mainmenu_gump
;2 = normal_gump
;1 = login_gump
;0 = unknown
_backTrack:
if #contname in mainmenu_gump_normal_gump_login_gump
{
gosub convertScreen #contname
set !currentScreen #result
}
if !targetScreen < !currentScreen
{
namespace pop
return #false
}
if !currentScreen = !targetScreen
{
namespace pop
return #true
}
if #contname = waiting_gump
{
str pos #contsize _
set !temp #strres - 1
str left #contsize !temp
set !x ( #strres / 2 ) + #contposX
str pos #contsize _
str del #contsize 1 #strres
set !y #strres + #contposY - 34
click !x !y
gosub _waitSysVar contname <> waiting_gump 2
goto _backTrack
}
goto _backTrack . !currentScreen
_backTrack1:
click 600 450
gosub _waitSysVar contname = nomal_gump 5
goto _backTrack
_backTrack2:
click 600 450
gosub _waitSysVar contname = mainmenu_gump 5
goto _backTrack
_backTrack3:
goto _backTrack

;************************************************* *****************

.

[DarkRitual]

Il problema di fondo non sarebbe quello di far partire un altro script mentre magari il tuo pg resta in attesa, il problema (almeno per quello che sò) sarebbe metterlo in pausa per rieseguirlo un secondo momento...Un conto è far partire script semplici e poco complessi, ma se invece vuoi lanciare Scorna o Filler vari credo che il tutto diventa molto più complesso...
Personalmente sò ancora poco di scripting x ultima e un evento simile non lo sò affatto gestire,forse qualcun'altro potrebbe risponderti la stessa cosa, forse no.... vedremo

[gramoz]

Non ho capito bene se è questo il tuo problema ma lo script è fatto apposta.
Devi farlo partire da un inn in modo che, dopo aver ritirato il bod, torna a sloggare li e puoi subito riloggare col 2 pg per raccogliere un altro bod e ripetere a sua volta l'operazione.

[DarkRitual]

Non ho capito bene se è questo il tuo problema ma lo script è fatto apposta.
Devi farlo partire da un inn in modo che, dopo aver ritirato il bod, torna a sloggare li e puoi subito riloggare col 2 pg per raccogliere un altro bod e ripetere a sua volta l'operazione.

No Gramoz, lui vorrebbe poter far partire uno script esterno al bodgather in maniera tale da non lasciare l'ultimo pg "del giro" senza fare niente, credo che la sua idea sia "prendo bod,finisce di fare il giro per prenderli,avvia lumberscorna,arrivato l'orario per andare a prendere gli altri bod si ferma a tagliare, torna a casa e riparte di nuovo il bodgather" ...e cosi via

[TredLibero]

Esatto Dark. Ovviamente il tailor non è compreso fra i pg del giro bod... Io vorrei lasciare away il tailor a fare quello che deve fare col suo script e poi, allo scadere del tempo del raziel, recallare e sloggarlo a casa così da far paritre il giro bod, dopo di che dovrebbe rientrare col mio pg e far ripartire lo script che usava. Va bene anche da casa, da dove si è sloggato insomma. Sai come posso fare ?

[fengyr]

il discorso non è tanto nell'aggiungere la parte in cui raccoglie i bod escludendo il tailor... ma è piuttosto nel modificare lo script che chiama il bod gather, bisogna fare in modo che lo script si metta in pausa (e fin qui basta un semplice comando call bodgather.txt), e poi mettere in condizione lo script di partenza di ripartire da dove è stato interrotto.

la maniera più semplice è di inserire un timer all'interno del primo script.
altrimenti, e secondo me sarebbe meglio, modificare il bod gather implementando un timer continuo che al momento opportuno manda un input all'altro script, lo mette in pausa in maniera stabile (senza creare situazioni impreviste e terminando correttamente le routine), fa il giro bod e fa ripartire in maniera corretta lo script "primario".

c'è un pò di lavoro ma in qualsiasi caso bisogna mettere mano sull'altro script...

ad esempio se leggete il contenuto del lumber script di Scorna c'è una funzione che, l'autore ha disattivato ma non eliminato del tutto ed è proprio per il giro bod
certe volte implementazioni del genere mi vengono da fare perchè informatica la studio all'uni, ma conoscendo Scorna (lo conosco in quanto cogildaneo, non ha mai studiato, è autodidatta!) capisco quanto a volte sia geniale

[TredLibero]

In realtà il bod collector è già settato per escludere il tailor, infatti funziona benissimo se lo lascio away da sloggato.. Sono anche riuscito a far sloggare il tailor allo scadere del timer (non ho porvato a mettere il recall ma penso di riuscirci...) il problema e' che pero' poi mi slogga a ogni pg che entra ( anche quelli dei bod..). Mi dite il comando per mettere in pausa uno script da un altro script ? e anche quello per rimetterlo in play, così faccio qualche prova. Mi sa che il problema più grande stà nel settare il login dopo il giro, io proprio non capisco le variabili del raziel (non so niente di scripting!) Purtroppo io ci ho provato ma non ci riesco, è per questo che ho chiesto aiuto. Cmq penso si possa fare modificando solo il raziel.
p.s.
L'altro script non è il il miner o lumber, ma uno script per fare pelli.

[DarkRitual]

Come ha detto fengyr, bisognerebbe avere tra le mani l'altro script e "temporizzarlo" , ovvero bisognerebbe farlo lavorare ogni X minuti e poi stop, lo si blocca,lo lascia sloggare a casa o dentro un inn e far lavorare in santa pace il bodgather

[Scorna]

In realtà il bod collector è già settato per escludere il tailor, infatti funziona benissimo se lo lascio away da sloggato.. Sono anche riuscito a far sloggare il tailor allo scadere del timer (non ho porvato a mettere il recall ma penso di riuscirci...) il problema e' che pero' poi mi slogga a ogni pg che entra ( anche quelli dei bod..). Mi dite il comando per mettere in pausa uno script da un altro script ? e anche quello per rimetterlo in play, così faccio qualche prova. Mi sa che il problema più grande stà nel settare il login dopo il giro, io proprio non capisco le variabili del raziel (non so niente di scripting!) Purtroppo io ci ho provato ma non ci riesco, è per questo che ho chiesto aiuto. Cmq penso si possa fare modificando solo il raziel.
p.s.
L'altro script non è il il miner o lumber, ma uno script per fare pelli.

Se l'altro script (quello per fare pelli ) non è scritto in modo da poter essere messo in pausa è un po' difficile...
Cmq la prima cosa che devi fare è trovare una sub che quello script richiama spesso e dove il pg sia in un posto facilmente ri-raggiungibile (tipo quando svuota il backpack ).
Trovare un punto valido nella sub per inserire una cosa del tipo:

if *999 = FERMATI
{
;codice per portare il pg in un posto sloggabile
pausaintromessa:
if *999 = FERMATI
goto pausaintromessa
;codice per portare il pg dove era
}

Dopo di che puoi bloccare lo script in modo esterno scrivendo:
set *999 FERMATI
e farlo ripartire semplicemente con:
set *999 VAI

Ciauz

[TredLibero]

Se l'altro script (quello per fare pelli ) non è scritto in modo da poter essere messo in pausa è un po' difficile...
Cmq la prima cosa che devi fare è trovare una sub che quello script richiama spesso e dove il pg sia in un posto facilmente ri-raggiungibile (tipo quando svuota il backpack ).
Trovare un punto valido nella sub per inserire una cosa del tipo:

if *999 = FERMATI
{
;codice per portare il pg in un posto sloggabile
pausaintromessa:
if *999 = FERMATI
goto pausaintromessa
;codice per portare il pg dove era
}

Dopo di che puoi bloccare lo script in modo esterno scrivendo:
set *999 FERMATI
e farlo ripartire semplicemente con:
set *999 VAI

Ciauz

Intanto ti ringrazio per l'aiuto... Ho fatto un sacco di prove ma non ci sono riuscito ... Non capisco dove inserire il
"set *999 FERMATI" nel raziel per farlo partire quando il timer è a 0, ne dove mettere "set *VAI" in modo che non riparta subito. Ma il "set *vai" dovrebbe andare subito dopo un codice per far loggare il tailor giusto ? Il fatto è che proprio non conosco le dinamiche che usa easyuo... Ho fatto un sacco di prove ma niente... Ma "pausaintromessa" lo devo sostituire con un tempo specifico ?

[ciurry]

scusate....in tutto questo avete valutato ai vari save e clean che uo fa?
non sono scripter, ma il poco che so è che se entra nel momento sbagliato una pausa in game, tutti i conteggi sballano e si "incricca" tutto :P

[Scorna]

Beh.. non è una modifica facile se non mastichi un po' di easyuo...
Stai parlando di due script scritti non prevedendo questo modo d'uso.

Ciauz

[TredLibero]

Ho capito, in questo caso mi sa che mi conviene abbandonare... Nella mia ignoranza avevo immaginato la cosa molto più semplice e pensavo si potesse fare aggiungendo dei comandi al raziel, del tipo: If timer è 0 --> ferma script pelli ----> recall ---> logout---(parte il raziel da solo). If timer è 52 minuti(dopo il giro)----> login tailor----> play script pelli.