[EASYUO REQ] % Durata incantesimi

[gramoz]

Forse esiste gia, fatto sta che non sono riuscito a trovare nulla.
Sapete per caso fare uno scriptino che indichi, sopra ad essi, la durata in % dei field? ma volendo anche dei paralyze e dei vari incantesimi a durata?

[manuel91]

allora dei field non ti so dire cmq se te clikki sulla pallina blu dello status ti compare una specie di angolo retto che ti dice la durata degli incantesimi castati su di te sia positivi che negativi

[gramoz]

allora dei field non ti so dire cmq se te clikki sulla pallina blu dello status ti compare una specie di angolo retto che ti dice la durata degli incantesimi castati su di te sia positivi che negativi

Sisi, intendevo quelli castati su altri

[fengyr]

il fatto sta tutto nel sapere quanto durano le spell e vedere se la lag (purtroppo il 90% del problema è quella) non influisce troppo nel calcolo...

se riesci a trovare una fonte sicura da cui poter ricavare le durate delle spell non è difficile poi scriptarlo...

edit: ho scritto non pensando a poison e curse... spell tipo queste sono semi-impossibili da calcolare precisamente visto che la durata dipende dal calcolo della tua skill magery contro la resisting spell dell'avversario.
se poi ti serve un timer per le evocazioni o i field quelli sono facili facili....

[antonio.gl]

Incalcolabile perchè dipende da resisting spells dell'avversario. Invece quella dei field è interessante, ora ci provo.
Fatto, anche se sicuramente mi sarò dimenticato qualche type
Funziona con paralize e energy field e gate travel.

;==================================
; Script Name: FieldController
; Author: Tony
; Version: 0.1
; Client Tested with: 6.0.1.3
; EUO version tested with: 1.5 v142
; Shard OSI / FS: FS
; Revision Date: 20/12/08
; Public Release: 20/12/06
; Purpose: Mostra la durata residua in secondi dei field fatti dal proprio pg.
; Per funzionare occorre che i nomi originali delle spell siano attivi,
; ad esempio: In sanct grav e non Energy Field
; Può monitorare: energy field, paralize field e gate travel.
;==================================
set %type QPV_GQV_PQV_VRV_VQV_KEF_OTF
set %jrnl #jindex
set %init #scnt
set %j 0
set %field field
set %timer timer
set %durata durata
while #true
{
  if #jindex > %jrnl
  {
    set %jrnl #jindex
    scanjournal #jindex
    if In_Sanct_Grav in #journal || In_Ex_Grav in #journal
    {
      gosub waitForField
      deletejournal
    }
    if Vas_Rel_Por in #journal
    {
      gosub waitForGate
      deletejournal
    }
  }
  if #scnt - %init > 2
  {
    for %i 0 %j
    {
      set %myfield %field . %i
      set %mytimer %timer . %i
      set %mydurata %durata . %i
      if %myfield <> N/A
      {
        set %mytimer %mytimer + %mydurata - #scnt
        if %mytimer < 0
          set %mytimer 0
        event exmsg %myfield 3 30 %mytimer
      }
    }
    set %init #scnt
  }
}
sub waitForGate
  set %start_wait #scnt
  finditem KEF_OTF G_1
  while #findkind = -1
  {
    wait 1
    finditem KEF_OTF G_1
    if #scnt - %start_wait > 5
      break
  }
  set %field . %j #findid
  set %timer . %j #scnt
  gosub calcolaDurata gate
  set %durata . %j #result
  set %j %j + 1
return
sub waitForField
  set #lpc 500
  while #targcurs <> 1
    wait 1
  while #targcurs = 1
    wait 1
  wait 10
  if #ltargetkind = 2
  {
    set %fieldx #ltargetx
    set %fieldy #ltargety
  }
  if #ltargetkind = 1
  {
    finditem #ltargetid
    set %fieldx #findx
    set %fieldy #findy
  }
  finditem %type
  for %k 1 #findcnt
  {
    set #findindex %k
    if #findx = %fieldx && #findy = %fieldy
    {
      set %field . %j #findid
      set %timer . %j #scnt
      if #findtype in VRV_VQV
        set %field_type paralize
      if #findtype in GQV_PQV_QPV
        set %field_type energy
      if #findtype in KEF_OTF
        set %field_type gate
      gosub calcolaDurata %field_type
      set %durata . %j #result
      set %j %j + 1
    }
  }

return

sub calcolaDurata
  chooseskill mage
  if %1 = paralize
    set %r ( #skill / 30 ) + 3
  if %1 = energy
    set %r ( ( #skill * 28 ) / 1000 ) + 2
  if %1 = gate
    set %r 30
return %r

[gramoz]

Grazie mille antonio.
Se volessi modificare il carattere/colore dei numerini che riga devo modificare?

[antonio.gl]

event exmsg %myfield 3 30 %mytimer

Il 3 è il font e il 30 il colore.