Tweet
;==================================
; Script Name: Spellbook Maker
; Author: Tony
; Version: 0.1
; Client Tested with: 6.0.10
; EUO version tested with: 1.5 v. 142
; Shard OSI / FS: FS
; Revision Date: 10/12/2006
; Public Release: 4/11/2008
; Global Variables Used: None
; Purpose: Riempie spellbook
;==================================
; NOTE:
;
; ISTRUZIONI:
; procurarsi tanti reagenti e metterli nel backpack del pg
; mettere tante penne e scroll vuote dentro una cassa
; Consigliato: Gm meditation, non muovere il mouse mentre lo script lavora.
;==================================
event exmsg #charid 3 30 Seleziona il baule con le risorse!
set #targcurs 1
while #targcurs = 1
wait 1
set %baule #ltargetid
SET #LOBJECTID %baule
event macro 17 0
wait 2s
event exmsg #charid 3 30 Seleziona il libro da riempire!
set #targcurs 1
while #targcurs = 1
wait 1
set %libro #ltargetid
wait 2s
set %spell 1
set %start_time #scnt
main_loop:
gosub check
gosub calcola
gosub premi
gosub sposta
goto main_loop
sub calcola
set %x1 30
set %y1 ( 90 + ( 20 * ( ( %spell - 1 ) / 8 ) ) )
set %x2 230
set %y2 70 + ( ( ( %spell - ( ( ( %spell - 1 ) / 8 ) * 8 ) ) - 1 ) * 20 )
return
sub check
if %spell = 65
{
set %time #scnt - %start_time
event sysmessage %time , #spc , secondi
stop
}
finditem PBG C_ , #backpackid
if #findkind = -1
gosub piglia_pen
else
set %pen #findid
finditem DPF C_ , #backpackid
if #findkind = -1
gosub piglia_scroll
set %circle ( ( ( %spell - 1 ) / 8 ) + 1 )
event exmsg #charid 3 15 Writing , #spc , circle , #spc , %circle , #spc , spell , #spc , %spell
if %circle = 1
set %mana 4
if %circle = 2
set %mana 6
if %circle = 3
set %mana 10
if %circle = 4
set %mana 12
if %circle = 5
set %mana 16
if %circle = 6
set %mana 20
if %circle = 7
set %mana 40
if %circle = 8
set %mana 50
event exmsg #charid 3 15 Check for available mana...
if #mana < %mana
gosub wait_for_mana
return
sub premi
set #lobjectid %pen
event macro 17 0
set %to #scnt
while #contsize <> 530_437
{
wait 10
event macro 17 0
if #scnt - %to > 10
break
}
set %x1 %x1 + #contposx
set %y1 %y1 + #contposy
click %x1 %y1 n mc
wait 5
click %x1 %y1
wait 10
set %to #scnt
while #contsize <> 530_437
{
wait 10
event macro 17 0
if #scnt - %to > 10
break
}
set %x2 %x2 + #contposx
set %y2 %y2 + #contposy
click %x2 %y2 n mc
wait 5
click %x2 %y2
wait 10
set %scrivendo #true
set %jrnl #jindex
while %scrivendo
{
if #contsize = 530_437
set %scrivendo #false
if #jindex > %jrnl
{
set %jrnl %jrnl + 1
scanjournal %jrnl
if tool in #journal
set %scrivendo #false
}
}
set %spell %spell + 1
return
sub sposta
finditem KUL_RUL_YUL_SUL_MUL_LUL_OUL_NUL_YUL_XUL_AVL_ZUL_WXL_EYL_OTL_WTL_EUL_MUL_UUL_CVL_HVL_IVL_FVL_GVL_VUL_WUL_TUL_PUL_DUL_IUL_JUL_KUL_LUL_GUL_XTL_QUL_CYL_PXL_ZXL_AYL_QXL_ZTL_NXL_KYL_VXL_YXL_RTL_GYL_DYL_CUL_HUL_ZUL_QTL_YTL_AUL_VTL_STL_BUL_FUL_HYL_JYL_NTL_PTL_UTL_FYL_XXL_BYL_TTL_IYL C_ , #backpackid
if #findkind <> -1
{
exevent drag #findid 1
wait 10
exevent dropc %libro
wait 10
}
else
{
set %spell %spell - 1
}
return
sub piglia_scroll
wait 1s
set #lobjectid %baule
event macro 17 0
wait 1s
finditem DPF C_ , %baule
if #findkind = -1
stop
exevent drag #findid 100
wait 10
exevent dropc #charid
wait 10
return
sub piglia_pen
wait 1s
set #lobjectid %baule
event macro 17 0
wait 1s
finditem PBG C_ , %baule
if #findkind = -1
stop
set %pen #findid
exevent drag #findid 1
wait 10
exevent dropc #charid
wait 10
return
sub wait_for_mana
set %med #true
wait 2s
while #mana < #maxmana
{
if %med
{
event macro 13 46
wait 5
set %jrnl #jindex
while %med
{
if #mana = #maxmana
set %med #false
if #jindex > %jrnl
{
set %jrnl %jrnl + 1
scanjournal %jrnl
if You_enter_a_meditative_trance. in #journal
set %med #false
}
}
}
wait 1
}
return
 |
ICQ 222293462 |
|
ICQ 222293462 |
|
ICQ 222293462 |
click %x %y mc
|
ICQ 222293462 |
Commenta