[CERCO EUO] Boards maker

[CIX666]

Giorno, per pigrizia ho macrato carpentry dopo aver preso tanta legna
sono andato su easyuo e ho trovato uno script "Lady of the Lakes FAST Logs 2 Boards"
che pero' ha ID sbagliati...siccome non so' aggiustare i gump ed inoltre mi crata dei music stand sprecando legna, volevo sapere se voi avete qualche altro script

grassie

[Aldarion]

Questo a me funziona bene.

;================================================= =
; Script Name: Endings Logs2Boards
; Author: ending
; Version: 2.5
; Client Tested with: 5.0.1c
; EUO version tested with: 1.5 TV62
; Shard OSI / FS: OSI
; Revision Date: 18Oct05
; Public Release: 12Jan05
; Purpose: Converts logs to boards in a container.
;=========Updates================================= =
;v2.5 - Skipped setting of board type if drawn from the same stack
;v2.4 - Fixed stability issues.
;v2.1 - Fixed a minor error causing the script to stop
; Line85:goto stashBoards:goto grabLogs
;v2.0 - Rewritten for ML woods and EUO 1.5 exevents
;v1.0 - Main Construction.
;================================================= =
initevents
setup:
gosub init
display ok Target your container with the logs.
set #targCurs 1
setupSupplyBag:
if #targCurs = 1
goto setupSupplyBag
set %supplyBag #lTargetID
set #lobjectid %supplyBag
event macro 17 0
wait 1s
gosub cleanBP
grabLogs:
set %lastWood %curWood
finditem ZLK C_ , %supplyBag
if #findkind = -1
{
display ok Done, halting.
halt
}
set %grabAmt ( 550 - #weight ) / 2
exevent drag #findid %grabAmt
exevent dropc #backpackid
wait 1s
set %curWood #findcol
convert:
wait 7
findItem KGG_EGG_AGG_IGG_BIG_ZHG_WFG_YFG_XFG C_ , #backpackid
if #findkind = -1
{
findItem KGG_EGG_AGG_IGG_BIG_ZHG_WFG_YFG_XFG C_ , %supplyBag
if #findkind = -1
{
display ok Cannot find carpentry tools. The script is halting.
halt
}
exevent drag #findid
exevent dropc #backpackid
wait 2s
}
set #lobjectid #findid
event macro 17 0
event macro 17 0
gosub gumpWait
gosub calcClicks
if %curWood <> %lastWood
{
click %woodtypex %woodtypey
wait 5
if %curWood = %normalCol
click %woodx %woody
if %curWood = %oakCol
click %woodx %oaky
if %curWood = %ashCol
click %woodx %ashy
if %curWood = %yewCol
click %woodx %yewy
if %curWood = %heartCol
click %woodx %hearty
if %curWood = %bloodCol
click %woodx %bloody
if %curWood = %frostCol
click %woodx %frosty
gosub gumpWait
click %othermenux %othermenuy
gosub gumpWait
}
click %boardmenux %boardmenuy
gosub gumpWait
set %curTime #scnt
click %exitmenux %exitmenuy
stashBoards:
if %curTime < ( #scnt - 5 )
{
event sysmessage Error correcting.
goto grabLogs
}
finditem TLK C_ , #backpackid
if #findkind = -1
goto stashBoards
exevent drag #findid #findstack
exevent dropc %supplyBag
wait 1s
goto grabLogs

sub init
set %normalCol 0
set %oakCol 2010
set %ashCol 1191
set %yewCol 1192
set %heartCol 1193
set %bloodCol 1194
set %frostCol 1151
return

sub cleanBP
_cleanBP:
finditem ZLK C_ , #backpackid
if #findkind = -1
return
exevent drag #findid #findstack
exevent dropc %supplyBag
wait 15
goto _cleanBP
return

sub gumpWait
set %curTime #scnt
_gumpWait:
if %curTime < ( #scnt - 5 )
return
if worn in #journal || worn in #sysmsg
return
if #CONTSIZE <> 530_437
goto _gumpWait
wait 5
return

sub calcClicks
set %woodtypex #contposx + 30
set %woodtypey #contposy + 375
set %woodx #contposx + 235
set %woody #contposy + 70
set %oaky #contposy + 90
set %ashy #contposy + 110
set %yewy #contposy + 130
set %hearty #contposy + 150
set %bloody #contposy + 170
set %frosty #contposy + 190
set %othermenux #contposx + 28
set %othermenuy #contposy + 90
set %boardmenux #contposx + 233
set %boardmenuy #contposy + 70
set %exitmenux #contposx + 30
set %exitmenuy #contposy + 413
return