[SCRIPT REQ] backpack pieno

[solitaryknight]

ciao...volevo sapere se esiste uno script semplice semplice che,se metto la runa della banca nel mio backpack,appena il back mi diventa pieno,mi recalli nella banca per posare la roba e una volta posato mi riporti nella zona da cui mi sono racallato
credo non sia nemmeno così difficile da fare...per chi lo sa fare :P

thx cmq per la collaborazione ^^

[antonio.gl]

E' venuto un po' lunghetto

set %roba POF_JJG_TLK   ;modifica questa riga aggiungendo i type degli oggetti da spostare in banca
set %elfo #false  ;modifica questa riga: pg elfo -> #true , pg umano -> #false
;########################
set %maxweight #maxweight - 10
if %elfo = #false
  set %maxweight #maxweight + 50
gosub check_rune
main_loop:
  gosub check_weight
  goto main_loop


sub check_weight
  if ( #weight > %maxweight )
    gosub posa_roba
return

sub posa_roba
  gosub recall bank
  finditem %roba C_ , #backpackid
  if #findkind = -1
  {
    set #lobjectid #backpackid
    event macro 22 0
    while #conttype <> ZJF
      wait 1
    wait 20
  }
  msg $
  msg bank $
  while #conttype <> IKF
    wait 1
  wait 20
  sposta_loop:
    finditem %roba C_ , #backpackid
    if #findkind <> -1
    {
      exevent drag #findid #findstack
      wait 10
      exevent dropc #contid
      wait 10
      goto sposta_loop
    }
  gosub recall vendor
return

sub recall
key esc
try_loop:
  wait 10
  set %last_index #jindex
  event macro 15 31
  target 3s
  if %1 = bank
    set #ltargetid %runa_bank
  if %1 = vendor
    set #ltargetid %runa_vendor
  set #ltargetkind 1
  event macro 22 0
  key esc
  wait 1s
  set %i 1
  set %last_index ( #jindex - %last_index )
  for %i %last_index 1
  {
    scanjournal %i
    if That_location_is_blocked. in #journal || The_spell_fizzles in #journal || More_reagents in #journal
    {
      deletejournal
      goto try_loop
    }
  }
return

sub check_rune
check_rune_loop:
if %runa_vendor = N/A || %runa_bank = N/A
{
  finditem QWL C_ , #backpackid
  if #findkind <> -1
  {
    event property #findid
    if vendor in #property
    {
      set %runa_vendor #findid
      ignoreitem %runa_vendor
      goto check_rune_loop
    }
    else if bank in #property
    {
      set %runa_bank #findid
      ignoreitem %runa_bank
      goto check_rune_loop
    }
    else
    {
      ignoreitem #findid
    }
  }
  else
  {
    event exmsg #charid 3 30 Non hai le rune richieste!
    stop
  }
}
return

Hai bisogno di due rune nel backpack: una si deve chiamare "bank", l'altra "vendor".
Il pg si recallerà utilizzando magery.
Se il pg si trova in sovrappeso lo script non funziona. Se vuoi puoi contattarmi per migliorarlo, ma se non so cosa devi trasportare non posso fare più di tanto.

[solitaryknight]

ok perfetto thx mille ^^