problema script per consegnare bod

[alexdelpiero]

quando lo faccio partire prende il bod da dentro la cassa lo appoggia sopra il tailor e non me lo consegna....mi dice che mancano 357 minuti...perchè?

[alexdelpiero]

qualcuno mi aiuta please?

[legolas93]

che script è? perchè io ho il transton e funzia benissimo. se serve qualche aiuto\consiglio chiama pure qua 203916987

[oooCyaooo]

è un pò lungo, vedo se c'entra ^_^''

; ================================================== ===================
; Script Name: Penny's Bod Swapper
; Author: Pennylane
; Version: 2.3
; Client Tested With: 5.0.7.1 (patch 38)
; Euo Version Tested With: 1.5 Ver 102
; Shard Osi / Fs: Osi, Fs
; Revision Date: 12/24/06
; Public Release: 10/24/05
; Global Variables Used: N/A
; Purpose:exchanges filled bods for new, moves rewards to pack animal.
; Will detect and save user specified cloth colors while dying the rest.
; Returns smithy prospecting hammers, shovels, and pickaxes to vendor
; (optional) while saving fortification powder, scrolls, anvils & hammers.
; ================================================== ===================
; --------------------------Version Updates----------------------------
; ================================================== ===================
; ver. 2.3 Dec. 26 2006
; fixed the weight issue again
; ver. 2.2 Dec. 24 2006
; added check to only dismount if riding a beetle (based on followers = 3)
; ver. 2.1 Dec. 24, 2006
; fixed as small issue with it not finding the tinker kids on RunUO shards
; (thank you BookWibble!)
; added gold to the loot options to be moved to the packy
; fixed a couple of freeshard gump issues
; changed the weight equation to account for elven chars
; fixed a gump offset for making sewing kits
; added aqua cloth to the save list
; fixed the guildmaster smithy bod issue (TY Twi!)
; ver. 2.0 Nov. 23, 2005
; added option to hardcode pack animal, bod books, reward bag & vendors
; added the ability to save all cloth colors without dying
; added all tinker kit options for OSI and RunUO shards
; added *some* RunUO compatability (no guarantees)
; added option to choose between OSI and RunUO shards
; cleaned up journal scanning code (ty Kedrick Valorite for tips!)
; a lot of other little tuneups that I have already forgotten
; ================================================== ===================
; ---------------------------directions--------------------------------
; ================================================== ===================
; -If you play a RunUO shard set %runuo to #true in customizable options below
; -Follow the directions in the cutomizable options below to choose your cloth
; colors or to save pickaxes, shovels and prospecting hammers (they are returned
; to the vendor by default)
; -Hardcode options are available below. If you aren't sure what your doing,
; DON'T DO IT
; -Put a bag, backpack or pouch on your pack animal
; -Have 2 bod books in your pack, one with your filled bods and one that is empty.
; -Tailors: you need an unused dye tub, tinker kit, sewing kit and ingots
; (in case your sewing kit breaks)
; -Press Play and follow the prompts.
; -Rate the script while your char is turning in bods!
; ================================================== ===================
; -----------------------customizable options--------------------------
; ================================================== ===================
; if you play a RunUO server set this to #true
set %RunUO #true
; If you are on a run uo shard where the location is different
; set this to the number location on the popup menu to open your pack animal
; the first option is #1, count down from the top
set %packpop 10
; If you are on a run uo shard where the location is different
; set this to the number location on the popup menu to get bod
; the first option is #1, count down from the top
set %vendorpop 4
; if you want to keep any of the items below, just remove the type from
; the list in %return
set %return npf_qpf_gbg_twf ;gargoyle pickaxes ( 2 types ), prospecting
; hammers, sturdy shovels
; if you have lag set this to #true
set %lag #false
;/////////////////////////////////////////////////////////////////////////////////////
; Below are the different colors of bod cloth listed by reward level
; if you want to save any of these colors, change #false to #true
; the colors listed are as they are named on the Tower of Roses bod reward site
;/////////////////////////////////////////////////////////////////////////////////////
;Level 1 Colors//
;////////////////
set %green #false
set %greenblue #false
set %dkturquoise #false
set %aqua #false
;////////////////
;Level 2 Colors//
;////////////////
set %turquoise #false
set %purple #false
set %dkpurple #false
set %bloodred #false ;done
;////////////////
;Level 3 Colors//
;////////////////
set %neonblue #false
set %neonpurple #false
set %neonpink #false
set %neonyellow #false
;////////////////
;Level 4 Colors//
;////////////////
set %neongreen #false
set %redblue #false
set %navy #false
set %charcoal #false
;////////////////
;Level 5 Colors//
;////////////////
set %blaze #true
set %icewhite #true
set %iceblue #false
set %icegreen #false
; ================================================== ===================
; ------------------------- Hardcode Options --------------------------
; ================================================== ===================
; If you don't know what you are doing, or if you use different books,
; bags, or vendor shops each time, don't alter these. This is for people
; who wish to hardcode their own setup.
set %packanimal N/A ;change N/A to the container id of your pack animal
set %rewardbag N/A ;change N/A to the id of the bag on your packy
set %filledbook N/A ;change N/A to the id of your book containing filled bods
set %emptybook N/A ;change N/A to the id of your empty bod book
set %tailorvendor N/A ;the id of the tailor vendor you use
set %smithyvendor N/A ;the id of the smithy vendor you use
; ================================================== =================== ;
; ----------------------do not edit beyond here------------------------ ;
; ================================================== =================== ;
ignoreitem reset
set %human HS_IS
set %elf AV_XU
if %lag #true
{
set %shortwait 20
set %longwait 40
}
else
{
set %shortwait 10
set %longwait 20
}
gosub setup
;sub bodswap
mainloop:
set %get_new #true
gosub weight_check
gosub item_check
gosub get_bod
gosub turn_in
if %get_new
gosub get_new
goto mainloop
; ================================================== ===================
; --------------------------subroutines-------------------------------
; ================================================== ===================
sub get_bod
openbook:
set %journal #jindex
finditem %filled c_ , #backpackid
set #lobjectid #findid
event macro 17
wait %shortwait
for %i %journal #jindex
{
scanjournal %i
if the_book_is_empty. in #journal
{
if %smithy
{
gosub turn_in
if %get_new
gosub get_new
}
if %tailor
{
gosub turn_in
if %get_new
gosub get_new
gosub combine
gosub dye
wait %shortwait
}
display No more bods to turn in$
+I hope you found this script helpful$
+Thank you for rating it!$
halt
;return %filled_book_empty
}
gosub waitforgump generic_gump 615_454
if ! %gumpopened
goto openbook:
dropbod:
set %journal #jindex
gosub click_offset 43 104
wait %shortwait
for %i %journal #jindex
{
scanjournal %i
if there_is_not_enough_room in #sysmsg
{
gosub empty %loot
goto openbook
}
if the_book_is_empty. in #journal
{
if %smithy
{
gosub turn_in
if %get_new
gosub get_new
}
if %tailor
{
gosub turn_in
if %get_new
gosub get_new
gosub combine
gosub dye
wait %shortwait
}
display No more bods to turn in$
+I hope you found this script helpful$
+Thank you for rating it!$
halt
;return %filled_book_empty
}
}
finditem %bod c_ , #backpackid
gosub waitforgump generic_gump 615_454
if #findkind = -1
goto dropbod
gosub click_offset 385 430
return
;================================================= ==
sub turn_in
find_bodguy:
set %journal #jindex
finditem %bodguy g_2
if #findkind = -1
{
finditem %bodguy g_8
event pathfind #findx #findy #findz 2
wait 30
goto find_bodguy
}
dropbod:
finditem %bod c_ , #backpackid
set %filledbod #findid
wait 5
exevent drag %filledbod
wait %longwait
exevent dropc %bodguy
wait %longwait
for %i %journal #jindex
{
scanjournal %i
if enough_room_in_your_backpack in #journal
{
if %smithy
gosub empty %loot
if %tailor
{
gosub combine
gosub dye
gosub empty %loot
}
}
if I_am_not_interested_in_this. in #journal
{
gosub put_away
set %get_new #false
return
}
}
finditem %bod c_ , #backpackid
if #findkind = -1
return
goto find_bodguy
;================================================= ==
sub get_new
find_bodguy2:
set %journal #jindex
finditem %bodguy g_2
if #findkind = -1
{
finditem %bodguy g_8
event pathfind #findx #findy #findz 2 2
wait 30
goto find_bodguy2
}
if %runuo = #true
exevent popup %bodguy %vendorpop
else
{
exevent popup %bodguy
waitforpopup1:
wait 2
if #contname <> normal_gump
goto waitforpopup1
gosub click_offset 90 40
wait %shortwait
}
for %i %journal #jindex
{
scanjournal %i
if an_offer_may_be_available in #journal
{
gosub get_bod
gosub turn_in
goto find_bodguy2
}
}
gosub waitforvendorgump
if %vgopen = #false
goto find_bodguy
gosub clickvendorgump
wait %shortwait
finditem %bod c_ , #backpackid
if #findkind = -1
goto find_bodguy2
gosub put_away
return
;================================================= ==

[oooCyaooo]

sub put_away
putaway:
finditem %bod c_ , #backpackid
if #findkind = -1
{
gosub click_offset 385 430
return
}
set %journal #jindex
exevent drag #findid
wait %longwait
exevent dropc %empty
for %i %journal #jindex
{
scanjournal %i
if The_book_is_full_of_deeds. in #journal
{
display ok Your empty book is now full.$
+I hope you found this script helpful$
+Thank you for rating it!$
halt
;return %emptybookfull
}
}
wait %longwait
goto putaway
;================================================= ==
sub click_offset
set %clickx #contposx + %1
set %clicky #contposy + %2
click %clickx %clicky f
return
;================================================= ==
sub weight_check
if #weight >= %maxweight
{
if %smithy
gosub empty %loot
if %tailor
{
gosub combine
gosub dye
gosub empty %loot
}
}
return
sub item_check
event property #backpackid
if 120/125 in #property
{
if %tailor
{
gosub combine
gosub dye
gosub empty %loot
}
if %smithy
gosub empty %loot
}
return
;================================================= ==
sub empty ;context: gosub empty %loot
finditem %sewing_kit c_ , #backpackid
for %i 1 #findcnt
{
finditem %sewing_kit c_ , #backpackid
event property #findid
if runic in #property
{
exevent drag #findid
wait %longwait
exevent dropc %packybag
wait %longwait
}
ignoreitem #findid
}
set %journal #jindex
ignoreitem reset
empty:
finditem %1 c_ , #backpackid
if #findkind = -1
return
if #findtype in %return
{
exevent drag #findid #findstack
wait %longwait
exevent dropc %bodguy
wait %longwait
goto empty
}
if #findtype <> bui
{
exevent drag #findid #findstack
wait %longwait
exevent dropc %packybag
wait %longwait
for %i %journal #jindex
{
scanjournal %i
if that_container_cannot_hold in #journal
{
display Your packy is full and so are you,$
+Its time to unload$
+I hope you found this script helpful$
+Thank you for rating it!$
halt
;return packy_full
}
}
goto empty
}
exevent drag #findid #findstack
wait %longwait
exevent dropc %packy
wait %longwait
for %i %journal #jindex
{
scanjournal %i
if that_container_cannot_hold in #journal
{
display Your packy is full and so are you,$
+Its time to unload$
+I hope you found this script helpful$
+Thank you for rating it!$
halt
;return packy_full
}
}
goto empty
;================================================= ==
sub combine
find_cloth:
finditem %bod_cloth c_ , #backpackid
if #findkind = -1
{
finditem %combined_cloth c_ , #backpackid
for %t 1 #findcnt
{
finditem %combined_cloth c_ , #backpackid
wait 5
if #findcol = 1155 && %green = #true
gosub savecloth
if #findcol = 1164 && %greenblue = #true
gosub savecloth
if #findcol = 1162 && %aqua = #true
gosub savecloth
if #findcol = 1160 && %dkturquoise = #true
gosub savecloth
if #findcol = 1173 && %turquoise = #true
gosub savecloth
if #findcol = 1163 && %purple = #true
gosub savecloth
if #findcol = 1158 && %dkpurple = #true
gosub savecloth
if #findcol = 1157 && %bloodred = #true
gosub savecloth
if #findcol = 1165 && %neonblue = #true
gosub savecloth
if #findcol = 1168 && %neonpurple = #true
gosub savecloth
if #findcol = 1166 && %neonpink = #true
gosub savecloth
if #findcol = 1169 && %neonyellow = #true
gosub savecloth
if #findcol = 1167 && %neongreen = #true
gosub savecloth
if #findcol = 1172 && %redblue = #true
gosub savecloth
if #findcol = 1156 && %navy = #true
gosub savecloth
if #findcol = 1175 && %charcoal = #true
gosub savecloth
if #findcol = 1150 && %icewhite = #true
gosub savecloth
if #findcol = 1161 && %blaze = #true
gosub savecloth
if #findcol = 1151 && %icegreen = #true
gosub savecloth
if #findcol = 1154 && %iceblue = #true
gosub savecloth
ignoreitem #findid
}
ignoreitem reset
return
}
use_sewing_kit1:
set %journal #jindex
finditem %sewing_kit c_ , #backpackid
if #findkind = -1
gosub make_kit
event property #findid
if runic in #property
{
ignoreitem #findid
goto use_sewing_kit1
}
set #lobjectid #findid
event macro 17
wait %shortwait
gosub waitforgump generic_gump 530_437
if ! %gumpopened
goto use_sewing_kit1
gosub click_offset 230 90 ;combine cloth
for %i %journal #jindex
{
scanjournal %i
if you_have_worn_out in #journal
{
gosub make_kit
goto use_sewing_kit1
}
}
wait %shortwait
gosub waitforgump generic_gump 530_437
gosub click_offset 25 420 ;exit
wait %shortwait
goto find_cloth
;================================================= ==
sub savecloth
set %movecloth #findid
exevent drag %movecloth #findstack
wait %longwait
exevent dropc %packy
wait %longwait
ignoreitem #findid
return
;================================================= ==
sub dye
dye_cloth:
set %journal #jindex
finditem %dye_tub c_ , #backpackid
set #lobjectid #findid
finditem %combined_cloth c_ , #backpackid
if #findkind = -1
{
use_sewing_kit2:
finditem %sewing_kit c_ , #backpackid
if #findkind = -1
{
gosub make_kit
goto use_sewing_kit2
}
event property #findid
if Runic in #property
{
ignoreitem #findid
goto use_sewing_kit2
}
set #lobjectid #findid
event macro 17
gosub waitforgump generic_gump 530_437
if ! %gumpopened
goto use_sewing_kit2
gosub click_offset 230 90 ;combine cloth
wait %shortwait
for %i %journal #jindex
{
scanjournal %i
if you_have_worn_out in #journal
{
gosub make_kit
goto use_sewing_kit2
}
}
gosub waitforgump generic_gump 530_437
gosub click_offset 25 420 ;exit
wait %longwait
ignoreitem reset
return
}
set #ltargetid #findid
event macro 17
target
event macro 22
ignoreitem #findid
wait 20
goto dye_cloth
;================================================= ==

[oooCyaooo]

sub make_kit
tinker:
finditem %tinker_kit c_ , #backpackid
set #lobjectid #findid
event macro 17
gosub waitforgump generic_gump 530_437
if ! %gumpopened
goto tinker
gosub click_offset 30 110 ;tools
gosub waitforgump generic_gump 530_437
for %i 1 2
{
gosub click_offset 230 190 ;sewing kit
}
gosub waitforgump generic_gump 530_437
gosub click_offset 30 410
finditem %sewing_kit c_ , #backpackid
if #findkind <> -1
return
goto tinker
;================================================= ==
sub waitforvendorgump
set %vgopen #true
set %vgcount 0
waitforvendorgump:
if #contname = generic_gump && ( #contsize = 460_207 )
+ || ( #contsize = 460_231 ) || ( #contsize = 460_279 )
+ || ( #contsize = 460_351 ) || ( #contsize = 460_375 )
+ || ( #contsize = 460_399 ) || ( #contsize = 460_303 )
+ || ( #contsize = 460_327 ) || ( #contsize = 499_279 )
+ || ( #contsize = 467_279 )
return
if %vgcount >= 50
{
set %vgopen #false
return
}
wait 2
set %vgcount %vgcount + 1
goto waitforvendorgump
sub waitforgump
waitforgump:
set %beenwaiting %beenwaiting + 1
if #contname = %1 && #contsize = %2
{
set %beenwaiting 0
set %gumpopened #true
return
}
wait 2
if %beenwaiting >= 40
{
set %gumpopened #false
return
}
goto waitforgump
sub clickvendorgump
if #contsize = 460_207
gosub click_offset 110 180
if #contsize = 460_231
gosub click_offset 110 200
if #contsize = 460_279
gosub click_offset 110 250
if #contsize = 467_279
gosub click_offset 110 250
if #contsize = 499_279
gosub click_offset 110 250
if #contsize = 460_303
gosub click_offset 110 270
if #contsize = 460_327
gosub click_offset 110 300
if #contsize = 460_351
gosub click_offset 110 320
if #contsize = 460_375
gosub click_offset 110 350
if #contsize = 460_399
gosub click_offset 110 370

return
; ================================================== =================== ;
; -----------------------------setup subs------------------------------ ;
; ================================================== =================== ;
sub setup
event macro 31 0
wait %shortwait
paperdoll:
event macro 8 1
wait %shortwait
contpos 802 1
wait %shortwait
if #contname <> paperdoll_gump
goto paperdoll
statusbar:
event macro 8 2
wait %shortwait
contpos 629 588
wait %shortwait
if #contname <> status_gump
goto statusbar
backpack:
event macro 8 7
wait %shortwait
contpos 768 329
wait %shortwait
if #contid <> #backpackid
goto backpack
set %bag zjf_lkf_ckf
set %tailor_loot bui_tvh_ewh_nvi_pof
set %bod eym
set %smith_loot bmh_keg_npf_qpf_tvh_gbg_tlh_xkh_skh_kkh_twf_ewh_po f
set %animal bo_wn_zgb
set %combined_cloth bui
set %ingots enk
set %tinker_kit JTL_KTL_GTL
set %sewing_kit hag
set %dye_tub dbg
set %bod_cloth dui_aui_fui_gui
set %gumpopened #true
if #followers = 3 3
set #lobjectid #charid
event macro 17
wait %shortwait
if %packanimal = N/A
gosub packy_setup
else
set %packy %packanimal
finditem %rewardbag
if %findkind = -1 || %rewardbag = N/A
gosub open_packy
else
set %packybag %rewardbag
event macro 3 0 all follow me
gosub loot_setup
if %tailor
{
if %tailorvendor = N/A
gosub bodguy
else
set %bodguy %tailorvendor
}
if %smithy
{
if %smithyvendor = N/A
gosub bodguy
else
set %bodguy %smithyvendor
}
gosub bodbook_setup
gosub clear_filter
gosub get_1st_bod
return
;================================================= ==
sub get_1st_bod
get_1st_bod:
set %journal #jindex
finditem %bodguy g_2
if #findkind = -1
{
finditem %bodguy g_8
event pathfind #findx #findy #findz 2 2
}
wait 20
if %runuo = #true
exevent popup %bodguy %vendorpop
else
{
exevent popup %bodguy
waitforpopup:
wait 2
if #contname <> normal_gump
goto waitforpopup
gosub click_offset 90 40
wait %shortwait
}
for %i %journal #jindex
{
scanjournal %i
if an_offer_may_be_available in #journal
return
}
wait %longwait
gosub clickvendorgump
wait %shortwait
finditem %bod c_ , #backpackid
if #findkind = -1
goto get_1st_bod
gosub put_away
return
;================================================= ==
sub clear_filter
openbook:
finditem %filled c_ , #backpackid
set #lobjectid #findid
event macro 17
wait 20
if #contname <> generic_gump && #contsize <> 615_454
goto openbook
gosub click_offset 50 40
wait %shortwait
gosub click_offset 386 426
wait %shortwait
gosub click_offset 520 430
wait %shortwait
gosub click_offset 390 430
wait %shortwait
return
sub findit ;finds needed items
findit:
finditem %1 c_ , #backpackid
if #findkind = -1
{
display You need %2 in your backpack$
+get it and press play.
pause
goto findit
}
return
;================================================= ==
sub set_kit
use_sewing_kit:
finditem %sewing_kit c_ , #backpackid
event property #findid
if runic in #property
{
exevent drag #findid
wait %longwait
exevent dropc %packybag
wait %longwait
goto use_sewing_kit
}
set #lobjectid #findid
event macro 17
wait 20
if you_have_worn_out in #sysmsg
gosub make_kit
if #contname <> generic_gump && #contsize <> 530_437
goto use_sewing_kit
gosub click_offset 30 90
wait 30
gosub click_offset 25 420
return
;================================================= ==
sub open_packy
finditem %packy
if #findtype = zgb
{
if %runuo = #true
exevent popup %packy %packypop
else
{
exevent popup %packy
wait %shortwait
gosub click_offset 60 190
wait %shortwait
contpos 437 551
set %packycont #contid
}
}
else
{
set #lobjectid #findid
event macro 17 0
wait %shortwait
contpos 437 551
set %packycont #contid
}
display ok Please target the bag in your packy$
+where we will place rewards
try_again_i:
wait %shortwait
set #targcurs 1
wait %shortwait
waittargeti:
if #targcurs = 0
{
finditem #ltargetid
if #findtype notin %bag
{
display ok That is not a bag we can use, $
+please get a backpack,pouch or bag and try again
goto try_again_i
}
wait %shortwait
set %packybag #ltargetid
return
}
goto waittargeti
;================================================= ==
sub loot_setup
display yesno Are you turning in tailor bods?
if #dispres = yes
{
set %tailor #true
gosub findit enk ingots
gosub findit %tinker_kit tinker , #spc , tool
gosub findit hag sewing , #spc , kit
gosub findit dbg dye , #spc , tub
gosub set_kit
set %loot %tailor_loot
finditem #charid
if #findtype in %human 2
set %allowable #maxweight - ( #weight - 50 )
set %maxweight %allowable / 2
if #findtype in %elf 2
set %allowable #maxweight - #weight
set %maxweight %allowable / 2
}
else
{
set %smithy #true
set %loot %smith_loot
set %maxweight #maxweight - 20
}
return
;================================================= ==
sub bodbook_setup
if %filledbook <> N/A
set %filled %filledbook
else
{
display Ok Please target your filled bod book$
try_again1:
wait %shortwait
set #targcurs 1
wait %shortwait
waittarget1:
if #targcurs = 0
{
finditem #ltargetid
if #findtype <> dym
{
display Ok That is not a bod book$
+please press ok and try again
goto try_again1
}
set %filled #ltargetid
goto emptybook
}
goto waittarget1
}
emptybook:
if %emptybook <> N/A
{
set %empty %emptybook
return
}
else
{
display Ok Please target your empty bod book$
try_again1:
wait %shortwait
set #targcurs 1
wait %shortwait
waittarget1:
if #targcurs = 0
{
finditem #ltargetid
if #findtype <> dym
{
display Ok That is not a bod book$
+please press ok and try again
goto try_again1
}
set %empty #ltargetid
return
}
goto waittarget1
}
;================================================= ==
sub bodguy
display ok Please target your vendor$
try_again2:
wait %shortwait
set #targcurs 1
wait %shortwait
waittarget2:
if #targcurs = 0
{
finditem #ltargetid
if #findrep <> 7
{
display ok That is not an NPC Vendor$
+please press ok and try again
goto try_again2
}
wait %shortwait
event property #findid
if tailor in #property && ( ( guildmaster in #property ) || ( guildmistress in #property ) )
{
display ok You wont get bods from that one$
+target a vendor, not a guildmaster$
+please press ok and try again
goto try_again2
}
set %bodguy #ltargetid
return
}
goto waittarget2
;================================================= ==
sub packy_setup
display Ok Please target your packy$
try_again:
wait %shortwait
set #targcurs 1
wait %shortwait
waittarget:
if #targcurs = 0
{
finditem #ltargetid
if #findtype notin %animal
{
display Ok That is not a pack animal $
+please press ok and try again
goto try_again
}
wait %shortwait
set %packy #ltargetid
return
}
goto waittarget





ecco qui
ah mi dimenticavo
}shutdown force

[alexdelpiero]

non mi funziona...niente da fare...possibili sia il client?