[EasyUO] Utility per colorare i cloth

[Oceans]

Script fatto da me. Serve a colorare i cloths che avete nel backpack del beetle (quelli appena ritirati dalla consegna away ), e li mette in una sacchetta per terra.

PS: Lo sò sono niubbo, ma stò imparando...

Dovete settare solo 3 variabili, con i seriali corretti

Set %Beetle XXX
Set %DyeTube XXXXXX
Set %Cassa XXXXXX

Il nome di queste variabili spero vi facciano capire che seriale inserire.

Eccovi lo script

; Script fatto da Athelstan-LorD-
;msn-email: oceans@gamesnet.it
;icq: 166467051
;Script per colorare i cloth tutti dello stesso colore
;www.sweetuo.com <-- video di UODreams
;----------------------------------
;----------------------------------
;Seguite le istruzioni e poi premi play
;Inserisci il seriale del beetle
Set %Beetle GYG
;Inserisci il seriale del dyetube
Set %DyeTube NUXVKMD
;Inserisci il seriale della cassa
Set %Cassa NLORKMD
;Premi play
;----------------------------------
;----------------------------------
;----------------------------------
Set %Stoffa BUI

Loop:
;Trova Beetle e apri Menu
finditem %Beetle G_10
{
	exevent Popup #findid 11
	wait 10
}
;Cerca la stoffa nel backpack del beetle
finditem %Stoffa C_ , #CONTID
If #FINDCNT > 0
;Se ci sono
   {
	  Exevent Drag #FINDID #findstack
    wait 10
	  Exevent Dropc #backpackid
	  wait 10
   }
;Se non ce ne sono
else
   {
   display Cloths finiti
   halt
   }
;Colora col Tubo
Set #LOBJECTID %DyeTube
event macro 17
set #LTARGETID #FINDID
wait 10
event macro 22
wait 1s
;Sposto i cloth colorati nella sacchetta
finditem %Cassa G_3
wait 10
finditem %Stoffa C_ , #backpackid
Exevent Drag #FINDID #findstack
wait 10
Exevent Dropc %Cassa
;Finito e torno all'inizio
goto Loop

[Batista]

Bella Athel!

Io tempo fa mi ero fatto questo.
Metto anke il mio se a qualcuno servisse...

;==================================
; Script Name: Painter
; Author: Ray
; Version: 0.1
; Client Tested with: 5.9.1a
; EUO version tested with: 1.5 Version 110
; Shard OSI / FS: FS, RunUo 1.0
; Revision Date: 12/04/2007
; Public Release: 21/09/2007
; Global Variables Used: N/A
; Purpose: Colora i cloth all'interno di un secure
;==================================
initevent
event sysmessage Iniziamo a pitturare
wait 5
event macro 8 7    ;apre e posiziona il backpack
wait 12
_targetta:
event exmsg #CHARID 0 1152 Targetta il container $      ;scegli il container
set #TARGCURS 1
while #TARGCURS = 1
    wait 10
set %container #LTARGETID
set #LOBJECTID #LTARGETID
finditem %container G
if #FINDDIST > 1      ;distanza dal container (deve esser < 1 tile)
{
   event exmsg #CHARID 0 1152 Container troppo distante $
   wait 10
   event exmsg #CHARID 0 1152 Distanza: #FINDDIST tile $
   wait 10
   event exmsg #CHARID 0 1152 Mettiti a max 1 Tile di distanza $
   wait 10
   goto _targetta
}
event macro 22
event macro 17 0
wait 20
gosub open_beatle      ;toglie i cloth dal beatle per metterli nel container
wait 10
gosub svuota_beatle
wait 10
finditem DBG C_ , #BACKPACKID    ;cerca il dyetub nello zaino
if #FINDCNT = -1
{
    event sysmessage Compra un dye tub
    halt
}
set %dyetub #FINDID
set %dyecolor #FINDCOL

check_cloth:
finditem BUI C_ , %container   ;cerca i cloth nel container
;set %clothcolor #FINDCOL
while #FINDCNT >= #FINDINDEX
      {
      set #LOBJECTID %dyetub
      event macro 22
      wait 8
      event macro 17 0
      wait 8

      set #LTARGETID #FINDID
      event macro 22
      wait 8
      
      exevent drag #FINDID #FINDSTACK
      exevent dropc %container
      ;wait 8
      
      ignoreitem #FINDID
      set #FINDINDEX #FINDINDEX + 1
}
event sysmessage Niente da colorare
halt

;sub gestione del beatle

sub open_beatle
   set #lobjectid #charid
   event macro 17
   msg all follow me $
   wait 5
   event exmsg #CHARID 0 1152 Targetta il Beatle
   set #targcurs 1
   while #targcurs = 1
   wait 2
   set %beatle #ltargetid
   exevent popup %beatle 11
   wait 20
   while #contName <> container_gump && #contSize <> 230_204
   wait 20
   contpos 440 570
   wait 20
   set %zainoBeatle #CONTID
   return
   
sub svuota_beatle
    svuota:
    finditem BUI C_ , %zainoBeatle
    if #FINDKIND <> -1
    {
      exevent drag #FINDID #FINDSTACK
      wait 12
      exevent dropc %container
      wait 10
    }
    else
    return
    goto svuota
return

Ci sta che ci siano righe inutile o scritte male, nn lo ho riletto.
Cmq a me funziona da dio!