[CERCO] Script per....

[Stie89]

Salve a tutti. Sto cercando uno script che mi permette di usare le pozze appena avvelenato, oppure usare le greather heal quando scendo sotto un tot di hp, oppure che mi permetta di usare le refresh quando scendo da un tot di stamina...
Beh, esiste?
Mi potete dire come si chiama oppure postarlo qui di seguito? Grazie

[Batista]

Questo è quello che mi passò Gabriel e che usavo io quando iniziai a fare pvp.
E' una vita che nn lo uso, ci sta pure che lo avessi modificato a suo tempo quando ancora non sapevo manco scrivere un ciclo for, anke se dandogli un'occhio così veloce dovrebbe funzionare.
In alto ti puoi settare gli hp minimi a cui bere la heal e la stamina minima a cui bere le refresh.
P.S.: questo mi sa che funziona solo se hai abilitato l'opzione di razor per togliere lo scudo quando bevi pozze.
Se giochi senza questa opzione oppure senza razor dimmelo che ti posto la versione che avevo fatto io per usarla con injection.

; SCRIPT PER POZZE AUTOMATICHE
;===================================


; VARIABILI DA SETTARE
;===================================
; Soglia minima di HitPoints per bere la pozza heal
set %minHP 20

; Soglia di stamina minima a cui si beve la pozza
set %minStam 80

;pausa tra una pozza e l'altra (es: %pausa 20 = 1 secondo) (default: 14)
set %pausa 14
;===================================

InitEvents
set %timer_pozza 0


; MAIN LOOP
;===================================
mainloop:
if ( ( H notin #charstatus ) && ( #charghost = NO ) )
{
gosub beviPozze
goto mainloop
}
goto mainloop

;===================================
; sub name : BEVI POZZE
; author : Gabriel Delamoth[NeT]
; purpose : semplice sub che funziona da redirect.
;===================================
Sub beviPozze
if ( C in #charstatus )
{
gosub controllo
gosub beviCura
return
}

if ( #hits < %minHP )
{
gosub controllo
gosub beviHeal
return
}

if ( #stamina < %minStam )
{
gosub controllo
gosub beviRefresh
return
}
return

;===================================
; CONTROLLO
;===================================
Sub controllo
if ( H in #charStatus )
{
wait 10
gosub controllo
}
return

;===================================
; Bevi pozza Stamina
;===================================
Sub beviRefresh
finditem ZUF C_ , #backPackId
if ( #findkind <> -1 )
{
event ExMsg #CharId 3 39 -refresh-
set #lobjectid #findid
event macro 17 0
wait %pausa
return
}
return

;===================================
; Bevi pozza Cura
;===================================
Sub beviCura
finditem NUF C_ , #backPackId
if ( #findkind <> -1 )
{
event ExMsg #CharId 3 44 -cura-
set #lobjectid #findid
event macro 17 0
wait %pausa
return
}
return

;===================================
; Bevi pozza Heal
;===================================
Sub beviHeal
if ( #scnt > %timer_pozza && C notin #charStatus )
{
finditem UUF C_ , #backPackId
if ( #findkind <> -1 )
{
event ExMsg #CharId 3 55 -heal-
set #lobjectid #findid
event macro 17 0
set %timer_pozza #scnt + 11
wait %pausa
return
}
}
return
;FINE SCRIPT

[Stie89]

Grazie, lo proverò il prima possibile
Cmq uso razor e ho impostato di togliere lo scudo quando le pozze. Grazie mille!

Appena provato e mi sembra che vada bene Grazie!