[EASYUO-REQ]Script Vet

[passopazzo]

tempo fa nn ricordo chi aveva uno script per ressare pet se si avvicinava in automatico cosi lascio pg a luna quando nn ci sono per ressare pet,
qualcuno me lo passa pls?

[HaerDelis]

;By Danilovic
set %timerressato #scnt + 60
set %timernonmorto #scnt + 300
Loop:

finditem HHB_UJ_MHB_EG_ZGB_WJ_QC_YJ_OJ_TJ_BO_JG_WN_SF_SG_OF_MG_JB_CG_TE
+_DF_CD_YE_XE_GN_OF_HH_FN_CH_JJ_KG_SH_SC G_1                                ;cerca se ci sono pet da ressare

set %numeropettrovati #findCnt
while #findIndex <= %numeropettrovati                                       ;ripeti fino a controllo tutti pet trovati
    {
     set %indice #jindex
     set #LTARGETID #FINDID                                                 ;assegna il pet trovato al lasttarget
     event macro 13 2                                                      ;animal lore
     target
     event macro 22 0                                                       ;last target
     wait 10
     set %numrighe #jindex - %indice
     gosub checkJournal The_spirits_of_the_dead %numrighe
     if #result = #true
        {
         gosub resurrect
         ignoreitem #LTARGETID ressato                                       ;ignora pet ressato
        }
     if #CONTSIZE = 400_381                                                  ;se gump animal lore si apre
            {
             set %x #CONTPOSX + 190
             set %y #CONTPOSY + 200
             click %x %y r                                                   ;chiudi gump animal lore
             ignoreitem #LTARGETID non_morto                                 ;ignora pet non morto
            }

     set #findIndex #findIndex + 1                                           ;aumenta index per passare pet successivo
     wait 5
    }
    
if %timerressato < #scnt
    {
          ignoreitem reset ressato                                           ;resetta dopo 1 minuto i pet ignorati
          set %timerressato #scnt + 60
    }
if %timernonmorto < #scnt
    {
          ignoreitem reset non_morto                                           ;resetta dopo 1 minuto i pet ignorati
          set %timernonmorto #scnt + 300
    }
    
goto loop                                                                    ;torno al loop

sub resurrect
    FINDITEM ZLF C_ , #backpackid                                            ;cerca bende nel backpack
    if #FINDKIND = -1
       {
        For %n 1 3
           {                                                                 ;Chiedi 5 volte di passarti una benda
            Event Macro 4 0 Passami delle bende e ti resso il pet
            wait 10s
            If #CONTNAME = trade_gump                                        ;se si apre il gump
                    {
                        set %x #CONTPOSX + 65
                        set %y #CONTPOSY + 42
                        click %x %y                                          ;accetta bende in trade
                        gosub resurrect                                      ;vai alla sub res
                    }
           }
        return                                                               ;se per 3 volte non ti passano benda return e ignorapet
       }
    set %indice #jindex
    set #LOBJECTID #FINDID                                                   ;assegna id bende al lastobject
    event macro 17 0                                                         ;last object
    target
    event macro 22 0                                                         ;last target
    wait 45
    set %numrighe #jindex - %indice
    gosub checkJournal You_fail_to_resurrect %numrighe
    if #result = #true
        {
         gosub resurrect
        }
return

;======================== checkJournal  ==========
; Script Name: sub checkJournal
; Author: Necro|FS
; Purpose: Checks for user-defined messages in #journal.
sub checkJournal
nameSpace Push
nameSpace local yMW
if %0 = 0 || %0 = n/a
   set %1 1
for !_i 1 %1
{
   scanjournal !_i
   if %1 in #journal
   {
      nameSpace Clear
      nameSpace Pop
      return #true
   }
}
nameSpace Clear
nameSpace Pop
return #false

eccolo