[EasyUO - HELP] ricavare le resistenze di un target

[bino]

qualcuno sa dirmi in quale modo posso ricavare le resistenze di un target, e magari piu' in generale le sue proprietà (stat,valore delle skill, dci etc...)

[xvaso]

io uso questo scanner enemy preso da easy




initevents
linespercycle 200
ignoreitem reset

set %humantype HS_IS
set %autoscan #false

set %props1 physical , #spc , resist
set %props2 fire , #spc , resist
set %props3 cold , #spc , resist
set %props4 poison , #spc , resist
set %props5 energy , #spc , resist
set %props6 hit , #spc , chance , #spc , increase
set %props7 defense , #spc , chance , #spc , increase
set %props8 spell , #spc , damage , #spc , increase
set %props9 reflect , #spc , phisical , #spc , damage
set %props10 lower , #spc , mana , #spc , cost
set %props11 lower , #spc , reagent , #spc , cost
set %props12 $damage , #spc , increase

set %maxprops 12

menu clear
menu window size 180 200
menu show 700 200
menu HideEUO
menu button scan 0 0 75 25 Scan
menu button autoscan 75 0 75 25 Autoscan
set #menubutton N/A
menu window title Ready
gosub writemenu

mainloop:
wait 5
if %autoscan
{
if #enemyid <> N/A && #enemyid <> %lscanned
{
finditem #enemyid
if #findkind <> -1
{
set %lscanned #findid
if #findtype in %humantype
gosub scanpg #findid
}
}
}
gosub readmenu
goto mainloop

sub scanpg
if %0 = 0
{
menu window title Target player
set #targcurs 1
waitfortarg:
wait 1
if #targcurs = 1
goto waitfortarg
finditem #ltargetid
if #findtype notin %humantype
{
event sysmessage not a pg
return
}
set %pgid #findid
}
if %0 = 1
set %pgid %1
set #lobjectid %pgid
event macro 17
waitforpaperdoll:
finditem * c_ , %pgid
if #findkind = -1
{
wait 1
goto waitforpaperdoll
}
for %i 1 %maxprops
{
set %value . %i 0
str len %props . %i
set %propslen . %i #strres
}
menu window title Scanning...
scanloop:
finditem * c_ , %pgid
if #findkind <> -1
{
set %itemid #findid
gosub scanprops %itemid
ignoreitem %itemid pglist
wait 1
goto scanloop
}
ignoreitem reset pglist
sound
gosub writemenu
menu window title Ready
return

sub scanprops
event property 0
retry:
event property %1
if #property = 25 || #property = N/A
goto retry
set %itemprops #property
for %i 1 %maxprops
{
str pos %itemprops %props . %i
if #strres > 0
{
set %dove1 #strres
set %dove2 %dove1 + %propslen . %i
str mid %itemprops %dove2 3
if % in #strres
str del #strres 3 1
set %value . %i %value . %i + #strres
str del %itemprops %dove1 %propslen . %i

}
}
return

sub readmenu
if #menubutton = scan
{
set #menubutton N/A
gosub scanpg
return
}
if #menubutton = autoscan
{
set #menubutton N/A
set %autoscan ! %autoscan
if %autoscan
menu font bgcolor red
if ! %autoscan
menu font bgcolor btnface
menu delete autoscan
menu button autoscan 75 0 75 25 Autoscan
menu font bgcolor btnface
return
}
if #menubutton = CLOSED
{
set #menubutton N/A
halt
return
}
return

sub writemenu
menu font size 8
set %y 30
for %i 1 %maxprops
{
set %textname value , %i
menu delete %textname
menu text %textname 10 %y %props . %i , #spc , %value . %i
set %y %y + 12
}
return

[bino]

ti ringrazio

[froncy]

...

dove l'hai preso??
quello l'ho scritto io. Lo riconosco da alcune cose come $damage.
A sto punto mi viene il dubbio che qualcuno l'abbia spacciato per suo e l'abbia postato sul sito di easyuo.
Se invece te l'ha dato qualcuno, è andato in giro per semplice passaparola

[xvaso]

dove l'hai preso??
quello l'ho scritto io. Lo riconosco da alcune cose come $damage.
A sto punto mi viene il dubbio che qualcuno l'abbia spacciato per suo e l'abbia postato sul sito di easyuo.
Se invece te l'ha dato qualcuno, è andato in giro per semplice passaparola

uhmmm pensavo d averlo preso dal sito d easy...ma forse me lo hanno passato,con certezza nn saprei dirtelo

[danyeleid]

...

INITEVENTS è oramai obsoleto ed inutile da scrivere, viene attivato di default da diverse generazioni di EUO

[froncy]

INITEVENTS è oramai obsoleto ed inutile da scrivere, viene attivato di default da diverse generazioni di EUO

l'avevo scritto tanto tempo fa

[kill_adder]

Si il mio è = e si chiama Mitraton_ScannerEnemy cmq è un po' obsoleto nn riconosce come pg ne gli elfi ne i ninja in animal form o i maghi poliformati :O

[froncy]

Si il mio è = e si chiama Mitraton_ScannerEnemy cmq è un po' obsoleto nn riconosce come pg ne gli elfi ne i ninja in animal form o i maghi poliformati :O

basta semplicemente cambiare la riga:

set %humantype HS_IS

e aggiungere i type desiderati, ad esempio:

set %humantype HS_IS_XXX_YYY_ZZZ