[EasyUO - HELP] Raziel's Bod Gathering Script

[Traif1502]

Salve. Da tempo uso lo script in questione (http://www.easyuo.com/forum/viewtopic.php?t=77) ma è da un pò di tempo ke mi da un problema... Se lo script si attiva per prendere i bod e durante il "viaggio" c'è un save o un cleaning, dopo qualche secondo si blocca e mi dice che c'è qualcosa in mezzo alla strada e dice di sistemare la Rail... Il probl è questo: la rail funziona alla grande; l'ho risistemata tantissime volte e infatti se non c'è un save/cleaning non da problemi e va alla grande... Sapete per caso come risolvere questo problema?

[N3xO]

Azz ti odio!!! Come hai fatto a far andare quel dannato script? Ho smanettato per ore su quel cosa ma nada!!!

[Jullette]

Non l'ho mai usato e credo che mai lo userò mai xo' la cosa che mi viene in mente è che puoi mettere un check sul journal x vedere se salva oppure fa un clear. Insomma, un po' come succede col boydon filler

[Boydon]

Sempre nel mio filler ci sono delle sub ah-hoc per il save.

Le puoi copia-incollare e richiamarle al momento giusto.
Più volte le richiami e meglio il save è detectato, ma non esagerare che se no lo script si rallenta.

[Traif1502]

Azz nn sono esperto di script, o meglio, nn ne capisco un tubo

Puoi riportarmi qui le sub ah-hoc per il save? Poi le inserisco io qui e là sperando di nn fare macelli

[Boydon]

Azz nn sono esperto di script, o meglio, nn ne capisco un tubo

Puoi riportarmi qui le sub ah-hoc per il save? Poi le inserisco io qui e là sperando di nn fare macelli

Rischi di farne molto facilmente. Soprattutto se richiami la mia sub all'interno di altre sub già fatte da Raziel. Purtroppo ogni volta che chiami una sub i parametri che gli passi (a meno che non siano salvati in qualche modo) sono sovrascritti.

Cmq eccoti le sub (sono due, ma te devi richiamare solo la prima "CheckForWorldSave", la seconda incollala nello script, ma non la chiamare mai).

;==================
;** 
;* @name CheckForWorldSave 
;* @ver 1.0 20May05 
;* @author  Boydon
;* @purpose To detect world saves and resources cleaning of RunUO Shards
;* @params 
;* @returns
;* @notes the sub keep track of the last scanned journal line using
;*					the variable %Saveindex: every time the sub is called the script will
;*					start to scan from that line.
;* @dependencies sub WaitForSaveEnd
;* @example gosub CheckForWorldSave
;* @status Tested and working fine

sub CheckForWorldSave

	nameSpace Push
	nameSpace Local CheckForWorldSave , #time , #random , #scnt2

	if %SaveIndex = N/A
		set %SaveIndex #jindex

	set !Save #false
	set !Jstart %SaveIndex
	for !i !Jstart #jindex
	{
		scanjournal !i
		if #jcolor = 53
		{
			if THE_WORLD_WILL_SAVE_IN in #journal || WORLD_IS_SAVING in #journal
			{
				set !Save #true
				Event ExMsg #charid 3 33 SAVE Detected
				gosub WaitForSaveEnd WORLD_SAVE_COMPLETE 100 !i SAVE
				set %SaveIndex #jindex
				set !i #jindex
			}
			if CLEANING in #journal
			{
				set !Save #true
				Event ExMsg #charid 3 33 CLEANING Detected
				gosub WaitForSaveEnd CLEANED 30 !i CLEANING
				set %SaveIndex #jindex
				set !i #jindex
			}
		}
		set %SaveIndex !i
	}

	nameSpace Clear
	nameSpace Pop

return

;==================
;** 
;* @name WaitForSaveEnd 
;* @ver 1.0 20May05 
;* @author  Boydon
;* @purpose To detect when world save/ resource cleaning has ended
;* @params %1 req End of save message
;*				 %2 req Time to wait before the sub goes in time out
;*				 %3 req #jindex of world save start message
;*				 %4 req Tells what are we waiting for, can be SAVE|CLEANING
;* @returns
;* @notes This sub _MUST_ be called _ONLY_FROM_ sub CheckForWorldSave.
;*				This sub uses the same namespace as sub CheckForSave.
;* @dependencies sub CheckForWorldSave
;* @example 
;* @status Tested and working fine

sub WaitForSaveEnd

	if %0 < 4 || %1 = N/A || %2 = N/A || %3 = N/A || %4 = N/A
	{
		display ok Wrong use of Sub WaitForSaveEnd: some required arguments are missing!
			+$Script will be halted.
		halt
	}

	set !EndOfSave %1
	set !SaveTimeOut #scnt + %2
	set !Jstart %3
	set !Message %4

	waitforsaveend:

	for !j !jstart #jindex
	{
		scanjournal !j
		if #jcolor = 53
		{
			if !EndOfSave in #journal
			{
				set !Save #false
				set %SaveIndex #jindex
				set !j #jindex
			}
		}
	}
	if !Save = #true && #scnt <= !SaveTimeOut
	{
		wait 1
		goto waitforsaveend
	}
	if #scnt > !SaveTimeOut
	{
		set !Save #false
		set %SaveIndex #jindex
		event ExMsg #charid 3 33 !Message detection timed out...
	}
	event ExMsg #charid 3 33 End of !Message Detected
return

[Traif1502]

Ok finalmente sono riuscito a "beccare" un save mentre lo script era in funzione e.... FUNZIONA!!!!!! Quindi un grazie 100000000000000000000000 ad Amo Natalie Imbruglia e Boydon

[Archimede]

scusa traif visto che non ci capisco nulla di script ma questo mi farebe propio comodo non è che lo posteresti tutto con le modifiche che hai apportato?

[libs86]

traif puoi postare tutto lo script aggiornato??!

[Traif1502]

Raga contattatemi ke ve lo passo, facciamo prima xke nn so come metterlo online ciau
335-718-155

Ok lo trovate qui, il link dovrebbe essere questo: Download... Cliccate col destro e salva oggetto con nome...

[Marino]

non trovo più questo scirpt nella sezione download qualcuno può farmi la cortesia di postarlo o contattarmi

[teodebla]

Ok ora il mio script funziona...nella speranza ke nn becchi un save durante la rail!!!
A parte questo vorrei ke il mio pg ripartisse senza aspettare di vaer ricevuto un bod. cioè: ora lo script va dal ncp e gli kiede il bod; se l'ncp dice di aspettare lui aspetta li continuando a kiedere finke nn lo ottiene... Il mio primo sarto deve aspettare 6 ore, tutti gli altri 1...vorrei riuscire a nn penalizzarne nessuno! è possibile??

[Sephiroth23]

Ok ora il mio script funziona...nella speranza ke nn becchi un save durante la rail!!!
A parte questo vorrei ke il mio pg ripartisse senza aspettare di vaer ricevuto un bod. cioè: ora lo script va dal ncp e gli kiede il bod; se l'ncp dice di aspettare lui aspetta li continuando a kiedere finke nn lo ottiene... Il mio primo sarto deve aspettare 6 ore, tutti gli altri 1...vorrei riuscire a nn penalizzarne nessuno! è possibile??

Qualcuno ha risolto questa cosa?

[Drael]

semplicemente non usare il sarto credo sia l'unico modo senza andare a modificare lo script.

[Sephiroth23]

Sono riuscito a ovviare al problema...semplicemente faccio partire uno script quasi identico...
l'unica differenza è che logga col sarto e aspetta 6 ore tra un bod e l'altro.
Li faccio partire 10 minuti uno dall'altro e sono a posto