[EasyUO] Visualizzazione Perfection

[froncy]

Avrei una mezza richiesta: Per completare uno script, che posterò in questo topic, mi manca una cosa che non posso provare perchè non ho un pg samurai.
Dovreste indicarmi ESATTAMENTE quattro frasi che appaiono quando si usa perfection:

Quando aumenta
Quando diminuisce
Quando diminuisce al punto da tornare a zero
Quando arriva al massimo

Se me le postate tutte e 4 posso postare uno script che vi indica il vostro livello di perfection.

[Shadowrulez]

you have gained in perfection as you precisely strike your opponent (sicura)
you have lost all of your perfection (mi sembra.. cmq in parte è lei)
you have lost some perfection (mi sembra di ricordare.. domani te le diko cn sicurezza)
you have achieved perfection in inflicting damage to this opponent! (sicura)
su quelle ove si perde perfection, domani saprò essere + preciso...

[froncy]

gosub Initialize
gosub Main
halt

sub Main
mainloop:
         sleep %SleepTime
         gosub DetectJournalAction
         if #result <> 0
            gosub ManageAction #result
         goto mainloop
return

sub ManageAction
set %Action %1
if %Action = %NoPerfection
{
 set %Perfection 0
 gosub DisplayPerfection
 return
}
if %Action = %AddPerfection
{
 set %Perfection %Perfection + %PerfectionIncrease
 gosub DisplayPerfection
 return
}
if %Action = %SubPerfection
{
 set %Perfection %Perfection - %PerfectionDecrease
 gosub DisplayPerfection
 return
}
if %Action = %MaxPerfection
{
 set %Perfection 100
 gosub DisplayPerfection
 return
}
if %Action = %HonorTarget
{
 WaitForSettingTarget:
   sleep 1
   if #targcurs <> 0
      goto WaitForSettingTarget
 set %Perfection 0
 gosub DisplayPerfection
 return
}
return

sub DisplayPerfection
finditem #enemyid g
if #findkind = -1
   set %MonsterID #charID
else
   set %MonsterID #findid
set %message Perfection: , #spc , %Perfection , %
event ExMsg %MonsterID 3 0 %message
return

sub DetectJournalAction
set %StartJIndex %LastJIndex
set %EndJIndex #jindex
if %StartJIndex > %EndJIndex
   return 0
gosub ScanJournalString %MsgNoPerfection %StartJIndex %EndJIndex
if #result <> 0
{
 set %LastJIndex #result + 1
 return %NoPerfection
}
gosub ScanJournalString %MsgAddPerfection %StartJIndex %EndJIndex
if #result <> 0
{
 set %LastJIndex #result + 1
 return %AddPerfection
}
gosub ScanJournalString %MsgSubPerfection %StartJIndex %EndJIndex
if #result <> 0
{
 set %LastJIndex #result + 1
 return %SubPerfection
}
gosub ScanJournalString %MsgMaxPerfection %StartJIndex %EndJIndex
if #result <> 0
{
 set %LastJIndex #result + 1
 return %MaxPerfection
}
gosub ScanJournalString %MsgHonorTarget %StartJIndex %EndJIndex
if #result <> 0
{
 set %LastJIndex #result + 1
 return %HonorTarget
}
set %LastJIndex %EndJIndex + 1
return 0

sub ScanJournalString
set %String %1
set %StartIndex %2
set %EndIndex %3
for %JIndex %StartIndex %EndIndex
{
 scanjournal %JIndex
 if %String in #journal
 {
  return %JIndex
 }
}
return 0

sub ComputePerfectionIncrease
chooseskill bush
if #skill < 500
   return 0
set %result #skill / 100
if %result > 100
   set %result 100
return %result

sub Initialize
;General
set %SleepTime 10
set %LastJIndex #jindex

;Perfection Numbers
set %PerfectionDecrease 25
gosub ComputePerfectionIncrease
set %PerfectionIncrease #result
set %Perfection 0

;Perfection Messages
set %MsgNoPerfection you_have_lost_all_perfection
set %MsgAddPerfection you_gain_in_perfection_as_you_precisely_strike_your_opponent
set %MsgSubPerfection you_have_lost_some_perfection
set %MsgMaxPerfection you_have_achieved_perfection
set %MsgHonorTarget Target_what_you_wish_to_honor.


;Detect Codes
set %NoPerfection 4
set %AddPerfection 1
set %SubPerfection 2
set %MaxPerfection 3
set %HonorTarget 5
return

[froncy]

Mi fate il favore di provare se funziona? così la metto nei miei script funzionanti

[isterico]

molto carino, domani lo provo... certo per easyuo serve a poco o niente..

[isterico]

nn vorrei darti dispiacere.. ma a me nn funziona ^_^''
quando attivi honor(senza ancora dare il target)ti scrive perfection:0 poi taghetti mostro ma nn scrive nulla anche se sale e scende perfct..

[froncy]

per forza non funziona, mi scrivono le frasi sbagliate...

vabbè ho fatto da me, ho alzato bushido fino a 50 su un worker e alla fine funziona.
Ho editato il post con lo script corretto.

L'unica cosa è che se uno ha i monili con bushido su sballa, perchè perfection tiene conto di bushido reale. Allora bisogna far partire lo script quando non si hanno i monili addosso (il controllo sul livello di bushido lo fa solo all'inizio).