Cerco script x macrare poisoning

[d_almirel]

cdt...

grazie in anticipo x ki mi aiutera'

[erbuka]

io usavo questo e sono arrivato a 100 abbastanza bene
ti metti in casa e ti servono due cose:
1) securebag con keg o pozioni dentro
2) 20+ dagger nello zaino

; Poisoning Script


set %poison_type AVF
set %item_type WSF
set %keg_type QMJ

set %poison_mode XXX
set %item_count XXX
set %keg_count XXX
set %item XXX
set %container XXX

set %empty_flag The , #spc , keg , #spc , is , #spc , empty

; MAIN PROGRAM BEGIN

gosub Setup
gosub PrepareInstance

mainloop:
for %i 1 %item_count
{
finditem %item_type %i C_ , #backpackid
set %item #findid
for %j 1 3
{
event SysMessage %i , #spc , %j , #spc , %item
gosub Poison
}
}
goto mainloop

; MAIN PROGRAM END

sub Setup

; Seleziona il contenitore di pozioni o dei keg
display Select The Container
set #targcurs 1
wait 5s
set %container #ltargetid

; Opzione usa keg
display yesno Do you want to use Potion Kegs?
if #dispres = yes
{
set %poison_mode KEG
}
else
{
set %poison_mode POT
}
return

sub PrepareInstance
set #lobjectid %container
event Macro 17 0
wait 1s
finditem %item_type C_ , #backpackid ; cerca item da avvelenare
set %item_count #findcnt
if %poison_mode = KEG ; cerca Keg nel container
{
finditem %keg_type C_ , %container
set %keg_count #findcnt
}
return


sub Poison
if %poison_mode = POT
{
finditem %poison_type C_ , %container
set #ltargetid #findid
}
else
{
gosub SelectKeg
event Macro 17 0
wait 1s
finditem %poison_type C_ , #backpackid
set #ltargetid #findid
}
event Macro 13 30 ; use skill poisoning
wait 1s
event Macro 22 0 ; last target
wait 1s
set #ltargetid %item ; set dagger target
event Macro 22 0 ; last target
wait 10s
return

sub SelectKeg
for %z 1 %keg_count
{
finditem %keg_type %z C_ , %container
event Property #findid
if ( %empty_flag in #property ) = #false
{
set #lobjectid #findid
return
}
}
return