[EasyUO - Help] Chi trova l'errore nel mio AutoLooter?

[OracoloGrigio]

Io uso normalmente una versione da me modificata del Falcor Autolooter (questo per intenderci).
Io non so scriptare in EasyUo, per cui mi son limitato, oltre ad adattare le liste di oggetti alle mie esigenze, ad aggiungere un tasto (TAB) che resetti il looter (cancellando la lista di corpi ignorati).
Mi sarebbe piaciuto aggiungere qualche riga di codice per usare automaticamente il pugnale sul corpo, in modo da estrarne le pelli. Ho provato a scrivere qualche riga (più precisamente l'ultima sub), ma quando attivo il tutto, lo script smette di funzionare.
Qualcuno riesce a vedere dov'è l'errore?

InitEvents
gosub OpenBackPack

Set %LootBag #BACKPACKID
finditem ZJF_CKF C_ , %LootBag
 if #findkind = -1
{
	msg nn hai un bag nel tuo back pack
	halt
}

set %LootBag #findid
;CKF
;Set %LootBag RVCGKMD
Set %CorpseID YFM_YNF
set %Blade WSF;_CNF_BNF_TSF_GMH_HNF_TRD_URD_VRH_

;===Loot Items=== 
Set %Everything *
Set %Gold POF_ZVF_UVF_EVF_VVF_RVF_HVF_NVF_GVF
Set %Blades FUO_ATF_NPO_JPH_TSF_NMH_VRH_JTF_SOH_BPH
Set %Shields FIK_GIK_CIK_NIK_AIK_MIK_HLK_CLK_OIK
Set %Gioielli IJG_UJG_CWL_LWL
Set %Reagenti JZF_RZF_MZF_KUF_WZF_KZF_JUF_SZF_YZF_DUF_IUF_UZF_TZF
Set %ScrollNecro KYM_TYM_SYM_OYM_JYM_IYM_MYM_WYM
Set %Helmets  GSH_OSH_TSH
Set %Shields FIK_GIK_CIK_NIK_AIK_MIK_HLK_CLK
Set %Axes LSF_BSF_NSF_ZRF_RMH_LPH_UOH
Set %Polearms HSF_ZTO_BUO_XTH_OPO_CUO_XRH_GUO_MTF_RRH
Set %Bashing VTH_YSF_BUH_AUO_TRH_ZTH
Set %Dragon RKO_LKO_NKO_DLO_PKO
Set %Bow WHO_QPO_USF_WOH
Set %Ossa OZF_BJK_GUF_KJK_ZIC
Set %Funghi TTO
Set %Frecce RWF
Set %PetBall GMF
Set %Pozze UUF_ZUF_NUF_YUF_XUF
Set %Varie OZF_RWF_DEG_ZLF_JJG
Set %Semi PDF

;===Loot Lists=== 
Set %LootList1 %Gold
Set %LootList2 %Reagenti
Set %LootList3 %Varie
Set %LootList4 %Ossa
Set %LootList5

;===WaitTimes===
;Set %OpenCorpseWait 11
Set %OpenCorpseWait 3
set %BeforeStackWait 8
;Set %NextLootWait 6
Set %NextLootWait 20
;===Script=== 
Main:
   ;OnhotKey F4 
    OnhotKey SPACE
   {
    ;gosub CutCorpse
    gosub FindCorpse
   }
   OnhotKey TAB
   {
    ignoreItem reset 1
   }
goto Main

sub FindCorpse
   finditem %CorpseID G_2
   if #findkind = -1
      return
   set %Corpse #findid
   ignoreitem %Corpse 1
   gosub LootCorpse
return

sub LootCorpse
    set #lobjectid %Corpse
    event macro 17
    wait %OpenCorpseWait
 ; contpos 413 707
;   gosub FindLoot
   for %i 1 5
      {
      SearchLoop:
      finditem %LootList . %i C_ , %Corpse
      if #findkind <> -1
         {
         set %Loot #findid
         set %Quantita #FINDSTACK
         exevent drag %Loot %Quantita
         wait 1
         exevent dropc %LootBag
         wait %NextLootWait
         goto SearchLoop
         }
      }
return


sub OpenBackPack
	OpenBackPackLoop:
	event macro 8 7
	gosub waitForVar ContSize = 230_204 2
	if ! #result && #CharGhost = NO
	{
		goto OpenBackPackLoop
	}
	set %BackPackID #contID
	contpos 645 620
return


sub waitForVar
	set %timeout #time + 5
	if  %0 > 3
		set %timeout #time + %4
	waitForVarLoop:
	if # . %1 %2 %3
		return #true
	if #time >= %timeout
		return #false
	goto waitForVarLoop
return

sub CutCorpse
    set #lobjectid %Blade
    set #ltargetkind 1
    set #ltargetid %Corpse
    event macro 17 0
    target 2s
    event macro 22 0
return

[froncy]

lo devi mettere qui:

sub FindCorpse
   finditem %CorpseID G_2
   if #findkind = -1
      return
   set %Corpse #findid
   ignoreitem %Corpse 1
   gosub CutCorpse  ; <-------------
   gosub LootCorpse
return

e se non usi razor devi aggiungere anche wait 13 (almeno) dopo aver tagliato il corpo.

[OracoloGrigio]

Nope, ancora non funziona...
Apre il corpo dopo qualche secondo, e non fa null'altro...

[froncy]

ah non avevo guardato bene: OLTRE a quello che ti ho detto, devi fare così:

sub CutCorpse
    finditem %Blade
    if #findkind = -1
      return
    set #lobjectid #findid
    event macro 17 0
    target 2s
    if #targcurs <> 1
      return
    set #ltargetkind 1
    set #ltargetid %Corpse
    event macro 22 0
    wait 13
return

occhio che %Blade l'hai settato male, devi mettere uno spazio in più: WSF ;_CNF senò potrebbe dare problemi.

[OracoloGrigio]

Haha!
:batte le manine:
Ora funziona! Grazie!

Un bacio al tuo avatar...

[Boydon]

A essere pignoli hai anche una variabile di troppo:

set %BackPackID #contID

la setti, ma poi non la usi mai in tutto lo script.

[OracoloGrigio]

Ah, pretendi troppo!
Io mi son fidato dello script che ho trovato: mi son solo limitato ad aggiungere qualche dettaglio...
Ma se mi dici che posso toglierla, la tolgo!