[EASYUO] Cataloguer

[CristalBall]

aprire un container e lanciare lo script

nn salva in un file txt ma e' facilmente modificabile

;==================================
; Script Name: Cataloguer
; Author: Sorrow
; Version: 1.0
; Client Tested with: xxxxx
; EUO version tested with: 1.42 (0098)
; Shard OSI / FS: OSI
;==================================

gosub showResultsmenu
set %CONTAINERID #CONTID
finditem * C_ , %CONTAINERID
set %nCnt #findCnt
if %CONTAINERID <> N/A
{
	for %i %nCnt 1
		{
			findItem * %i C_ , %CONTAINERID
			set %sItemID #findID
			event property %sItemID
;			event ExMsg #CHARID 3 0 %CONTAINERID - %sItemID #PROPERTY
			set %PARAM %CONTAINERID , - , %sItemID , #spc , #PROPERTY
			menu List add text -------------------------------------------------------------------------
			set %write %PARAM

write:			
			if $ in %write
			{
				str Len %PARAM
				set %LenStringPARAM #strres
				str Len %write
				set %LenStringwrite #strres

				str pos %PARAM $
				set %posnow #strres

			   	str left %PARAM #strres
				str del #strres %posnow 1

				str lower #strres
				set %PARAM #strres
				if %posnow <> %LenStringPARAM || %LenStringPARAM <> %LenStringwrite
				{
					menu List add text %PARAM
					set %LenStringStart %posnow + 1
					str Mid %write %LenStringStart %LenStringwrite
					set %write #strres
					str pos %write $
					set %poswrite #strres
					
					str Mid %write 1 %poswrite
					set %poswrite #strres
					set %PARAM #strres
				}	
				else
				{
					menu List add text %PARAM
					set %write %PARAM
				}
				goto write
			}
			wait 1s
		}
}
halt

sub showResultsmenu
menu Clear
menu Window Title Results
menu Window Color BtnFace
menu Window Size 600 270
menu Font Name MS Sans Serif
menu Font Size 8
menu Font Style
menu Font Color WindowText
menu Font BGColor Window
menu List Create text 10 10 580 250
menu Show 421 270
return

[dio_brando89]

non capisco come si fa a salvare il risultato in un file .txt...
semplicemente una volta che ha finito di fare la lista mi lascia aperta la finestra dei risultati, ma posso solo selezionare una riga e non posso copiare niente da li...

help

[dio_brando89]

non capisco come si fa a salvare il risultato in un file .txt...
semplicemente una volta che ha finito di fare la lista mi lascia aperta la finestra dei risultati, ma posso solo selezionare una riga e non posso copiare niente da li...

help

up

[d_fenixlm]

Per DioBrando:

Questo qui crea il file nella directory dove sta easyUo:
Per usarlo chiudi il contenitore da visitare. avvialo lo script. Appare una finestra dove ti dice di aprire il contenutore che ti interessa. Ora apri il contenitore che ti interessa e attendi. Un po lento ma crea il file di testo.

DISCLAMER: lo ho usato nn succede nulla di che ma non è uno script fatto da me. (mi pare trovato su easyuo)

;==================================
; Script Name:   Panther's Coantainer Contents Lister
; Author:  Panther_sn
; Version: 1.0
; Client Tested with:  4.0.11c
; EUO version tested with: V1.5.0048
; Shard OSI / FS: Only Tested On FS, But should work on OSI
; Revision Date:
; Public Release: 3 Aug 2005
; Global Variables Used: N/A
; Purpose: To list all Items in a container, in a text File
; SPECIAL THANKS TO:  Minoc Miner Murderer for Ceed's PropertyParse Sub
; SPECIAL THANKS TO:  RoadKill for his WriteFastDOSArray
;==================================
;Instructions:
;Start Script
;Open container you want listed
; Wait until It shows Finished
; Find file by the name of
; Conatiner.XXXXXX.030805.151416.txt
;xxxxxx Being The containerID
; 050803 being the date the file was created
;151416 being the time the file was created
;==================================
menu hideeuo
set %task Open , #spc , Conatainer , #spc , To , #spc , List
gosub showEUOMenu1
set %container #contid
set %scnt #scnt + 10
wt:
if %container = #contid
{
   if #scnt < %scnt
        goto wt
}
set %container #contid
set %file Container , %container , #dot , #date , #dot , #time , #dot , txt
wait 10
gosub update1
gosub WriteInitial
loop:
finditem * C_ , %container
if #findkind = -1
{
wait 2s
gosub update2
   halt
}
event property #findid
gosub PropertyParse
gosub WriteFastDOSarray array 1 %totalprops %file
wait 1
ignoreitem #findid
set %itemsleft %itemsleft - 1
gosub update
goto loop




;===================================================
; Script Name:  Ceed's PropertyParse Sub
; Author:  Minoc Miner Murderer
; Version:  2.0.0
; Client Tested with:  4.0.6a
; EUO version tested with:  1.42.009D
; Shard OSI / FS:  OSI
; Revision Date:  12/6/04
; Public Release:  12/6/04
; Global Variables Used: None
; Purpose:  Breaks #PROPERTY strings into individual
;           variables and counts the total properties
;====================================================
SUB PropertyParse
	NAMESPACE PUSH
	NAMESPACE LOCAL Sub_PropertyParse
        SET !subject #PROPERTY
        SET !temp 0
        IF #PROPERTY = $ || #PROPERTY = #SPC , $ ||
        + #PROPERTY = N/A 2
        	SET %TotalProps 0
        	RETURN
        _S_PP_PL:
        SET !temp !temp + 1
        STR POS !subject $
        IF #STRRES = 0 2
                SET %Prop . !temp !subject
                GOTO _S_PP_EP
        SET !area #STRRES - 1
        STR LEFT !subject !area
        SET %Array . !temp #STRRES
        SET !area !area + 1
        STR DEL !subject 1 !area
        SET !subject #STRRES
        GOTO _S_PP_PL
        _S_PP_EP:
     SET %Array . !temp .................
        SET %TotalProps !temp
        NAMESPACE POP
RETURN



;==================
;**
;* @name WriteFastDOSArray
;* @ver 1.2 11May04
;* @author  Roadkill, credit to jjarmis for figuring out how to do CR/LF in string!
;* @purpose write the values from an array into multiline file
;*        using single DOS write for speed instead of slow loop.
;* @params %1 the varname of array holding data to write, 1line/element
;*      %2 req holds the starting record to write
;*      %3 req holds the final record to write
;*      %4 req holds the filename to write to.
;*   %5 opt holds the buffersize to stay below (default 2000, limit is 2010)
;* @returns
;* @example call rksubs.txt WriteFastDOSarray writearray 1 30 testfile.txt
;* @status tested perfect
;===============================================
sub WriteFastDOSArray
  set !lpc #lpc
  set #lpc 1000
  set !doslengthlimit %5
  if %0 < 5 || %5 = n/a
    set !doslengthlimit 2000
  ;get comspec for OS
     str left #osver 1
     set !filecmd cmd.exe
     if #strres = 1
       set !filecmd command.com
     ;test for allow exec
     if exec notin #opts
     {
       display OK You MUST have "allow Execute" enabled to write a file,$
       + and right now you DON'T! Fix it...you have 10 seconds.
       wait 10s
     }
     set !writestring %1 , %2
     set !writestring % . !writestring
     set !wstart %2 + 1
     set !crlf #spc , >> , #spc , %4 , #spc , && , #spc , echo , #spc
     for !z !wstart %3
     {
       set !element %1 , !z
          set !element % . !element
          str len !element
          set !elementlen #strres
          str len !writestring
          set !writestringlen #strres
          if !writestringlen + !elementlen > !doslengthlimit
          {
               execute !filecmd /c echo !writestring >> %4
               wait 5
               set !writestring #smc , ---bufferdump---
          }
          set !writestring !writestring , !crlf , !element
     }
       execute !filecmd /c echo !writestring >> %4
       wait 5
  set #lpc !lpc
return



;===========
sub update2
set %task Finished , #spc , Listing , #spc , Contents
menu delete Label1
menu Font Size 10
menu Font Color Yellow
menu Text Label1 8 8 %task
menu delete EUOLabel2
menu delete totalitems
menu delete EUOLabel5
menu delete itemsleft
return

sub update
if #menubutton = CLOSED
{
menu hideeuo
menu show 0 0
}
menu delete itemsleft
menu Text itemsleft 16 52 %itemsleft
return

sub update1
set %task Listing , #spc , Contents
menu delete Label1
menu Font Size 10
menu Font Style
menu Font Color Olive
menu Font Transparent #true
menu Font Align Center
menu Text Label1 8 8 %task
finditem * C_ , %container
set %totalitems #findcnt
menu delete EUOLabel2
menu Font Size 8
menu Font Color Red
menu Text EUOLabel2 50 32 Total Items To Count
menu delete totalitems
menu Text totalitems 16 32 %totalitems
menu delete EUOLabel5
menu Text EUOLabel5 50 52 Left to List
set %itemsleft %totalitems
menu delete itemsleft
menu Text itemsleft 16 52 %itemsleft
return



;--------- EasyUO Menu Designer Code Begin ---------
sub showEUOMenu1
	menu Clear
	menu Window Title Container Info Lister
	menu Window Color Black
	menu Window Size 160 80
 	menu Font Transparent #true
	menu Font Align Right
	menu Font Name MS Sans Serif
	menu Font Size 10
	menu Font Style
	menu Font Color Olive
	menu Font Transparent #false
	menu Font Align Left
	menu Font BGColor HighlightText
	menu Text Label1 8 8 %task
	menu Font Size 8
	menu Font Color Red
	menu Text EUOLabel2 68 32
	menu Font Align Center
	menu Text totalitems 16 32
	menu Font Color Red
	menu Text EUOLabel5 68 52
	menu Font Align Center
	menu Text itemsleft 16 52
	menu Show 0 0
	menu Show 0 0
return
;--------- EasyUO Menu Designer Code End ---------