Alzare Ninjitsu

[rolonoazoro]

Salve a tutti ho un problema, sto macrando ninjitsu e sn arrivato tranquillamente a 57.5 castando mirror image, a qst punto secondo la scaletta dovrei macrare castando focus attack, solo che nn sapendo come organizzare la macro ho cercato qlk script, ma nessuno di quelli che ho trovato mi funzionava (o io riuscivo a configurarlo nella mia niubbaggine), cmq chiedevo se qualcuno di voi potrebbe aiutarmi, dandomi qualche consiglio per la macro o postando qualche script che magari io riesca a far funzionare .

Grazie in anticipo

[Assassin]

Passa diretto a shadow jump sale ugualmente e ci sono meno casini

[rolonoazoro]

il problema e che , se non sbaglio, per fare shadow jump ci vogliono hiding e stealth, e non li ho perche il mio template nn li prevede...

[jericho.1991]

il problema e che , se non sbaglio, per fare shadow jump ci vogliono hiding e stealth, e non li ho perche il mio template nn li prevede...

equippa monili + ninja e vai di ds
P.S:la pazienza è la virtù dei forti

[rolonoazoro]

equippa monili + ninja e vai di ds
P.S:la pazienza è la virtù dei forti

ok. anche se la scaletta prevede di castare il ds da 90 in su, equippo i monili +15 e +14, il problema e che nn so come organizzare la macro, da qll che ho potuto leggere si castano le mirror e si casta il ds su di loro, solo che con i pochi script che ho provato nn ho avuto successo. Ho letto anche di andare in loss e macrare in loss, ma secondo me e solo un casino...

[Jose_2388]

In loss non puoi più macrare ^^.

Devi equippare monili +ninja e fare una macro del tipo:
CastSpell Mirror Image
Target Random (grey, red ecc in base al colore delle mirror che evochi)
CastSpell Death Stike
Attack Last Target

Più o meno così insoma...mettici qualche pausa e sei apposto. Il tutto in barca o per lo meno muovendoti se no non sale.

[Assassin]

io mi sono fatto questo script :

;==================================
; Script Name: Ninjitsu Train
; Version: 1.0
; Author: Voldemort
; Client Tested with: 6.0.1.3
; EUO version tested with: 1.5 v115
; Shard OSI / FS: FS
; Revision Date: 24/11/2008
; Public Release: 24/11/2008
; Purpose: move ship on 9x9
;==================================

set %tot_cicli_move 6            ; Grandezza del quadrato modifica per allargare o restringere il quadrato

;==================================
; Non modificare le seguenti righe
;==================================
set %idscript NinjitsuTrain
set %versionscript 1.0
set %debug_mode #false

finditem #charid
set %tipo #findtype

ignoreitem #charid

event sysMessage Inizio script %idscript v %versionscript

display yesno Desideri eseguire lo script in debug mode?
if #dispRes = yes
{
   event sysMessage Debug Mode : ON
   set %debug_mode #true
}

gosub CheckForWorldSave

;==================================;
;        Ciclo principale          ;
;==================================;
while #true
{
      gosub Muovi Forward %tot_cicli_move %debug_mode
      wait 1s
      gosub Muovi Left %tot_cicli_move %debug_mode
      wait 1s
      gosub Muovi Back %tot_cicli_move %debug_mode
      wait 1s
      gosub Muovi Right %tot_cicli_move %debug_mode
      wait 1s
}
;==================================

;==================================;
;          muove la barca          ;
;==================================;
sub Muovi
    set %movimenti 0
    set %tot_cicli_move %2
    set %direzione %1
    set %debug_mode %3

    while %movimenti < %tot_cicli_move
    {
         event macro 1 0 %direzione one
         set %movimenti %movimenti + 1
         if %debug_mode = #true
         {
            event sysMessage Movimento ( %direzione ) : %movimenti
            event sysMessage Controllo salvataggio
            event sysMessage Provo a usare il DS
         }
         
         gosub DeathStrike
         gosub CheckForWorldSave
    }
    if %debug_mode = #true
    {
         event sysMessage Totale movimenti ( %direzione ) effettuati : %movimenti
         event sysMessage Controllo salvataggio
    }
    
    gosub CheckForWorldSave
return
;==================================

;==================================;
;       Casta Death Strike         ;
;==================================;
sub DeathStrike
    set %i 2

    if #mana > 40
    {
         event macro 15 252
         wait 4s
         finditem %tipo G_ 2
         if ( #findkind <> -1 )
         {
              event property #findid
              if #charname in #property
              {
                   set #enemyid #findid
                   set #ltargetid #findid
                   set #lobjectid #findid
                   wait 5
                   event macro 15 246 ;Cast spell Death Strike
                   wait 5
                   event macro 27 0 ;Attack Last
              }
              else
              ignoreitem #findid
         }
    }
    wait 6s
return
;==================================

;**
;* @name CheckForWorldSave
;* @ver 1.0 20May05
;* @author  Boydon
;* @purpose To detect world saves and resources cleaning of RunUO Shards
;* @params
;* @returns
;* @notes the sub keep track of the last scanned journal line using
;*					the variable %Saveindex: every time the sub is called the script will
;*					start to scan from that line.
;* @dependencies sub WaitForSaveEnd
;* @example gosub CheckForWorldSave
;* @status Tested and working fine

sub CheckForWorldSave

	nameSpace Push
	nameSpace Local CheckForWorldSave , #time , #random , #scnt2

	if %SaveIndex = N/A
		set %SaveIndex #jindex

	set !Save #false
	set !Jstart %SaveIndex
	for !i !Jstart #jindex
	{
		scanjournal !i
		if #jcolor = 53
		{
			if THE_WORLD_WILL_SAVE_IN in #journal || WORLD_IS_SAVING in #journal
			{
				set !Save #true
				Event ExMsg #charid 3 33 SAVE Detected
				gosub WaitForSaveEnd WORLD_SAVE_COMPLETE 100 !i SAVE
				set %SaveIndex #jindex
				set !i #jindex
			}
			if CLEANING in #journal
			{
				set !Save #true
				Event ExMsg #charid 3 33 CLEANING Detected
				gosub WaitForSaveEnd CLEANED 100 !i CLEANING
				set %SaveIndex #jindex
				set !i #jindex
			}
		}
		set %SaveIndex !i
	}

	nameSpace Clear
	nameSpace Pop

return
;==================================

;**
;* @name WaitForSaveEnd
;* @ver 1.0 20May05
;* @author  Boydon
;* @purpose To detect when world save/ resource cleaning has ended
;* @params %1 req End of save message
;*				 %2 req Time to wait before the sub goes in time out
;*				 %3 req #jindex of world save start message
;*				 %4 req Tells what are we waiting for, can be SAVE|CLEANING
;* @returns
;* @notes This sub _MUST_ be called _ONLY_FROM_ sub CheckForWorldSave.
;*				This sub uses the same namespace as sub CheckForSave.
;* @dependencies sub CheckForWorldSave
;* @example
;* @status Tested and working fine

sub WaitForSaveEnd

	if %0 < 4 || %1 = N/A || %2 = N/A || %3 = N/A || %4 = N/A
	{
		display ok Wrong use of Sub WaitForSaveEnd: some required arguments are missing!
			+$Script will be halted.
		halt
	}

	set !EndOfSave %1
	set !SaveTimeOut #scnt + %2
	set !Jstart %3
	set !Message %4

	waitforsaveend:

	for !j !jstart #jindex
	{
		scanjournal !j
		if #jcolor = 53
		{
			if !EndOfSave in #journal
			{
				set !Save #false
				set %SaveIndex #jindex
				set !j #jindex
			}
		}
	}
	if !Save = #true && #scnt <= !SaveTimeOut
	{
		wait 1
		goto waitforsaveend
	}
	if #scnt > !SaveTimeOut
	{
		set !Save #false
		set %SaveIndex #jindex
		event ExMsg #charid 3 33 !Message detection timed out...
	}
	event ExMsg #charid 3 33 End of !Message Detected
return
;==================================

;==================
; SAVE / CLEANING INFO
;==================

;------------------
; Save Messages
;------------------
THE_WORLD_WILL_SAVE_IN ; advice before the save
WORLD_IS_SAVING ; world save is starting
WORLD_SAVE_COMPLETE ; world save is complete

;------------------
; Resource Cleaning Messages
;------------------
CLEANING ; cleaning save is starting
CLEANED ; cleaning is complete

;------------------
; #jcolour of save / cleaning message
;------------------
Save journal color 53

piazzi il tuo pg sulla barca e fai play al resto ci pensa lui.

[rolonoazoro]

lo provo e ti faccio sapere thz