Snooping e Fishing?

[No-Stop]

vorrei sapere come è possibile impostare una macro per snooping... qulacuno ne ha mai fatta una? e il modo milgliore per macrare fishing?

[ErCristo]

Scarica Easyuo ti metti un bello script ke apre le borse degli NPC in auto e stai apposto
dimmi se ti va bene questo

;==================================
; Script Name:  Snooping Gainer
; Author: Necro|FS
; Version: 1.5
; Client Tested with: 4.0.5b
; EUO version tested with: 1.42.009B
; Shard OSI / FS: OSI
; Revision Date: 03-11-06
; Public Release: 7-27-04
; Global Variables Used: n/a
; Purpose: Snoops bags of another character.
;==================================
; Directions : Press play, open the bag of the character you'll be snooping
;                  when prompted.
;--------------------------------------------------------------
; Initial setup
Event Macro 31 0 
wait 10 
Event Macro 8 2 
CHOOSESKILL Snooping real
set %Skill #SKILL 
wait 20 
set %SysMessages SYS in #opts 
set %shardsList Legends_Atlantic_Lake , #spc , Superior_Great , #spc , 
+ Lakes_Chesapeake_Catskills_Siege , #spc , Perilous_Origin_Pacific_Sonoma_Lake , #spc , 
+ Austin_Baja_Napa , #spc , Valley_Drachenfels_Europa_Oceania_Mizuho_Izumo_
+Sakura_Mugen_Wakoku_Formosa_Arirang_Balhae_Asuka_Yamato_Hokuto
set %freeShard #shard notIn %shardsList 
 
;--------------------------------------------------------------
;find bag of Snooped character
set #LOBJECTID xxx
set #CONTID xxx
 
if %SysMessages = -1 
   Event SysMessage †Use the Backpack of the person you will be snooping now...†
else 
   display OK †Use the Backpack of the person you will be snooping now...†
 
PickBackPackLoop: 
 
if #LOBJECTID = xxx
   goto PickBackPackLoop
set %PackID #LOBJECTID 
 
;--------------------------------------------------------------
; open the Main pack of the character you will snoop
if %SysMessages = -1 
   Event SysMessage Opening main pack.. 
 
OpenMainPack: 
 
set #lobjectid %PackID 
Event Macro 17 0 
 
If #CONTID = %PackID 
   goto Start
wait 15 
goto OpenMainPack
 
;--------------------------------------------------------------
; Main Loop
Start: 
sub _cSPA
CHOOSESKILL Snooping real
if #skill = 1000 
   gosub GMed
FindItem LKF_ZJF_CKF_CUD C
set %BagFound #FindID 
; checks if the bag is your stable
if #FINDY < 0 
{ 
   ignoreitem #FINDID 2 
   goto start
} 
; checks if the bag is in your backpack
If #FINDKIND = 0 
   goto OpenABag
If #FINDKIND = -1 
{ 
chooseskill snooping real
; checks if a gain occurred in that run
   if #skill > %skill 
   { 
      ignoreitem reset 1 
      set #CONTID xxx
      set %skill #skill 
      Event Macro 31 0 
      wait 10 
      Event Macro 8 2 
      goto OpenMainPack
   } 
   Event Macro 31 0 
   display OK No more packs were found or you opened them all without gaining.. 
   Halt 
} 
;--------------------------------------------------------------
 
OpenABag: 
 
finditem %BagFound 
if #findkind = -1 
  goto start
set #LOBJECTID %BagFound 
event macro 17 0 
wait 1s 
 
If #CONTID = %BagFound 
{ 
   ignoreitem #FINDID 1 
   goto Start
} 
goto OpenABag
halt 
 
;--------------------------------------------------------------
 
sub GMed
display OK Congratulations ! 
halt 
 
;--------------------------------------------------------------
 
sub _cSPA
if ! %freeshard 
{ 
  _CSPA: 
  gosub CheckSkillPointsAvailable
  if ! #result 
  { 
    if ! %CSPAcnt 
    { 
      display ok You have no replacement skills available.  Please turn some skills
      + down... Script will continue automatically. 
      event macro 8 4 
      wait 40 
      set %CSPAcnt #true 
    } 
    goto _CSPA
  } 
} 
return 
;===========
;**
;* @name CheckSkillpointsAvailable
;* @ver 1.3 1Dec04 ,added bushido/ninjitsu, and return var option, gets %totalskillcap and age
;* @author  Roadkill
;* @purpose checks all skills for one pointed down with skillpoints avail to gain
;*   or total skill < your skillcap (gives total skillcap and account age also).
;* @params  %1 varname to hold returned #T/#F same as #result, optional
;* @returns <@#result T/F, true=skill points available for gain>, and @%1
;*   %totalskillcap holds your total account skillcap (ie 7200)
;*   %accountage will hold the account age in months
;* @example call rksubs.txt CheckSkillpointsAvailable pointsavail
;* @status tested good.  Takes < 1/2 sec to run all skills, 1st pass 1s to get
;*   %totalskillcap with account age
sub CheckSkillpointsAvailable
  set !lpc #lpc 
  set #lpc 1000 
  set !skstr alch_anat_anil_anim_arch_arms_begg_blac_bowc_bush_camp_carp_cart_ , 
  + chiv_cook_dete_disc_eval_fenc_fish_focu_fore_heal_herd_hidi_insc_item_ , 
  + lock_lumb_mace_mage_medi_mini_musi_necr_ninj_parr_peac_pois_prov_remo_resi_ , 
  + snoo_spir_stea_stlt_swor_tact_tail_tast_tink_trac_vete_wres_
  set !pointsAvail #false 
  set !skilltotal 0 
cspaloop: 
  str len !skstr 
  if #strres < 5 
    goto exitcspa
  str left !skstr 4 
  chooseskill #strres real
  str del !skstr 1 5 
  set !skstr #strres 
  if #skilllock <> down || #skill = 0 
  { 
    set !skilltotal !skilltotal + #skill 
    goto cspaloop
  } 
  set !pointsAvail #true 
exitcspa: 
  if !skilltotal < 7000 
    set !pointsAvail #true 
  if !pointsAvail = #false || %totalskillcap = n/a
  { 
    if %totalskillcap <> n/a
      goto _cspatsc
    _cspadoll: 
    event macro 8 1 
    wait 10 
    if #contname <> paperdoll_gump
      goto _cspadoll
    set !cspax #contposx + 30 
    set !cspay #contposy + 215 
    _cspaprofile: 
    click !cspax !cspay F X 2 dmc
    wait 10 
    scanjournal 
    if account notin #journal && account notin #sysmsg 
      goto _cspaprofile
    if account in #sysmsg 
      set !agestr #sysmsg 
    else 
      set !agestr #journal 
    set !cspax #contposx + 100 
    set !cspay #contposy + 100 
    click !cspax !cspay r dmc
    ;THIS_ACCOUNT_IS_55_MONTHS_OLD
    str len !agestr 
    set !len #strres - 27 
    str mid !agestr 17 !len 
    set %accountage #strres 
    set !skillbonus ( %accountage / 12 ) * 50 
    if !skillbonus > 200 
      set !skillbonus 200 
    set %totalskillcap 7000 + !skillbonus 
  _cspatsc: 
    if !skilltotal < %totalskillcap 
      set !pointsAvail #true 
  } 
exitcspa2: 
if %0 > 0 && %1 <> n/a
  set % . %1 !pointsAvail 
set #lpc !lpc 
return !pointsAvail

[No-Stop]

mmm lo ho scaricato ma come lo installo? mi si blocca al terzo punto mi chiede yes o no e poi mail o link e dopo nn mi fa klikkare ok come fo?

[ErCristo]

Scarica Easyuo

Scarica Easyuo oppure qua EasyUO
te lo anke messo sopra
Per lo script basta copiarlo e incollarlo in Easyuo e premere play

[No-Stop]

poi copio e incollo? quello che hai scritto?

[ErCristo]

Per lo script basta copiarlo e incollarlo in Easyuo e premere play

Si

[No-Stop]

per fischig qualcuno ha qualche idea? vorrei macrare senza barca ma al limite la compro...

[Rikch]

seza barca puoi macrare solo fino a 60 (mi pare) poi devi pescare in mare aperto.

io avevo fatto una macro con razor che spostava avanti la barca per 10 secondi, percava 4 volte in 4 locazioni, poi tornava indietro per 7 secondi.