Script Fishing

[Elassar]

Qualcuno ha qualche bel script per far salire fishing????

tnx

[Gioda]

uppo siccome sono gia stati gentili a darmene uno ci daranno anche questo?

[n_iago]

;================================== 
; Script Name: Auto Fisher 
; Author: Goldfish 
; Version: 2.00 
; Client Tested with: 4.0.0.p 
; EUO version tested with: 1.40 (0058) 
; Shard OSI / FS: OSI 
; Revision Date: October 30, 2003 
; Public Release: October 13, 2003 
; Purpose: A script that will fish and fish and fish and... 
; Oh yeah it also chops up those fishes into steaks. 
;================================== 
initevents 
set %nowater no 
; === SETUP === 
display ok This script is designed to be run on a boat. Make sure you also have a 
+ fishing pole and a dagger. If you are not ready please stop the script and do the above. 
event Macro 8 1 
wait 1s 
set #contPosX 10 
set #contPosY 10 
wait 1s 
event Macro 8 7 
wait 1s 
set %packID #contID 
findItem KDF C 
if #findKind = -1 
{ 
   display ok You do not have a fishing pole, the script will now halt. 
   halt 
} 
set %pole #findID 
findItem KDF C 
if #findKind = -1 
{ 
   display ok You do not have a dagger, the script will now halt. 
   halt 
} 
set %dagger #findID 
click 243 279 
set #lTargetID null 
display ok Please target the tillerman. 
set #targCurs 1 
charloop: 
if #lTargetID = null 
{ 
   goto charloop 
} 
set %clickX #cursorX - 52 
set %clickY #cursorY + 78 
display ok Please make sure your character is standing next to the tillerman. Also 
+ make sure your character is not riding a mount.$ 
+ You have 5 seconds to do so. 
wait 5s 
display ok Setup complete. Please enjoy. 
msg raise anchor$ 
; === END SETUP === 
fish: 
set #lObjectID %pole 
event Macro 17 0 
target 
click: 
click %clickX %clickY d 
for %checkClick 1 10 
{ 
   if #targCurs = 0 
   { 
      set %checkClick 10 
      goto success 
   } 
} 
goto click 
success: 
if %nowater = yes 
{ 
   display ok You have not targeted water, not next to water, or the script has failed and is now halting. 
   halt 
} 
scanjournal 1 
if fish_while_riding in #journal 
{ 
   deleteJournal 
   display ok You cannot fish while riding a mount. Please get off your mount. $ 
+ The script will now halt. 
   halt 
} 
scanjournal 1 
if but_fail_to_catch_anything in #journal 
{ 
   deleteJournal 
   wait 1 
   set %nowater no 
   event SysMessage Failed to catch anything, Fishing Again... 
   goto fish 
} 
scanjournal 1 
if you_pull_out_an_item in #journal 
{ 
   deleteJournal 
   wait 1 
   event SysMessage Fish Caught, Re-fishing Area 
   set %nowater no 
   goto fish 
} 
scanjournal 1 
if closer_to_the_water_to_fish in #journal 
{ 
   deleteJournal 
   if %nowater = pending 
   { 
      set %nowater yes 
      goto fish 
   } 
   wait 1 
   event SysMessage Not close to the water please move closer... 
   set %nowater pending 
   wait 3s 
   goto fish 
} 
scanjournal 1 
if you_need_water_to_fish_in in #journal 
{ 
   deleteJournal 
   if %nowater = pending 
   { 
      set %nowater yes 
      goto fish 
   } 
   wait 1 
   event SysMessage No Water on target re-attempting fishing 
   set %nowater pending 
   wait 3s 
   goto fish 
} 
scanjournal 1 
if seem_to_be_biting_here in #journal 
{ 
   deleteJournal 
   wait 1 
   event SysMessage No more fish, moving on... 
   msg slow forward$ 
   wait 5s 
   msg stop$ 
   set %nowater no 
   goto fish 
} 
scanjournal 1 
if sea_serpent in #journal 
{ 
   deletejournal 
   msg slow forward$ 
   wait 15s 
   msg stop$ 
   set %nowater no 
} 
scanjournal 1 
if water_elemental in #journal 
{ 
   deletejournal 
   msg forward$ 
   wait 15s 
   msg stop$ 
   set %nowater no 
} 
if #WEIGHT > #MAXWEIGHT - 10 
{ 
   gosub cut 
} 
goto success 

sub cut 
wait 5s 
FQD: 
finditem FQD C 
if #findKind = -1 
{ 
   goto DQD 
} 
set %fishies #findType 
set #lObjectID %dagger 
event Macro 17 0 
set #findMod 30_15 
target 
click #findX #findY 
wait 1s 
DQD: 
finditem DQD C 
if #findKind = -1 
{ 
   goto EQD 
} 
set %fishies #findType 
set #lObjectID %dagger 
event Macro 17 0 
set #findMod 24_17 
target 
click #findX #findY 
wait 1s 
EQD: 
finditem EQD C 
if #findKind = -1 
{ 
   goto GQD 
} 
set %fishies #findType 
set #lObjectID %dagger 
event Macro 17 0 
set #findMod 13_11 
target 
click #findX #findY 
wait 1s 
GQD: 
finditem GQD C 
if #findKind = -1 
{ 
   goto end 
} 
set %fishies #findType 
set #lObjectID %dagger 
event Macro 17 0 
set #findMod 25_29 
target 
click #findX #findY 
wait 1s 
end: 
set #findMod 0_0 
if #WEIGHT > #MAXWEIGHT - 5 
{ 
   display ok You are too heavy to continue. The script will now halt. 
   halt 
}

[elgigio]

scusate l'ignoranza

come si usa lo script?

dove si usa lo script?

scusate la domanda da niubbone, ma lo sono

[Elassar]

asdasd ne avevo trovato uno simile sul sito di easyuo.

Cmq sto script si usa con EasyUO

www.easyuo.com

li trovi tutto

[n_iago]

E' quello di easyuo..

si usa in barca con la canna da pesca nello zaino.

[Kyosuke83]

Script? mah io sono Gm fishing e lo lascio a pescare con UOLoop.. sempre su un punto tanto quando il mare diventa inpescabile dopo pochi minuti ritorna pescabile. io nn ci ho messo tanto così ^_^