wood

[princeps]

se hai diversi tipi di log nel pack e usi la saw x trasformarne un tipo in board ti dice ke nn hai materiali nel pack, se invece lo fai con un solo materiale funziona...è un bug è va corretto dato ke si possono scegliere i tipi di materiale da trasformare in board quindi nn vedo xkè devo avere solo quel tipo nel pack...

[adrytug]

Up

[princeps]

ho fatto fare uno script ke prende i log da una cassa e li trasforma in board, ancora nn l' ho provato xkè sn di fretta cmq te lo posto così finkè nn fixano almeno nn dobbiamo farlo a mano

;==================================
; Script Name: Boardmaker
; Version: 0.1
; Author: Tony
; Client Tested with: 6.0.6
; EUO version tested with: 1.5 v132
; Shard OSI / FS: FS
; Revision Date: 26/09/08
; Public Release: 26/09/08
; Purpose: crea boards a partire da logs
;==================================
;Per cominciare serve una cassa con dentro logs, lingotti e tinker tools
;è possibile usare la banca piuttosto che una cassa
;NON MODIFICARE NIENTE QUI SOTTO
;==================================
set %tinker_type KTL
set %saw_type EGG
set %log_type ZLK
set %board_type TLK
set %ingot_type ENK

set %bank #false
set %first_time #true
event exmsg #charid 3 30 Seleziona la cassa o clicca sul pg per usare la banca.
set #targcurs 1
while #targcurs = 1
  wait 1
if #ltargetid = #charid
  set %bank #true
else
  set %cassa #ltargetid

gosub apriCassa

main_loop:
  gosub calcolaPeso
  gosub sposta %log_type %q %cassa #backpackid
  gosub tagliaLegna
  gosub sposta %board_type 1000 #backpackid %cassa
  wait 10
goto main_loop

sub tagliaLegna
  finditem %saw_type C_ , #backpackid
  if #findkind = -1
    gosub craftaSega
  finditem %saw_type C_ , #backpackid
  set #lobjectid #findid
  try:
    event macro 17 0
    set %init #scnt
    while #contsize <> 530_437
    {
      wait 1
      if #scnt - %init > 4
        goto try
    }
  wait 10
  if %first_time
  {
    set %x 30 + #contposx
    set %y 90 + #contposy
    click %x %y
    wait 20
    set %x 230 + #contposx
    set %y 70 + #contposy
    click %x %y
    set %first_time #false
  }
  else
  {
    set %x 280 + #contposx
    set %y 410 + #contposy
    click %x %y
  }
  wait 3s
return

return

sub craftaSega
  finditem %ingot_type C_ , #backpackid
  if #findstack < 4
  {
    set %stack #findstack
    set %need 4 - %stack
    finditem %ingot_type C_ , %cassa
    if #findstack < %need
      gosub error
    exevent drag #findid %need
    wait 8
    exevent dropc #backpackid
    wait 8
  }
  finditem %tinker_type C_ , #backpackid
  if #findkind = -1
  {
    finditem %tinker_type C_ , %cassa
    if #findkind = -1
      gosub error craftasega
    exevent drag #findid 1
    wait 8
    exevent dropc #backpackid
    wait 8
  }
  set #lobjectid #findid
  try:
    event macro 17 0
    set %init #scnt
    while #contsize <> 530_437
    {
      wait 1
      if #scnt - %init > 4
        goto try
    }
  set %x 28 + #contposx
  set %y 110 + #contposy
  click %x %y
  wait 20
  set %x 230 + #contposx
  set %y 210 + #contposy
  click %x %y
  wait 3s
  set %cx #contposx + 10
  set %cy #contposy + 10
  click %cx %cy f r dmc
return

sub sposta
  set %obj_type %1
  set %q %2
  set %from %3
  set %to %4
  finditem %obj_type C_ , %from
  if #findkind = -1
    gosub error
  exevent drag #findid %q
  wait 8
  exevent dropc %to
  wait 8
return


return

sub calcolaPeso
  set %q ( ( #maxweight - #weight ) / 2 )
return

sub apriCassa
  if %bank
  {
    try:
    set %init #scnt
    msg $
    msg bank $
    while #contsize <> 180_240
    {
      wait 1
      if #scnt - %init > 4
        goto try
    }
    set %cassa #contid
  }
  else
  {
     set #lobjectid %cassa
     event macro 17 0
     wait 1s
  }
return

sub error
  event exmsg #charid 3 30 Risorse/attrezzi easuriti!
  halt
return

[princeps]

altro bug ke nn permette il funzionamento dello script ke ho postato qui sopra, se prendo log x un totale di peso 450 stone, e sul mio pg posso portare max 485 stone mi dice cmq ke ho troppo peso addosso e nn mi fa mettere i log nel pack -.-
quando invece ho ancora un margine di 35 stone come peso -.-

[adrytug]

Princeps non ai uno script che mete solo i log's in banka o nella casa? Poi piutosto facio a mano io. Grazie in anticipo.

[princeps]

no xò ho risolto cn lo script ke trasforma log in board

;==================================
; Script Name: Boardmaker
; Version: 0.2
; Author: Tony
; Client Tested with: 6.0.6
; EUO version tested with: 1.5 v132
; Shard OSI / FS: FS
; Revision Date: 26/09/08
; Public Release: 26/09/08
; Purpose: crea boards a partire da logs
;==================================
;Per cominciare serve una cassa con dentro logs, lingotti e tinker tools
;è possibile usare la banca piuttosto che una cassa
;NON MODIFICARE NIENTE QUI SOTTO
;==================================
set %logs 190 ;<---setta quanti log prendere per volta o metti 0 per automatico
;==================================
set %tinker_type KTL
set %saw_type EGG
set %log_type ZLK
set %board_type TLK
set %ingot_type ENK

set %bank #false
set %first_time #true
event exmsg #charid 3 30 Seleziona la cassa o clicca sul pg per usare la banca.
set #targcurs 1
while #targcurs = 1
  wait 1
if #ltargetid = #charid
  set %bank #true
else
  set %cassa #ltargetid

gosub apriCassa

main_loop:
  gosub calcolaPeso
  gosub prendiLegna
  gosub tagliaLegna
  finditem %board_type C_ , #backpackid
  set %init #scnt
  while #findkind = -1
  {
    wait 1
    finditem %board_type C_ , #backpackid
    if #scnt - %init > 5
      break
  }
  gosub sposta %board_type 1000 #backpackid %cassa
  wait 10
goto main_loop

sub tagliaLegna
  finditem %saw_type C_ , #backpackid
  if #findkind = -1
    gosub craftaSega
  finditem %saw_type C_ , #backpackid
  set #lobjectid #findid
  try:
    event macro 17 0
    set %init #scnt
    while #contsize <> 530_437
    {
      wait 1
      if #scnt - %init > 4
        goto try
    }
  wait 10
  if %first_time
  {
    set %x 30 + #contposx
    set %y 90 + #contposy
    click %x %y
    wait 20
    set %x 230 + #contposx
    set %y 70 + #contposy
    click %x %y
    set %first_time #false
  }
  else
  {
    set %x 280 + #contposx
    set %y 410 + #contposy
    click %x %y
  }
  wait 4s
return

sub prendiLegna
  find:
    finditem %log_type C_ , %cassa
    if #findkind = -1
      gosub error
    if #findcol <> 0 2
      ignoreitem #findid
      goto find
    exevent drag #findid %q
    wait 8
    exevent dropc #backpackid
    wait 1s
return

sub craftaSega
  finditem %ingot_type C_ , #backpackid
  if #findstack < 4
  {
    set %stack #findstack
    set %need 4 - %stack
    finditem %ingot_type C_ , %cassa
    if #findstack < %need
      gosub error
    exevent drag #findid %need
    wait 8
    exevent dropc #backpackid
    wait 8
  }
  finditem %tinker_type C_ , #backpackid
  if #findkind = -1
  {
    finditem %tinker_type C_ , %cassa
    if #findkind = -1
      gosub error craftasega
    exevent drag #findid 1
    wait 8
    exevent dropc #backpackid
    wait 8
  }
  set #lobjectid #findid
  try:
    event macro 17 0
    set %init #scnt
    while #contsize <> 530_437
    {
      wait 1
      if #scnt - %init > 4
        goto try
    }
  set %x 28 + #contposx
  set %y 110 + #contposy
  click %x %y
  wait 20
  set %x 230 + #contposx
  set %y 210 + #contposy
  click %x %y
  wait 3s
  set %cx #contposx + 10
  set %cy #contposy + 10
  click %cx %cy f r dmc
return

sub sposta
  set %obj_type %1
  set %q %2
  set %from %3
  set %to %4
  finditem %obj_type C_ , %from
  if #findkind = -1
    gosub error
  exevent drag #findid %q
  wait 8
  exevent dropc %to
  wait 8
return


return

sub calcolaPeso
  if %logs = 0
    set %q ( ( #maxweight - #weight ) / 2 )
  else
    set %q %logs
return

sub apriCassa
  if %bank
  {
    try:
    set %init #scnt
    msg $
    msg bank $
    while #contsize <> 180_240
    {
      wait 1
      if #scnt - %init > 4
        goto try
    }
    set %cassa #contid
  }
  else
  {
     set #lobjectid %cassa
     event macro 17 0
     wait 1s
  }
return

sub error
  event exmsg #charid 3 30 Risorse/attrezzi easuriti!
  halt
return

p.s. noto cn piacere ke anke avendo fatto presente cn page in game di questo posti i gm continuano a fregarsene e manco rispondono...

[adrytug]

no xò ho risolto cn lo script ke trasforma log in board
[[/CODE]
p.s. noto cn piacere ke anke avendo fatto presente cn page in game di questo posti i gm continuano a fregarsene e manco rispondono...

Idem

[Gaspa86]

Si puo risolvere cosi:

1) attaccate lo script taglialegna (uso lumber scorna) e gli tolgo dalla cassa (o dalla banca) sia le seghe che i toolkit, il mio pg nn a tinkering quindi prova a trasformare le log in board ma quando si accorge di nn avere seghe e quindi posa i log nella cassa (o in banca) nello zaino mettete una 20° di accette prima di lasciarlo a macrare...

2) trasformate i log in board con uno script (prince il tuo si blocca dp un po) provate questo (lo script ne posto metà e metà xke è troppo lungo copiatelo e appiccicate i due pezzi uno sopra l'altro senza saltare pezzi è! )

;======================================================
; Script Name: Hosebomber's ML Board Maker
; Author: Hosebomber
; Version: 1.4
; Client Tested with: 5.0.1d
; EUO version tested with: 1.5 (test ver 64)
; Shard OSI / FS: OSI
; Revision Date: 10-28-05
; Public Release: 9-27-05
; Global Variables Used: N/A
; Purpose: Turn logs into boards. (all types)
; ======================================================
; -------------------------Version History--------------
; ======================================================
;Version Update
;Version 1.1 Added menu, added auto bank setup via display.
;Version 1.2 Added a fix for elves being weak little peoples.
;        Also cleaned up some coding to make it a bit faster.
;Version 1.3 Added a hide button to menu.
;        Fixxed typo that caused a loop to occur when starting
;        with less then one carp tool or tinker kit in pack.
;Version 1.4 Added the option to tinker tools or not.
;        If it is unchecked via the menu it will look for tools in
;        you log secure. Also added the ability to scan you secure
;        for ingots if none is in your pack.
; =======================================================
; ---------------------------Directions------------------
; =======================================================
;If using your bank make sure all logs are in a single container in your bank.
;If starting in your home, make sure all logs are in the root
;   of the container.
;Press PLAY
;If you lag set the variable below. (should not need this)
;If you DO NOT wish to make regular logs change below to #false.
;======================================================
;Do you lag??? If so set this to #true
set %Damn_I_Lag #false
;If you do not wish to make a type of board set below to #false
set %normal #true
set %oak #true
set %ash #true
set %yew #true
set %heart #true
set %blood #true
set %frost #true
set %ingots ENK
;==== Nothing below this line SHOULD need changed ======
;set board types here
set %boards TLK
;Set log types here
set %logs ZLK
;Set carp tool types here.
set %carp_tool BIG_AGG_AIG_ZHG_EGG_KGG_IGG_WFG_CGG
;Set tinker tool types here.
set %tinker_kit GTL_KTL_JTL
; ========================================================
; ----------------------Do Not Edit Beyond Here-----------
; ========================================================
gosub Set_variables
gosub Board_menu
if %Damn_I_Lag = #true
{
  set %short_delay 20
}
else
{
  set %short_delay 10
}
event macro 31
wait 20
gosub Get_Paperdoll_Placement
wait 20
gosub Start
gosub Set_secure
gosub Set_plane_to_other
gosub Open_secure
gosub Set_low_skill

Main_Loop:
gosub Hide
gosub Find_logs
gosub Cal_amount
gosub Get_logs
gosub Set_plane_to_type
gosub Make_boards
gosub Put_boards_away
goto Main_Loop

;===================================================
sub Set_secure
display yesno Are you using your bank?$
if #dispRes = yes
{
nextCPos 25 500
msg Bank$
wait %short_delay
}
display OK Please target your secure container.$
wait %short_delay
set #targcurs 1
wait %short_delay
WaitTarget:
if #targcurs = 0
{
set %secure #ltargetid
return
}
goto WaitTarget
return
;===================================================
sub Set_plane_to_other
finditem %carp_tool C_ , %backpackid
if #findkind = -1
{
display OK Please start with atleast 1 Carpentry tool in you pack.$
        +Script Halting.$
        Halt
}
set %carp_tool_id #findid
set #lobjectid %carp_tool_id
event macro 17
wait 2
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %set_plane_clickx
set %clicky %gumpy + %set_plane_clicky
click %clickx %clicky f
wait 2
gosub wait_for_gump
wait 2
gosub close_gump
wait %short_delay
return
;===================================================
sub Open_secure
nextCPos 25 25
set #lobjectid %secure
event macro 17
wait %short_delay
return
;===================================================
sub Find_logs
Log_search:
finditem %logs C_ , %secure
wait 5
if #findkind = -1
{
gosub close_gump
Display OK you are out of logs.$
        +Please get and restart the script.$
        Halt
}
else
{
    event property #findid
    if  ! ( Oak in #property ) &&  ! ( Ash in #property ) &&
        + ! ( Yew in #property ) && ! ( Heartwood in #property ) &&
        + ! (  Bloodwood in #property ) && ! ( Frostwood in #property )
    {
       if %normal = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Normal
    set %type 1
    }
    if Oak in #property
    {
     if %oak = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Oak
    set %type 2
    }
    if Ash in #property
    {
       if %ash = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Ash
    set %type 3
    }
    if Yew in #property
    {
       if %yew = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Yew
    set %type 4
    }
    if Heartwood in #property
    {
       if %heart = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Heartwood
    set %type 5
    }
    if  Bloodwood in #property
    {
       if %blood = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Bloodwood
    set %type 6
    }
    if Frostwood in #property
    {
       if %frost = #false
        {
        ignoreItem #findid
        goto Log_search
        }
    set %getting Frostwood
    set %type 7
    }
}
set %get_these_logs #findid
return
;===================================================
sub Cal_amount
set %amount #maxweight + %weight_mod
set %amount %amount - #weight
if #maxweight > 500
set %amount 500 - #weight
set %mod_amount %amount / 2
set %amount_o_logs %mod_amount
if %amount_o_logs > #findstack
set %amount_o_logs #findstack
return
;===================================================
sub Get_logs
  menu set update_status Getting %amount_o_logs %getting logs....
Exevent Drag %get_these_logs %amount_o_logs
wait 10
Exevent Dropc %backpackid
wait 10
return
;======================================================
sub Set_plane_to_type
if %type = %old_type
{
wait %short_delay
return
}
  menu set update_status Setting Carp Tool to board type....
finditem %carp_tool C_ , %backpackid
set %carp_tool_id #findid
if #findcnt < 2
 {
 if %tinker
  gosub set_tink_kit_to_wood
 else
  gosub get_tools %carp_tool %secure
 }
set #lobjectid %carp_tool_id
event macro 17
wait %short_delay
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %board_type_clickx
set %clicky %gumpy + %board_type_clicky
click %clickx %clicky f
wait %short_delay
gosub wait_for_gump
if %type = 1
set %type_clicky 70
if %type = 2
set %type_clicky 90
if %type = 3
set %type_clicky 110
if %type = 4
set %type_clicky 130
if %type = 5
set %type_clicky 150
if %type = 6
set %type_clicky 170
if %type = 7
set %type_clicky 190
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %type_clickx
set %clicky %gumpy + %type_clicky
click %clickx %clicky f
wait %short_delay
return
;======================================================
sub Make_boards
set %old_type %type
Try_again:
  menu set update_status Making %amount_o_logs %getting boards.
finditem %carp_tool C_ , %backpackid
event property #findid
if #findkind < 2
gosub set_tink_kit_to_wood
else
gosub get_tools %carp_tool %secure
set %carp_tool_id #findid
set #lobjectid %carp_tool_id
event macro 17
wait 2
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %make_board_clickx
set %clicky %gumpy + %make_board_clicky
click %clickx %clicky f
wait 20
gosub wait_for_gump
finditem %logs C_ , %backpackid
if #findkind <> -1
{
gosub Set_plane_to_type
goto Try_again
}
return
;======================================================
sub Put_boards_away
  menu set update_status Putting %amount_o_logs %getting boards away.
finditem %boards C_ , %backpackid
wait 2
Exevent Drag #findid #findstack
wait 10
Exevent Dropc %secure
wait 10
gosub Update_menu
return
;======================================================
sub set_tink_kit_to_wood
if ! %tinker
return
  menu set update_status Setting Tinker Tool....
finditem %tinker_kit C_ , %backpackid
set %tink_kit_id #findid
event property #findid
if #findcnt < 2
{
gosub set_tink_kit_to_tools
gosub set_tink_kit_to_wood
}
set #lobjectid %tink_kit_id
event macro 17
wait 2
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %tink_wood_tool_clickx
set %clicky %gumpy + %tink_wood_tool_clicky
click %clickx %clicky f
wait %short_delay
gosub wait_for_gump
wait %short_delay
finditem %carp_tool C_ , %backpackid
if #findcnt < 2
gosub make_plane
return
;=====================================================
sub make_plane
if ! %tinker
return
  menu set update_status Making Carp Tool....
finditem %tinker_kit C_ , %backpackid
set %tink_kit_id #findid
set #lobjectid %tink_kit_id
event macro 17
wait 2
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %make_plane_clickx
set %clicky %gumpy + %make_plane_clicky
click %clickx %clicky
wait %short_delay
gosub close_gump
wait %short_delay
return

[Gaspa86]

;======================================================
sub set_tink_kit_to_tools
if ! %tinker
return
  menu set update_status Setting Tinker Tool....
finditem %tinker_kit C_ , %backpackid
set %tink_kit_id #findid
set #lobjectid %tink_kit_id
event macro 17
wait 2
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %tool_set_clickx
set %clicky %gumpy + %tool_set_clicky
click %clickx %clicky f
wait 2
gosub wait_for_gump
gosub make_tink_kit
return
;=====================================================
sub make_tink_kit
if ! %tinker
return
  menu set update_status Making Tinker Tool....
finditem %tinker_kit C_ , %backpackid
set %tink_kit_id #findid
gosub ingot_check
set #lobjectid %tink_kit_id
event macro 17
wait 2
gosub wait_for_gump
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %tink_kit_clickx
set %clicky %gumpy + %tink_kit_clicky
click %clickx %clicky
wait 2
gosub wait_for_gump
gosub close_gump
return
;=======================================================
sub close_gump
Gump_close_loop:
set %gumpx #contposx
set %gumpy #contposy
set %clickx %gumpx + %gump_close_clickx
set %clicky %gumpy + %gump_close_clicky
click %clickx %clicky f
wait 2
if #contname = generic_gump
goto Gump_close_loop
return
;=======================================================
sub ingot_check
if ! %tinker
return
finditem %ingots C_ , #backpackid
if #findkind = -1 || #findstack < 2
  {
  finditem %ingots C_ , %secure
  if #findkind = -1
     {
     display You have no ingots in your pack or your secure.$
          Unable to make tools and your kit is about to break.$
          Script Halting.
     Halt
     }
  if #findstack < 2
     {
     display OK You are to low on ingots to make a tool.$
        +Please get more ingots and restart the script.$
     Halt
     }
  exevent drag #findid 10
  wait 10
  exevent dropc #backpackid
  wait 10
  }
return
;===================================================
sub Get_PaperDoll_Placement
GPDXY1:
event macro 8 1
wait 10
if #contname <> paperdoll_gump
  goto GPDXY1
contpos 775 0
wait %short_delay
nextCPos 775 350
event macro 8 7
wait 15
set %backpackid #BACKPACKID
wait %short_delay
event macro 8 2
wait 10
contpos 645 565
finditem #charid
if #findtype in HS_IS
set %weight_mod 60
return
;=======================================================
sub wait_for_gump
Wait_Loop:
if #contname <> generic_gump
{
if You_have_worn_out_your_tool! in #sysmsg
   {
   wait %short_delay
   return
   }
wait 2
goto Wait_Loop
}
return
;=======================================================
sub Start
start_loop:
if #menubutton = start
  {
  menu get tinker
  set %tinker #menures
  if ! %tinker
     {
     display You have chosen not to tinker tools.$
             Please insure that you have Carpenters tools$
             on the top level of your log secure.
     }
  menu delete tinker
  menu delete start
  set #menubutton N/A
  return
  }
goto start_loop
;===================================================
sub get_tools
finditem %1 C_ , %2
if #findkind = -1
{
display You have chosen not to tinker tool and your secure$
        has no tools in it either. With no tools I make no boards.$
        Script Halting.
Halt
}
exevent drag #findid
wait 10
exevent dropc #backpackid
wait 10
return
;===================================================
sub Set_low_skill
chooseSkill carp
set %carp_skill #skill
if %carp_skill < 650
set %oak #false
if %carpSkill < 800
set %ash #false
if %carpSkill < 950
set %yew #false
if %carpSkill < 1000
{
set %heart #false
set %blood #false
set %frost #false
}
return
;===================================================
sub Update_menu
set %total_boards %total_boards + #findstack
  menu set total_boards %total_boards
if %type = 1
{
set %menu_norm %menu_norm + #findstack
  menu set menu_normal %menu_norm
}
if %type = 2
{
set %menu_oak %menu_oak + #findstack
  menu set menu_oak %menu_oak
}
if %type = 3
{
set %menu_ash %menu_ash + #findstack
  menu set menu_ash %menu_ash
}
if %type = 4
{
set %menu_yew %menu_yew + #findstack
  menu set menu_yew %menu_yew
}
if %type = 5
{
set %menu_heart %menu_heart + #findstack
  menu set menu_heart %menu_heart
}
if %type = 6
{
set %menu_blood %menu_blood + #findstack
  menu set menu_blood %menu_blood
}
if %type = 7
{
set %menu_frost %menu_frost + #findstack
  menu set menu_frost %menu_frost
}
return
;===================================================
sub Hide
insure_hide:
if %hide_attempts = 10
{
display OK You are a terrible hider.$
        +I suggest you restart the script
        +and not try to hide this time.$
        Halt
}
if #menubutton = Hide
{
if h in #charstatus
   {
   set #menubutton N/A
   set %hide_attempts 0
   return
   }
  menu set update_status Hiding, at your request....
EVENT macro 13 21
set %hide_attempts %hide_attempts + 1
wait 12s
goto insure_hide
}
return
;===================================================
sub Set_variables
set %board_type_clickx 30
set %board_type_clicky 370
set %tink_wood_tool_clickx 30
set %tink_wood_tool_clicky 90
set %make_plane_clickx 230
set %make_plane_clicky 70
set %tool_set_clickx 30
set %tool_set_clicky 110
set %tink_kit_clickx 230
set %tink_kit_clicky 130
set %gump_close_clickx 30
set %gump_close_clicky 410
set %type_clickx 230
set %make_board_clickx 230
set %make_board_clicky 70
set %set_plane_clickx 30
set %set_plane_clicky 90
set %menu_norm 0
set %menu_oak 0
set %menu_ash 0
set %menu_yew 0
set %menu_heart 0
set %menu_blood 0
set %menu_frost 0
set %total_boards 0
set %old_type 0
set %weight_mod 20
set %hide_attempts 0
set #menubutton N/A
return
;===================================================
sub Board_menu
  menu Clear
  menu Window Title Hosebomber's ML Board Maker
  menu Window Color BtnText
  menu Window Size 350 140
  menu Font Transparent #true
  menu Font Align Right
  menu Font Name MS Sans Serif
  menu Font Size 10
  menu Font Style b
  menu Font Color Silver
  menu Font Align Left
  menu Font BGColor BtnText
  menu Text Status 10 10 Status:
  menu Font Size 8
  menu Font Color Yellow
  menu Text Normal 10 55 Normal:
  menu Font Color Olive
  menu Text Oak 10 76 Oak:
  menu Font Color Silver
  menu Text Ash 10 96 Ash:
  menu Font Color Red
  menu Text Yew 10 116 Yew:
  menu Font Color Green
  menu Text Heartwood 150 55 Heartwood:
  menu Font Color Maroon
  menu Text Bloodwood 150 76 Bloodwood:
  menu Font Color Aqua
  menu Text Frostwood 150 96 Frostwood:
  menu Font Size 14
  menu Font Color Lime
  menu Text Boards_made 10 30 Boards Made
  menu Font Size 8
  menu Text Total 150 116 Total Boards:
  menu Font Color Yellow
  menu Text menu_normal 55 56 %menu_norm
  menu Font Color Olive
  menu Text menu_oak 55 76 %menu_oak
  menu Font Color Silver
  menu Text menu_ash 55 96 %menu_ash
  menu Font Color Red
  menu Text menu_yew 55 116 %menu_yew
  menu Font Color Lime
  menu Text total_boards 230 116 %total_boards
  menu Font Color Aqua
  menu Text menu_frost 230 96 %menu_frost
  menu Font Color Maroon
  menu Text menu_blood 230 76 %menu_blood
  menu Font Color Green
  menu Text menu_heart 230 56 %menu_heart
  menu Font Size 10
  menu Font Color Silver
  menu Text update_status 60 10 Initializing....
  menu Font Style bu
  menu Font BGColor None
  menu Button Hide 150 30 75 25 Hide Me
  menu Font Size 8
  menu Font Style b
  menu Font BGColor BtnText
  menu Check tinker 168 10 180 17 #true Do you want to make tools?
  menu Font Size 12
  menu Font Color White
  menu Font BGColor Purple
  menu Button start 240 30 75 25 Start
  menu HideEUO
  menu Show 650 25
return

Ecco fatto !

[adrytug]

Grazie per l'aiuto.

[Gaspa86]

[meratuik]

opto x princeps, mio karissimo amiko questo forum nn e seguito anke io segnalando alkuni bug i gm prendono provvedimenti al piu presto kosi dikono ma nn lo fnno